Выводить координаты мышки по срабатыванию любой кнопки мышки каждый раз разными цветами

;выводить координаты мышки по срабатыванию любой клавиши мыши (пкм и лкм)
;причем разными цветами каждый раз , насколько я понял необходимо
;использовать прерывания мышки и для разных цветов прерывания видеоадаптера
.model small, Pascal
 
.stack 400h
 
.data
        ;коды клавиш
        KeyCode_Esc                     equ     1Bh     ;Esc
 
        ;Константы событий "мыши"
        MouseEvent_None                 equ     0000h   ;Удалить пользовательский обработчик
        MouseEvent_Move                 equ     0001h   ;любое перемещение
        MouseEvent_PressLeftButton      equ     0002h   ;нажатие левой кнопки
        MouseEvent_ReleaseLeftButton    equ     0004h   ;отпускание левой кнопки
        MouseEvent_PressRightButton     equ     0008h   ;нажатие правой кнопки
        MouseEvent_ReleaseRightButton   equ     0010h   ;отпускание правой кнопки
        MouseEvent_PressMiddleButton    equ     0020h   ;нажатие средней кнопки
        MouseEvent_ReleaseMiddleButton  equ     0040h   ;отпускание средней кнопки
 
        MouseInitOk                     equ     0FFFFh  ;инициализация мыши - успешна
        MouseInitFault                  equ     0000h   ;инициализация мыши - мышь или драйвер мыши не установлены
 
        MouseButtons_Any                equ     0000h   ;количество кнопок у мыши - отлично от 2 и 3
        MouseButtons_2                  equ     0002h   ;количество кнопок у мыши - 2
        MouseButtons_2_                 equ     0FFFFh  ;количество кнопок у мыши - 2
        MouseButtons_3                  equ     0003h   ;количество кнопок у мыши - 3
 
        ;сообщения программы
        msgMouseFault                   db      'The mouse or mouse driver was not detected.', 13, 10, '$'
        msgCoord                        db      'X: '
        strCoordX                       db      '12, Y: '
        strCoordY                       db      '12'
        lenCoord                        equ     $-msgCoord
        ;цвет выводимой строки
        strColor                        db      1
.code
 
;Ожидание нажатия клавиши на клавиатуре
;вход
; - нет
;выход
;ax - al - ASCII код нажатой клавиши, ah - скан-код
ReadKey         proc
        mov     ah,     00h
        int     16h
        ret
ReadKey         endp
 
;преобразование числа со знаком в строку
;на входе:
;  ax - число для преобразования
;  ds:di - адрес буфера строки
;на выходе:
;  строка
;  ax - длина строки
IntToStr        proc
        push    bx
        push    cx
        push    dx
        push    si
        push    di
 
        mov     bx,     10
        xor     cx,     cx      ;символов в модуле числа
        xor     si,     si      ;символов знака '-'
        or      ax,     ax
        jns     @@div
                neg     ax
                mov     [di],   byte ptr '-'
                inc     si
                inc     di
        @@div:
                xor     dx,     dx
                div     bx
                push    dx
                inc     cx      ;количество цифр в числе
                or      ax,     ax
        jnz     @@div
        mov     ax,     cx      ;длина строки возвращается в ax
        add     ax,     si
        @@store:
                pop     dx
                add     dl,     '0'
                mov     [di],   dl
                inc     di
        loop    @@store
 
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        ret
IntToStr        endp
 
;Инициализация работы с "мышью"
;Выполняется аппаратный и программный сброс мыши и драйвера
;вход
; - нет
;выход
;ax - результат инициализации
;   - 0000h, если мышь или драйвер мыши не установлены
;   - FFFFh, если драйвер и мышь установлены
;bx - число кнопок
;   - 0002 или FFFF - две
;   - 0003 - три
;   - 0000 - другое количество
MouseInit       proc
        mov     ax,     0000h
        int     33h
        ret
MouseInit       endp
 
;Показать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseShowCursor proc
        push    ax
        mov     ax,     0001h
        int     33h
        pop     ax
        ret
MouseShowCursor endp
 
;Спрятать курсор "мыши"
;вход
; - нет
;выход
; - нет
MouseHideCursor proc
        push    ax
        mov     ax,     0002h
        int     33h
        pop     ax
        ret
MouseHideCursor endp
 
;Определение курсора мыши в текстовом режиме
;вход
;BX = hardware/software text cursor
;     0000h software ( (char/attr AND CX) XOR DX)
;       CX = screen mask
;       DX = cursor mask
;     0001h hardware
;       CX = start scan line
;       DX = end scan line
;выход
; - нет
MouseDefineTextCursor   proc
        push    ax
        mov     ax,     000Ah
        int     33h
        pop     ax
        ret
MouseDefineTextCursor   endp
 
;Установить/удалить обработчик событий от "мыши"
;вход
;ES:DX = адрес обработчика
;СХ = условие вызова
;   бит 0 — любое перемещение мыши
;   бит 1 — нажатие левой кнопки
;   бит 2 — отпускание левой кнопки
;   бит 3 — нажатие правой кнопки
;   бит 4 — отпускание правой кнопки
;   бит 5 — нажатие средней кнопки
;   бит 6 — отпускание средней кнопки
;СХ = 0000h — отменить обработчик;выход
;выход
; - нет
MouseSetHandler proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    es
 
        mov     ax,     000Ch
        int     33h
 
        pop     es
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
MouseSetHandler endp
 
