Программа очищает экран и вырезает в центре экрана инверсное окно разумных размеров

model small
 
stack 100h
 
dataseg
    char    db  ? ;сам символ
    posx    db  20 ;горизонтальная координата
    posy    db  6 ;вертикальная координата
codeseg
 
    startupcode
 
    ; очистка экрана
    call clear_scr
 
    ; ввод начального символа
input:  mov ah, 0
    int 16h
    cmp al, 0
    je input       ; если символ не введён, то запрашиваем снова
    mov char, al
 
    ; главный цикл
_loop:     call char_out; выводим символ на экран
 
    mov ah, 0   ; считываем код нажатой клавиши
    int 16h
    cmp al, 0   ; если это символ
 
 
    mov char, al    ; сохраняем его и проверяем условие выхода
    cmp ah, 43h
    jne _loop       ; если это F9
    jmp exit
 
 
exit:   call clear_scr
    mov ah, 4ch
    int 21h
 
    
clear_scr   proc near   ; функция очистки экрана
    mov ax, 0600h
    mov bh, 07h
    mov cx, 0000h
    mov dx, 184fh
    int 10h
clear_scr   endp
 
 
char_out proc near     ; вывод текущего символа
 
    mov ah, 02h     ; в указанной позиции
    mov bh, 0
    mov dh, posy
    mov dl, posx
    int 10h
 
    mov ah,7
    xor al,al
    mov bh,0f0h
    mov ch,6
    mov cl,20
    mov dh,12
    mov dl,30
    int 10h 
 
    mov ah, 09h
    mov bh, 0
    mov bl, 07h
    mov al, char
    mov cx, 1
    int 10h
    ret
 
char_out endp
 
end

; Программа очищает экран и вырезает в центре экрана инверсное окно разумных размеров.
; Далее, при нажатии любой символьной клавиши
; её отображение должно появляться внутри этого окна.
; Таким образом, окно постепенно заполняется вводимыми с клавиатуры символами.
; Заполнение окна происходит в общепринятом порядке: слева – направо – сверху - вниз.
; Программно проверить нажатие клавиши Left Сtrl
; Выход из программы по нажатию клавиши INSERT или при полном заполнении окна.
    .model small
    .code
 
retc    macro
    local m0
    jnc m0
    ret
m0:
    endm
 
cls macro
    mov ax,3
    int 10h
    endm
 
bordx=8 ; размер бордюра окна
bordy=4
x0  dw 0 ; коорд верхнего левого угла окна
y0  dw 0
x1  dw 0 ; коорд нижнего левого угла окна (+1)
y1  dw 0
xb  label byte
x   dw 0
yb  label byte
y   dw 0
char    db 32      ; символ кот заполняется окно
attr    db 16*1+15 ; атрибут кот заполняется окно
start:  mov ax,cs ; основная программа 
    mov ds,ax
    mov ax,0B800h ; сегмент видео памяти
    mov es,ax
    mov ax,3      ; режим 80*25 текст - стереть экран
    int 10h
    mov x0,bordx  ; задать коорд углов окна
    mov y0,bordy
    mov x1,80-bordx
    mov y1,25-bordy
    call fillwindow ; заполнить окно символом
    mov ax,x0
    mov x,ax
    mov ax,y0
    mov y,ax
m1: call setcursor
    call inpkey     ; ожидать ввода клавиши
    call outkey
    jmp m1
 
inpkey: mov ah,1 ; готовность клавиатуры (нажат символ)
    int 16h
    jnz in0  ; переход если нажат символ
    mov ah,12h ; опрос шифтовых клавиш
    int 16h
    test ah,1 ; левый Ctrl - выход Исп. правый Ctrl для ввода символов
    jnz in1
    jmp inpkey ; символ не нажат - ожидание
in0:    mov ah,0   ; читать нажатый символ
    int 16h
    cmp ah,82  ; Insert key
    jz in1
    cmp al,27  ; ESC key
    jz in1
    mov char,al ; char=символ
    ret
in1:    cls
    int 20h ; выход в Дос
 
fillwindow:     ; заполнить окно символом
    mov ax,x0
    mov x,ax
    mov ax,y0
    mov y,ax
nraw:   mov ax,y  ; найти адрес в видеопамяти
    mov bl,80 ; di=2*(80*y+x) - адрес в видеопамяти
    mul bl
    add ax,x
    add ax,ax
    mov di,ax
    mov al,char
    mov ah,attr
    mov cx,x1
    sub cx,x0
    rep stosw ; заполнить строку символами
    inc y     ; след строка
    mov ax,y
    cmp ax,y1 ; достигнута последняя строка ?
    jc nraw   ; конец цикла
    ret
 
outkey: mov ax,y  ; найти адрес в видеопамяти
    mov bl,80 ; di=2*(80*y+x) - адрес в видеопамяти
    mul bl
    add ax,x
    add ax,ax
    mov di,ax
    mov al,char
    mov ah,attr
    stosw     ; записать 1 символ
    inc x     ; продвинуть позицию курсора с учетом размеров окна
    mov ax,x
    cmp ax,x1
    retc
    mov ax,x0
    mov x,ax
    inc y
    mov ax,y
    cmp ax,y1
    retc
    cls       ; выход при полном заполнении окна
    int 20h 
 
setcursor:mov dl,xb
    mov dh,yb
    mov ah,2
    mov bh,0
    int 10h
    ret
 
    end start