Обработчик событий нажатия клавиш мыши

.model small
.stack 100h
 
.data
cursor_pos_x dw ?
cursor_pos_y dw ?
msg1 db '%$'
msg2 db '@$'
 
.code
start:
    mov ax, @data
    mov ds, ax
    
    ; инициализация прерывания INT 33h для обработки событий мыши
    mov ax, 0h
    int 33h
    
    ; бесконечный цикл ожидания событий мыши
    wait_for_mouse_event:
        ; ожидание событий мыши
        mov ax, 3h
        int 33h
        
        ; проверка кода события мыши
        cmp bx, 02h ; отпускание правой клавиши мыши
        je right_mouse_button_up
        
        cmp bx, 01h ; отпускание левой клавиши мыши
        je left_mouse_button_up
        
        jmp wait_for_mouse_event ; ожидание следующего события мыши
        
    right_mouse_button_up:
        ; сохранение координат курсора
        mov cursor_pos_x, cx
        mov cursor_pos_y, dx
        
        ; вывод символа "%"
        mov ah, 09h
        lea dx, msg1
        int 21h
        
        jmp wait_for_mouse_event ; ожидание следующего события мыши
        
    left_mouse_button_up:
        ; сохранение координат курсора
        mov cursor_pos_x, cx
        mov cursor_pos_y, dx
        
        ; вывод символа "@"
        mov ah, 09h
        lea dx, msg2
        int 21h
        
        jmp wait_for_mouse_event ; ожидание следующего события мыши
        
end start

; Разработать программу, выводящую символ «%» в позицию,
; в которой происходит отпускание правой клавиши мыши
; и символ «@» в позиции, в которой происходит отпускание левой клавиши мыши.
    .model small
    .code
    assume ds:_text
 
; вызов функций мыши
mouse   macro val
    mov ax,val
    int 33h
    endm
 
mouseShow macro
    mouse 1
    endm
 
mouseHide macro
    mouse 2
    endm
 
mousePoll macro
    mouse 3
    endm
 
lt_rel=4 ; биты событий мышки
rt_rel=16
 
; вывод сообщения об ошибке, если драйвер мыши не найден
emess   db "Error: mouse driver not found",13,10,"$"
exiterr:mov ax,3 ; вернуться в текстовый режим
    int 10h
    mov dx,offset emess ; печать сообщения
    mov ah,9
    int 21h
    mov ax,4C01h ; выход в DOS с кодом ошибки 1
    int 21h
 
; основная программа
start:mov ax,cs
    mov ds,ax
    mov es,ax
    mouse 0    ; инит мышку
    cmp ax,-1  ; драйвер мышки не найден - ошибка
    jnz exiterr
    mouseShow  ; показать мышку
    mov cx,lt_rel+rt_rel ; маска обработчика событий мышки
    mov dx,offset subr   ; dx=адрес обработчика событий
    mouse 0Ch
main:   mov ah,1 ; клавиша нажата ?
    int 16h
    jnz ex   ; да, выход из программы
    jmp main ; нет - ожидать в цикле
ex: mov ah,0 ; поглотить код клавиши
    int 16h
    mov cx,0 ; отключить обработчик событий мышки
    mouse 0Ch
    mouseHide ; скрыть мышку
    mov ax,4C00h ; выход в Дос
    int 21h
 
subr:   test ax,lt_rel ; обработчик событий - регистры можно не сохранять
    jnz do_lt
    test ax,rt_rel
    jnz do_rt
    retf ; дальний возврат из обработчика
 
do_lt:  mov al,"@" ; отпущена левая кнопка мышки
    jmp doit    
do_rt:  mov al,"%" ; отпущена правая кнопка мышки
doit:   rept 3     ; cx=cx/8, dx=dx/8 - координаты мышки в знакоместах
    shr cx,1
    shr dx,1
    endm
    push es
    push ax
    mov ax,80 ; di=80*dx+cx
    mov di,dx
    mul di
    mov di,ax
    add di,cx
    add di,di ; di=2*di - адрес курсора мышки в видео памяти
    mouseHide ; скрыть мышку
    mov ax,0B800h ; es=видео сегмент
    mov es,ax
    pop ax    ; восстан из стека al - символ, который надо изобразить
    mov ah,15 ; ah=атрибут символа (белый на чёрном)
    mov es:[di],ax ; занести символ в видео память
    pop es
    mouseShow ; показать мышку
    retf ; дальний возврат из обработчика
 
    end start