Работа с графикой: нарисовать три вложенных квадрата

    .model small
    .code
 
include brez640.inc
 
; вывести прямоугольник
rectangle macro x0,y0,x1,y1,color
    invoke drawline,<x0,y0,x1,y0,color>
    invoke drawline,<x1,y0,x1,y1,color>
    invoke drawline,<x1,y1,x0,y1,color>
    invoke drawline,<x0,y1,x0,y0,color>
    endm
 
; вывести квадрат со строной размера siz
sq  macro x0,y0,siz,color
    rectangle x0,y0,x0+siz,y0+siz,color
    endm
 
; напечатать строку, используя прерывания int 10h BIOS
print   macro x,y,color,txt
    local m1,m2
    lea si,txt
    mov dh,y
    mov dl,x
    mov bh,0
    mov bl,color
m1: lodsb
    cmp al,0
    jz  m2
    mov ah,2 ; set cursor
    int 10h
    mov cx,1
    mov ah,9 ; print char
    int 10h
    inc dl
    jmp m1
m2:
    endm
 
txt db "Hello, world!",0
; основная программа
start:  mov ax,cs
    mov ds,ax
    mov es,ax
    mov ax,12h ; видео режим 640*480*16 цветов
    int 10h
    sq  10,10,460,13 ; квадрат со стороной 460 цветом 13
    print 10,15,14,txt ; текст
    mov ah,0 ; ожидание нажатия на клавишу
    int 16h
    mov ax,3 ; текстовый режим
    int 10h
    int 20h  ; выход в Дос
    end start

; аргументы вызова - координаты линии и цвет
; эти переменные заносятся в стек перед вызовом drawline
; см invoke
x1  equ word ptr [bp+12]
y1  equ word ptr [bp+10]
x2  equ word ptr [bp+8]
y2  equ word ptr [bp+6]
col equ byte ptr [bp+4]
 
; внутренние переменные drawline
; эти переменные существуют только в процессе работы drawline
deltaX  equ word ptr [bp-2]
deltaY  equ word ptr [bp-4]
signX   equ word ptr [bp-6]
signY   equ word ptr [bp-8]
er  equ word ptr [bp-10]
er2 equ word ptr [bp-12]
 
; вывод точки (VGA 640*480*16 цветов)
; x=cx, y=dx, color=al
erase   db 0
 
plot:   cmp erase,0
    jz  pl0
    mov al,0
pl0:    push di
    push es
    cmp cx,640 ; координаты выходят за границы экрана ?
    jnc pl1
    cmp dx,480
    jnc pl1
    push ax ; ---
    mov ax,80 ; di=80*y+(x/8)
    mul dx
    push cx
    rept 3
    shr cx,1
    endm
    add ax,cx
    mov di,ax
    pop cx
    and cl,7
    xor cl,7 ; CL= # of bits to shift left
 
; отрисовка в видео память
    mov ax,0A000h
    mov es,ax
 
; set Graphics Controller write mode 2
    mov dx,3CEh     ; GC address register port
    mov ah,1        ; AH= unshifted bit mask
    shl ah,cl       ; AH= bit mask in proper pos.
    mov al,8        ; AL= Bit register #
    out dx,ax
    mov ax,205h     ; AL= Mode register number
    out dx,ax       ; AH= Write Mode 2(bits 0,1)
                ;     Read Mode 0 (bit 3)
    mov ax,0003     ; AL= Function Select reg. # (code 0 - dot replace)
;   mov ah,3*8              ; (3*8 - dot XOR - code 3)
;   mov al,3
    out dx,ax       ; AH= read-modify-write bits
 
    pop ax ; ---
; чтение (в "защелки" VGA) затем запись
    xchg    al,es:[di]  ; выводим точку
 
; restore default Graphics Controller register value
    mov ax,0FF08h   ; default Bit Mask
    out dx,ax
    mov ax,0005     ; default Mode register
    out dx,ax
    mov ax,0003     ; default Function Select
    out dx,ax
 
pl1:    pop es
    pop di
    ret
 
; вывод линии
; SUB drawLine (x1, y1, x2, y2, col)
; Пример вызова:
; invoke drawline, <10,10,310,10,15>
 
drawline proc
    push bp   ; пролог Сохраняем bp в стеке
    mov bp,sp ; далее мы адресуем переменные с помощью bp
    sub sp,16 ; выделяем место под локальные переменные
    push ax
    push bx
    push cx
    push dx
;deltaX = ABS(x2 - x1)
    mov ax,x2
    sub ax,x1
    jge lin1
    neg ax
lin1:   mov deltaX,ax
;deltaY = ABS(y2 - y1)
    mov ax,y2
    sub ax,y1
    jge lin2
    neg ax
lin2:   mov deltaY,ax
;IF x1 < x2 THEN signX = 1 ELSE signX = -1
    mov bx,1
    mov ax,x1
    cmp ax,x2
    JL  lin3
    neg bx
lin3:   mov signX,bx
;iF y1 < y2 THEN signY = 1 ELSE signY = -1
    mov bx,1
    mov ax,y1
    cmp ax,y2
    JL  lin4
    neg bx
lin4:   mov signY,bx
;er = deltaX - deltaY
    mov ax,deltaX
    sub ax,deltaY
    mov er,ax
;PSET (x2, y2), col
    mov cx,x2
    mov dx,y2
    mov al,col
    call plot
; основной цикл построения линии
;WHILE (x1 <> x2) OR (y1 <> y2)
wil1:   mov ax,x1
    cmp ax,x2
    jnz wil2
    mov ax,y1
    cmp ax,y2
    jnz wil2
    jmp wend
wil2:   
;PSET (x1, y1), col
    mov cx,x1
    mov dx,y1
    mov al,col
    call plot
;er2 = er * 2
    mov ax,er
    add ax,ax
    mov er2,ax
;IF (er2 > -deltaY) THEN er = er - deltaY: x1 = x1 + signX
    mov ax,er2
    add ax,deltaY
    JLE lin5
    mov ax,er
    sub ax,deltaY
    mov er,ax
    mov ax,x1
    add ax,signX
    mov x1,ax
lin5:
;IF (er2 < deltaX) THEN er = er + deltaX: y1 = y1 + signY
    mov ax,er2
    cmp ax,deltaX
    jge lin6
    mov ax,er
    add ax,deltaX
    mov er,ax
    mov ax,y1
    add ax,signY
    mov y1,ax
;WEND
lin6:   jmp wil1
wend:   pop dx
    pop cx
    pop bx
    pop ax
    mov sp,bp ; эпилог, восстанавливаем sp
    pop bp    ; восстанавливаем bp
    ret 10    ; делаем возврат и продвигаем стек на 5*2=10 байт (т к 5 аргументов хранилось в стеке)
drawline endp
 
; макро вызова drawline См lst.lst, какой код генерит это макро
 
invoke macro CallProc,Params
    IRP P,<Params>
        mov ax, P
        push ax
        
    endm
    call CallProc
endm