Форматированный вывод на консоль строки текста курсив+жирный+подчеркнутый

.model  medium
 
.stack  200h
 
.data
        ;цвет символов
        Black           equ     0
        Blue            equ     1
        Green           equ     2
        Cyan            equ     3
        Red             equ     4
        Magenta         equ     5
        Brown           equ     6
        LightGray       equ     7
        DarkGray        equ     8
        LightBlue       equ     9
        LightGreen      equ     10
        LightCyan       equ     11
        LightRed        equ     12
        LightMagenta    equ     13
        Yellow          equ     14
        White           equ     15
        ;сообщения об ошибках при работе с файлами
        errFileOpenRd   db      'File open (for read) error', '$'
        errFileOpenWr   db      'File open (for write) error', '$'
        errFileRead     db      'File read error', '$'
        errFileWrite    db      'File write error', '$'
        errFileClose    db      'File close error', '$'
        ;сообщения программы
        CrLf            db      0Dh, 0Ah, '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        ;имя файла загружаемого шрифта
        aszFileName     db      'MyFont.fnt', 0
        ;тестовая строка
        asString        db      'Test String '
        sLen            =       $-asString
.data?
        InFileHandler   dw      ?
        __BUF_SIZE__    equ     4096
        Buffer          db      __BUF_SIZE__ dup(?)
.code
 
;макрос для упрощения вызова процедур с параметрами
invoke  macro   CallProc, Params
        IRP     P, <Params>
                mov     ax,     P
                push    ax
        endm
        call    CallProc
endm
 
;вывод цветной строки на экран с текущей позиции
;на входе:
;  lpString - дальний указатель (сегмент+смещение) на строку
;  StrLen   - длина строки
;  Color    - цвет символов строки (атрибут)
ShowColorString proc    near
        lpString        equ     [bp+4]
        StrLen          equ     [bp+8]
        Color           equ     [bp+10]
        push    bp
        mov     bp,     sp
 
        push    ax
        push    bx
        push    cx
        push    dx
        push    bp
        push    es
 
        ;получение текущей позиции курсора
        mov     ah,     03h     ;читать позицию курсора
        mov     bh,     00h     ;для видеостраницы
        int     10h             ;выход: dh,dl - позиция курсора
        ;вывод строки
        mov     ax,     1301h   ;функция вывода строки
        mov     bx,     Color   ;bl - цвет текста, сразу меняем
        mov     bh,     00h     ;страница видеопамяти
        mov     dl,     dl      ;позиция X экрана (не меняем - используем текущую)
        mov     dh,     dh      ;позиция Y экрана (не меняем - используем текущую)
        mov     cx,     StrLen  ;длина строки
        les     bp,     lpString;в es:bp помещаем адрес начала строки
        int     10h
 
        pop     es              ;восстанавливаем регистры
        pop     bp
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        pop     bp
        ret     8
