Создать директорию, в ней - файл, записать в него строку, переписать вторую половину строки в другой файл.

use16
org 100h
jmp start
 
;----DATA----
prop_dirname db 'Enter directory name: $'
prop_filename db 'Enter filename: $'
prop_filetext db 'Enter file content: $'
endline db 13,10,'$'
buffer rb 242
proc_buffer rb 242
proc_name db 'proc.txt',0
handle rw 1
;------------
 
start:
 
        call create_directory
        call print_endline
        call create_file
        call print_endline
        call write_file
        call print_endline
        call open_file
        call print_endline
        call process_file
 
jmp exit_app
 
 
;---PROGRAM METHODS---
create_directory:
        call input_dirname
mov ah, 39h ;CREATING DIRECTORY
int 21h
mov ah, 3Bh ;OPEN DIRECTORY
int 21h
        ret
 
create_file:
        call input_filename
mov ah, 3Ch ;CREATING FILE
xor cx, cx
int 21h
mov [handle], ax ;SAVING FILE DESCRIPTOR
        ret
 
write_file:
        call input_filetext
mov bx, [handle] ;GETTING FILE DESCRIPTOR
mov ah, 40h ;WRITING FILE
int 21h
        call close_file
        ret
 
open_file:
mov ah, 3Dh
mov al, 2
        call input_filename
int 21h
mov [handle], ax
 
mov bx, [handle]
mov ah, 3Fh ;OPENING FILE
mov dx, buffer
mov cx, 241
int 21h
        ret
 
process_file:
        add ax, dx
mov bx, dx
inc bx
mov si, proc_buffer
forloop:
cmp bx, ax
jge show_processed
mov cl, [bx]
mov [si], cl
          add bx, 2
inc si
jmp forloop
 
show_processed:
        call write_processed
mov byte[si], '$'
mov di, proc_buffer
        call print_str
        ret
 
write_processed:
mov dx, proc_name
mov ah, 3Ch
xor cx, cx
int 21h
mov bx, ax
mov ah, 40h
mov dx, proc_buffer
mov cx, si
        sub cx, proc_buffer
int 21h
        ret
 
input_dirname:
mov di, prop_dirname
        call print_str
        call input_str
        ret
 
input_filename:
mov di, prop_filename
        call print_str
        call input_str
        ret
 
input_filetext:
mov di, prop_filetext
        call print_str
        call input_str
        ret
 
;---SERVICE METHODS---
close_file:
mov ah, 3Eh
mov bx, [handle]
int 21h
        ret
 
exit_app:
mov ax, 4C00h
int 21h
 
print_str:
        push ax
mov ah, 9
xchg dx, di
int 21h
xchg dx, di
        pop ax
        ret
 
print_endline:
        push di
mov di,endline
call print_str
        pop di
        ret
 
input_str:
        push ax
mov ah, 0Ah
mov [buffer], 240
mov byte[buffer+1], 0
mov dx, buffer
int 21h
xor ax, ax
mov al, [buffer+1]
        add ax, dx
        add ax, 2
mov si, ax
mov al, 0
mov [si], al
mov cl, [buffer+1]
add dx, 2
pop ax
ret

org  100h
jmp  start
 
;----DATA----
mes0    db  13,10,'Dir name..: $'
mes1    db  13,10,'File name.: $'
mes2    db  13,10,'String....: $'
err     db  13,10,7,'Error!$'
okey    db  13,10,'--------------------'
        db  13,10,'Create Files OK! ..$'
 
buff    db  80            ; буфер для строки fn.0Ah
len     db  0
string  db  80 dup(0)
 
name    db  32 dup(0)     ; буфер для имени папки/файла
hand1   dw  0             ; хэндлы двух файлов
hand2   dw  0
;------------
 
start:  mov   dx,mes0
        call  Message
        mov   di,name       ; указатель на имя папки
        call  inpName
 
; создать папку
        mov   ah,39h
        mov   dx,name
        int   21h
        jc    Error
 
; читаем имя файла (сразу вложим в папку)
        mov   dx,mes1
        call  Message        ; ES:DI уже установлен
        mov   al,'\'         ; закроем путь
        stosb
        call  inpName        ; имя файла
        mov   si,di
        sub   si,5           ; указатель на последний символ имени (до расширения)
 
; создать сразу два файла
        mov   di,hand1       ; приёмник дескрипторов
        mov   bx,2           ; кол-во файлов
@@:     mov   ah,3Ch
        mov   dx,name
        mov   cx,20h
        int   21h
        stosw                ; запомним хэндл
        inc   byte[si]       ; сменить имя файла
        dec   bx
        jnz   @b             ; на повтор..
 
; читаем текстовую строку юзера
        mov   dx,mes2
        call  Message
        mov   ah,0Ah
        mov   dx,buff
        int   21h
 
; запись в первый файл
        xor   ch,ch
        mov   ah,40h
        mov   bx,[hand1]
        mov   dx,string
        mov   cl,[len]
        int   21h
        jc    Error
; запись во-второй файл
        shr   cx,1           ; разделить длину строки на 2
        add   dx,cx          ; сместить указатель в буфере на вторую половину строки
        mov   ah,40h
        mov   bx,[hand2]
        int   21h
        jc    Error
 
; закроем оба файла
        mov   ah,3Eh
        mov   bx,[hand1]
        int   21h
        mov   bx,[hand2]
        int   21h
 
        mov   dx,okey
        call  Message
exit:   xor   ax,ax
        int   16h
        int   20h            ; выход!
 
;------- Процедуры ------------------------------------//
Message:
        mov  ah,9
        int  21h
        ret
 
Error:  mov   dx,err
        call  Message
        jmp   exit
 
inpName:
        mov   cx,12
        mov   ah,1
@@:     int   21h
        cmp   al,13
        je    @f
        stosb
        loop  @b
@@:     ret