Номер текущей строки CRT-луча

PARTS_PER_FRAME =       400                     ; number of parts we want to divide screen by timer - set as you with
                                                ; (not less than number of visible screen lines / 2; best view for 400 and 200 in text mode [3] and Mode X [13h])
 
TOTAL_LINES_PER_FRAME = 449                     ; 449 for text mode and Mode X (including invisible frame zones)
VISIBLE_LINES_PER_FRAME = 400                   ; 400 for text mode and Mode X
 
; Don't change these values
TOTAL_PARTS_PER_FRAME = (PARTS_PER_FRAME*TOTAL_LINES_PER_FRAME+VISIBLE_LINES_PER_FRAME/2)/VISIBLE_LINES_PER_FRAME ; number of parts including invisible frame zones
 
SHOW_GRADIENT_BAR =     0                       ; 0=show static color lines, 1=show moving color bar
 
;-----------------------------------------------------------------------------------------------------------------------
 
; Intercept IRQ 0 handler and tune timer to synchronize with VGA clock
macro   InterceptTimer
{
                cli
                xor     dx,dx
                mov     es,dx
                les     ax,[es:8*4]             ; ES:AX = IRQ 0 handler
                mov     word [OrigTimerHandler+0],ax
                mov     word [OrigTimerHandler+2],es
                mov     es,dx
                mov     word [es:8*4+0],TimerHandler
                mov     [es:8*4+2],cs           ; set new handler
                mov     [CurrentPart],-1        ; current part number = -1
 
                call    TuneTimerClock          ; set mode 2 of timer (channel 0) to countdown by 1 instead of 2 (DX = 0 - default value)
                call    VerticalRetrace
                call    ReadTimerValue
                push    dx
                call    VerticalRetrace
                call    ReadTimerValue
                pop     ax
                sub     ax,dx                   ; AX = clocks per frame
                add     ax,TOTAL_PARTS_PER_FRAME/2
                xor     dx,dx
                mov     bx,TOTAL_PARTS_PER_FRAME
                div     bx                      ; AX = Round(clocks per frame / total parts per frame)
 
                xchg    dx,ax
                call    TuneTimerClock          ; set timer (channel 0) clocks
                sti
}
 
; Restore timer (channel 0) counter clock and IRQ 0 handler
macro   RestoreTimer
{
                cli
                les     ax,[OrigTimerHandler]
                push    ds
                xor     dx,dx
                mov     ds,dx
                mov     [8*4+0],ax
                mov     [8*4+2],es              ; restore IRQ 0 handler
                pop     ds
                call    TuneTimerClock          ; DX = 0 (reset to default 65536 value)
                sti
}
 
;-----------------------------------------------------------------------------------------------------------------------
 
use16
org     0x100
 
                mov     ax,0x13
                int     0x10
 
                InterceptTimer
 
                xor     ah,ah
                int     0x16
 
                RestoreTimer
 
                mov     ax,3
                int     0x10
 
                int     0x20
 
;-----------------------------------------------------------------------------------------------------------------------
 
; This macro is called from our IRQ 0 handler on first screen part
; Input value: DS = CS
; Segment registers (including DS) should be saved if changed !!!
macro   FirstPart
{
  if    SHOW_GRADIENT_BAR
        local   ..exit
                mov     ax,[BarPos]
                add     ax,[BarPosDelta]
                mov     [BarPos],ax
                jz      @F
                cmp     ax,MAX_LINE_POS
                jb      ..exit
        @@:     neg     [BarPosDelta]
        ..exit:
  end if
}
 
