Считать с экрана строку, вывести эту строку в файл

    .model tiny
    .code
    org 100h
 
; ввод строки в переменную buf длиной buflen
input   macro buf,buflen
     local m1
     jmp short m1
buf  db buflen+1
     db 0
     db buflen+1 dup (0)
m1:  mov dx,offset buf ; ввод строки
     mov ah,0Ah
     int 21h
     endm
 
start:  jmp beg
okmess  db "File "
fname   db "textout.txt",0 ; имя вашего файла (не более 8 симв имени и 3 симв расширения)
        db "is written with success",13,10,"$"
fil dw 0 ; дескриптор файла
prompt  db "Input a string to save in file",13,10,">$"
mnotopen db "Cant create and open file",13,10,"$"
mwriterr db "Cant write data to file",13,10,"$"
crlf    db 13,10,"$"
beg:    push cs
    pop  ds
    push cs
    pop  ds
    mov  dx,offset prompt
    call prntext
    input txtbuf,70 ; ввести строку длиной до 70 символов
    mov dx,offset crlf
    call prntext
    mov dx,offset fname
    mov cx,0 ; атрибут файла
    mov ah,3Ch ; создать файл и открыть для чтения и записи
    int 21h
    jc  openerr
    mov fil,ax ; сохранить дескриптор файла
    mov si,offset txtbuf
    inc si
    lodsb
    mov cl,al ; cx=длина строки
    mov ch,0
    mov dx,si ; dx=адрес строки
    jcxz m1   ; не вызывать функцию записи при cx=0 (not trucate file length)
    mov bx,fil
    mov ah,40h ; записать данные
    int 21h
    jc  writerr
    cmp ax,cx  ; данные не записаны, возможно переполнен диск ?
    jnz writerr
m1: mov bx,fil
    cmp bx,0   ; если bx-0 то что-то не так - пропустить закрытие
    jz  m2
    mov ah,3eh ; закрыть файл
    int 21h
m2: mov dx,offset okmess ; всё нормально
    call prntext
exit:   mov ah,0 ; ожидание нажатия на клавишу
    int 16h
    mov ax,4C00h ; выход в Dos
    int 21h
openerr: mov dx,offset mnotopen ; файл не удалось создать
    call prntext
    jmp exit
writerr:mov dx,offset mwriterr ; файл не удалось записать
    call prntext
    mov bx,fil
    cmp bx,0
    jz  m2a
    mov ah,3eh ; закрыть файл
    int 21h
m2a:    jmp exit
prntext:mov ah,9
    int 21h
    ret
    end start