ShowColorString endp
 
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;загружаем файл со шрифтом в память
        mov     ax,     3D00h   ;открыть для чтения
        lea     dx,     [aszFileName]
        int     21h
        jnc     @@InFileOpenOk
                mov     ah,     09h
                lea     dx,     [errFileOpenRd]
                jmp     @@Exit
        @@InFileOpenOk:
        mov     [InFileHandler],        ax
        ;чтение из файла
        mov     ah,     3Fh
        mov     bx,     [InFileHandler]
        mov     cx,     __BUF_SIZE__
        lea     dx,     [Buffer]
        int     21h
        jnc     @@InFileReadOk
                ;если ошибка чтения - вывести диагностическое сообщение
                ;и прекратить обработку
                mov     ah,     09h
                lea     dx,     [errFileRead]
                int     21h
                jmp     @@Exit
        @@InFileReadOk:
        ;закрытие файла
        mov     ah,     3Eh
        mov     bx,     [InFileHandler]
        int     21h
        jnc     @@InFileCloseOk
                mov     ah,     09h
                lea     dx,     [errFileClose]
                int     21h
                jmp     @@Exit
        @@InFileCloseOk:
 
        ;загрузить шрифт из файла в знакогенератор в блок 1
        mov     ax,     1100h
        mov     bl,     01h     ;font block to load (0 to 4; 4 if 256K EGA memory)
        mov     bh,     16      ;count of bytes per character pattern (eg, 8 or 14)
        mov     cx,     256     ;кол-во симв в табл.
        mov     dl,     0;      ; код первого знака    -+
        mov     dh,     0       ;-----------------------+
        push    es              ; ES:BP адр начала табл.
        push    ds
        pop     es
        mov     bp,     offset Buffer
        int     10h
        pop     es
 
        ;устанавливает, шрифтом из какого блока памяти будет
        ;выводится текст в зависимости от цвета символа 0-7/8-15.
        ;Если цвет символа 0-7, то выбирается шрифт из блока NBlock,
        ;а если цвет фона символа 8-15, то выбирается шрифт из блока NBlockLight.
        ;Шрифты в блоки загружаются функциями 1100h, 1101h, 1102h, 1104h
        ;bl=NBlock OR (NBlockLight SHL 2)
        mov     ax,     1103h   ;int 10h, функция 11h, подфункция 03h
        mov     bl,     04h     ;основной шрифт будет при цвете 0-7,
                                ;дополнительный будет при цвете 8-15
                                ;биты 0...1 - для номера основного
                                ;биты 2...3 - для номера дополнительного
        int     10h
 
        ;демонстрация
        invoke  ShowColorString, <Yellow, sLen, ds, offset asString>
        invoke  ShowColorString, <Brown, sLen, ds, offset asString>
 
@@Exit:
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
        mov     ah,     00h
        int     16h
        ;установкой текстового режима сбрасывает настройки шрифтов
        mov     ax,     0003h
        int     10h
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main

;EGAITAL.COM
;Exploring the EGA, part 2 by Charles Petzold (PC magazine) (1986-09-16)
;This EGAITAL program will change your EGA font to italic.
.model tiny
 
.code
org     100h
main    proc
        cld
        mov     bh,     06h             ; get 8x16 font
        mov     ax,     1130h
        int     10h                     ; returns es:bp
        push    es
        pop     ds
        mov     si,     bp              ; ds:si points to font
        push    cs
        pop     es
        mov     di,     offset FontArea ; es:di = destination
        mov     bx,     0100h           ; number of characters
        MAINLOOP:
                mov     cx,     04h     ; MAINLOOP:
                call    SHIFTRIGHT      ; call SHIFTRIGHT
                call    SHIFTRIGHT      ; call SHIFTRIGHT
                call    SHIFTRIGHT      ; call SHIFTRIGHT
                call    SHIFTRIGHT      ; call SHIFTRIGHT
                call    SHIFTLEFT       ; call SHIFTLEFT
                call    SHIFTLEFT       ; call SHIFTLEFT
                call    SHIFTLEFT       ; call SHIFTLEFT
                call    SHIFTLEFT       ; call SHIFTLEFT
                dec     bx              ; decrement char count
        jnz     MAINLOOP                ; loop if not zero
        mov     bp,     offset FontArea ; point to font
        sub     dx,     dx              ; starting character
        mov     cx,     0100h           ; character count
        mov     bh,     10h             ; bytes per character
        mov     bl,     cs:[005Dh]
        and     bl,     03h             ; block to load
        mov     ax,     1100h           ; load font
        int     10h
        int     20h                     ; terminate
main    endp
 
SHIFTRIGHT      proc    near
        lodsw                           ; SHIFTRIGHT:
        shr     al,     cl
        shr     ah,     cl
        stosw                           ; and store
        dec     cl
        retn
SHIFTRIGHT      endp
 
SHIFTLEFT       proc    near
        lodsw                           ; SHIFTLEFT:
        shl     al,     cl
        shl     ah,     cl
        stosw                           ; and store
        inc     cl
        retn
SHIFTLEFT       endp
 
FontArea:
 
end     main