;Обработчик событий "мыши"
;вход
;АХ содержит условие вызова,
;ВХ - состояние кнопок,
;СХ, DX - X- и Y-координаты курсора,
;SI, DI - счетчики последнего перемещения по горизонтали и вертикали
;      (единицы измерения для этих счетчиков - мики, 1/200 дюйма),
;DS - сегмент данных драйвера мыши.
;выход
; - нет
MyMouseHandler  proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    si
        push    di
        push    ds
        push    es
 
        ;чтобы не было восстановления предыдущего состояния
        ;экрана после перемещения мыши, спрячем курсор
        call    MouseHideCursor
        ;Программы, работающие в текстовом режиме,
        ;должны разделить полученные координаты на 8
        ;(как координату X, так и координату Y).
        shr     cx,     1
        shr     cx,     1
        shr     cx,     1
        shr     dx,     1
        shr     dx,     1
        shr     dx,     1
        ;для работы с переменными программы и для вывода строки
        ;устанавливаем ds и es на сегмент данных программы
        mov     ax,     @data
        mov     ds,     ax
        mov     es,     ax
        ;преобразование чисел в строку
        mov     word ptr [strCoordX],   '  '
        mov     word ptr [strCoordY],   '  '
        mov     ax,     dx
        lea     di,     [strCoordY]
        call    IntToStr
        mov     ax,     cx
        lea     di,     [strCoordX]
        call    IntToStr
        ;вывод строки
        mov     ah,     0Fh             ;уточнение параметров видеорежима
        int     10h
        mov     ax,     1300h           ;функция вывода строки
        mov     bl,     [strColor]      ;bl - цвет текста
        ;mov     bh,     00h            ;страница видеопамяти, берётся из вызова справки
        mov     dl,     00              ;позиция X экрана (от 0)
        mov     dh,     00              ;позиция Y экрана (от 0)
        mov     cx,     lenCoord        ;длина строки
        mov     bp,     offset msgCoord ;в es:bp помещаем адрес начала строки
        int     10h
        ;изменение цвета строки для следующего вызова
        mov     al,     [strColor]
        inc     al
        and     al,     0Fh
        cmp     al,     1
        adc     al,     0
        mov     [strColor],     al
        ;после изменений на экране покажем курсор
        call    MouseShowCursor
@@Exit:
        pop     es
        pop     ds
        pop     di
        pop     si
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        retf
MyMouseHandler  endp
 
;основная программа
main            proc
        mov     ax,     @data
        mov     ds,     ax
 
        ;попытка инициализации мыши
        call    MouseInit
        cmp     ax,     MouseInitOk
        je      @@MouseInitOk
        ;если инициализация не удалась - вывести сообщение
        ;и завершить программу
        mov     ah,     09h
        lea     dx,     msgMouseFault
        int     21h
        jmp     @@mainExit
 
@@MouseInitOk:
        ;установить курсор
        mov     bx,     0       ;software cursor
        mov     cx,     0FFFFh  ;and mask
        mov     dx,     0FF00h  ;xor mask
        call    MouseDefineTextCursor
        ;показать курсор
        call    MouseShowCursor
        ;установить пользовательский обработчик событий "мыши"
        push    es
        mov     ax,     seg MyMouseHandler
        mov     es,     ax
        mov     dx,     offset  MyMouseHandler
        mov     cx,     MouseEvent_PressLeftButton
        call    MouseSetHandler
        pop     es
 
        ;цикл ожидания нажатия кнопки ESC
        ;в цикле проверяется работа обработчика мыши
@@WaitEscapePressed:
        call    ReadKey
        cmp     al,     KeyCode_Esc
        jne     @@WaitEscapePressed
 
        ;завершение работы с "мышью"
        ;спрятать курсор
        call    MouseHideCursor
        ;удалить пользовательский обработчик прерывания
        mov     cx,     MouseEvent_None
        call    MouseSetHandler
 
@@mainExit:
        mov     ax,     4C00h
        int     21h
main            endp
 
end     main

        .model  tiny
        .code
        org     100h
start: 
    ;;; 320x100 decimal dosbox 640x200 max (027f 00c7)
    
    ;mov bl, 04fh
    ;mov cx, 4
    ;mov ah, 9h
    ;int 10h
    
    
    mov ax, 1
    int 33h
    mov ax, 3
    int 33h
 
    
    
        
    mov ax, cx
    xchg    al, ah
    call ShowHex
    
    xchg    al, ah
    call ShowHex
 
 
    push    dx
        mov     dx, offset endl
        mov ah,2
 
    int     21h
    pop dx
    
    mov ax, dx
    xchg    al, ah
    call ShowHex
    xchg    al, ah
    call ShowHex
 
    ret
ShowHex:
 
first PROC 
        push ax
    push cx
    push dx
        mov     di, OFFSET asHex
        mov     cx, ax
        and     ax, 000fh
        mov     bx, OFFSET HexTabl
        xlat
        mov     [di+1], al
 
        mov     ax, cx
        and     ax, 00f0h
        mov     cl, 4
        shr     ax, cl
        xlat
        mov     [di], al
 
        mov     ah, 13h
        mov     al, 1
        mov bl,2h
        mov     bp, OFFSET asHex
        mov cx, gg -1- offset asHex ;
        
        mov dl, 10
mov dh, 7 
mov bh, 0
        int     10h
    
    pop dx
    pop cx
        pop ax
        ret
        first ENDP
    
HexTabl  db     '0123456789abcdef'
asHex    db     '00','$'
gg:
endl         db      0Dh, 0Ah, '$'
    end     start