Создать оверлейный модуль

.model  small
 
.stack  200h
 
ExecOverlayRec  struc
        wStartSeg       dw      ?
        wReloFactor     dw      ?
ExecOverlayRec  ends
 
.data
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        ;диагностические сообщения
        asErrResizeMem  db      "Resize memory block error", '$'
        asErrReleaseMem db      "Release memory block error", '$'
        asErrAllocMem   db      "Allocate memory block error", '$'
        asErrExec       db      "Exec failed", '$'
        ;имя оверлейного файла
        oname           db      'OVERLAY.OVL',0 ; pathname of overlay file
.data?
        pars            ExecOverlayRec  <?>
        entry           dd      ?               ; entry point for overlay
        stkseg          dw      ?               ; save SS register
        stkptr          dw      ?               ; save SP register
.code
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;освобождаем память
        ;когда процесс получает управление через функцию 4bH EXEC,
        ;вся доступная память уже распределена ему, поэтому освобождаем её часть сразу
        ;при запуске программы es и ds указывают на начало PSP
        mov     ax,     es
        mov     bx,     seg zseg ;по файлу .map видно что zseg начинается в самом конце
        sub     bx,     ax
        mov     ah,     4ah
        int     21h
        jnc     @@ResizeMemOk
                mov     ah,     09h
                lea     dx,     [asErrResizeMem]
                int     21h
                jmp     @@Exit
        @@ResizeMemOk:
                                ; allocate memory for overlay
        mov     bx,1000h        ; get 64 KB (4096 paragraphs)
        mov     ah,48h          ; function 48h = allocate block
        int     21h             ; transfer to MS-DOS
        jnc     @@AllocOk       ; jump if allocation failed
                mov     ah,     09h
                lea     dx,     [asErrAllocMem]
                int     21h
                jmp     @@Exit
        @@AllocOk:
 
        mov     [pars].wStartSeg,ax     ; set load address for overlay
        mov     [pars].wReloFactor,ax   ; set relocation segment for overlay
 
                                ; set segment of entry point
        mov     word ptr [entry+2],ax
        mov     word ptr [entry], 0
 
        mov     [stkseg],ss     ; save root's stack pointer
        mov     [stkptr],sp
 
        mov     ax,ds           ; set ES = DS
        mov     es,ax
 
        mov     dx,offset oname ; DS:DX = overlay pathname
        mov     bx,offset pars  ; ES:BX = parameter block
        mov     ax,4b03h        ; function 4bh, subfunction 03h
        int     21h             ; transfer to MS-DOS
 
        mov     ax,_DATA        ; make our data segment
        mov     ds,ax           ; addressable again
        mov     es,ax
 
        cli                     ; (for bug in some early 8088s)
        mov     ss,[stkseg]     ; restore stack pointer
        mov     sp,[stkptr]
        sti                     ; (for bug in some early 8088s)
 
        jnc     @@ExecOk        ; jump if EXEC failed
                mov     ah,     09h
                lea     dx,     [asErrExec]
                int     21h
                jmp     @@ReleaseMem
        @@ExecOk:
                                ; otherwise EXEC succeeded...
        push    ds              ; save our data segment
        call    dword ptr[entry]; now call the overlay
        pop     ds              ; restore our data segment
 
@@ReleaseMem:
        mov     ah,     49h
        mov     bx,     [pars].wStartSeg
        mov     es,     bx
        int     21h
@@Exit:
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        mov     ah,     00h
        int     16h
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
;сегмент для определения размеров программы
zseg    segment para use16
zseg    ends
 
end     main

.model tiny
 
.code
 
        org     100h
main    proc
 
        jmp     start
 
        ;Данные
        Hello           db      'Hello!', '$'
        CrLf            db      0Dh, 0Ah, '$'
 
start:
        ;программа
        push    ds
        push    cs
        pop     ds
 
        mov     ah,     09h
        lea     dx,     [Hello-100h]
        int     21h
 
        pop     ds
        ;завершение программы
        retf
main    endp
 
end     main