; This macro is called from our IRQ 0 handler on next screen part
; Input values: DS = CS; CX = screen part number (can be >= PARTS_PER_FRAME)
; Segment registers (except DS) should be saved if changed !!!
macro   NextPart
{
  if    SHOW_GRADIENT_BAR
  MAX_LINE_POS  =       PARTS_PER_FRAME-125
                mov     ax,[BarPos]
 
                xor     bx,bx                   ; black
                sub     cx,ax
                jb      @F                      ; jump if part number < BarPos
                cmp     cx,124
                ja      @F                      ; jump if part number - BarPos > 124
 
                mov     bx,cx
                inc     bx                      ; saturation = part number - BarPos + 1 (1..63)
                cmp     cx,63
                jb      @F                      ; jump if part number - BarPos < 63
 
                mov     bx,125
                sub     bx,cx                   ; saturation = 125 - (part number - BarPos)
        @@:
                xor     ax,ax
                mov     bh,bl
                SetPalette
  else ; ~ SHOW_GRADIENT_BAR
                mov     ax,0x3F00
                mov     bx,0x3F00               ; magenta (out of screen)
                cmp     cx,PARTS_PER_FRAME
                jae     @F
 
                xor     bx,bx                   ; red (first and last 16 lines)
                cmp     cx,16
                jb      @F
                cmp     cx,PARTS_PER_FRAME-16
                jae     @F
 
                mov     bl,0x3F                 ; yellow (next 16 lines)
                cmp     cx,32
                jb      @F
                cmp     cx,PARTS_PER_FRAME-32
                jae     @F
 
                cbw                             ; green (next 16 lines)
                cmp     cx,48
                jb      @F
                cmp     cx,PARTS_PER_FRAME-48
                jae     @F
 
                mov     bh,0x3F                 ; cyan (next 16 lines)
                cmp     cx,64
                jb      @F
                cmp     cx,PARTS_PER_FRAME-64
                jae     @F
 
                xor     bl,bl                   ; blue (other visible zone)
        @@:
                SetPalette
  end if
}
 
; Set palette of color AL to AH (red), BL (green), BH (blue)
macro   SetPalette
{
                mov     dx,0x3C8
                out     dx,al
                inc     dx
                mov     al,ah
                out     dx,al                   ; red
                mov     al,bl
                out     dx,al                   ; green
                mov     al,bh
                out     dx,al                   ; blue
}
 
BarPos          dw      0                       ; position of gradient bar
BarPosDelta     dw      1                       ; direction (positive = down, negative = up)
 
;-----------------------------------------------------------------------------------------------------------------------
 
; Our IRQ 0 handler
TimerHandler:
                pusha
                push    ds
                push    cs
                pop     ds
                inc     [CurrentPart]
 
                mov     dx,0x3DA
                in      al,dx
                test    al,8
                jz      .noretrace                      ; jump if no vertical retracing
        @@:     in      al,dx
                test    al,1
                jnz     @B                              ; wait for first visible screen line
                xor     ax,ax
                mov     [CurrentPart],ax
                FirstPart
        .noretrace:
                mov     cx,[CurrentPart]
                NextPart
 
                mov     al,0x20
                out     0x20,al                 ; EOI
                pop     ds
                popa
                iret
 
; Set timer (channel 0) counter to DX clock cycles between IRQ 0 generations
TuneTimerClock:
                mov     al,0x34                 ; channel 0 write mode, counter mode 2
                out     0x43,al
                xchg    dx,ax
                out     0x40,al                 ; low byte of clock cycles
                mov     al,ah
                out     0x40,al                 ; high byte of clock cycles
                ret
 
; Read timer (channel 0) counter value into DX
ReadTimerValue:
                xor     al,al
                out     0x43,al                 ; channel 0 read mode
                in      al,0x40
                xchg    dx,ax
                in      al,0x40
                mov     dh,al
                ret
 
; Wait for vertical retrace start
VerticalRetrace:
                mov     dx,0x3DA
        @@:     in      al,dx
                test    al,8
                jz      @B
        @@:     in      al,dx
                test    al,8
                jnz     @B
                ret
 
CurrentPart     rw      1                       ; current part number
OrigTimerHandler rd     1                       ; original timer handler far address