Посчитать выражение

print macro _addr
    mov ah, 09h
    lea dx, _addr
    int 21h
endm
 
print_file macro number_bytes, _addr
    mov ah, 40h
    mov bx, handle
    xor ch, ch
    mov cl, byte ptr number_bytes
    inc cl
    lea dx, _addr
    int 21h
endm
 
scan macro _addr
    mov ah, 0Ah
    lea dx, _addr
    int 21h
endm
 
_CharToStr macro arg1, arg2
    lea bx, arg1
    ifnb <arg2>
        mov al, arg2
    endif
    call CharToStr
    mov byte ptr[bx], ' '
endm
 
_StrToChar macro arg1, arg2, arg3
    lea bx, arg1
    add bx, 2
    call StrToChar
    jc arg3 
    ifnb <arg2>
        mov arg2, al
    endif
endm    
 
codesg segment 'code'
    assume cs:codesg, ds:codesg, ss:codesg
    org 100h
    main: jmp begin
        _A db ?
        _B db ?
        rez dw ?
        handle dw ?
        filename db 'test9.txt', 0
        mes1 db 13, 10, 'Invalid number!!!',13,10,'$'
        mes2 db 13, 10, 'Enter number A ( -129<A<128 ): $'
        len = $-mes2-2
        mes3 db 13, 10, 'Enter number B ( -129<A<128 ): $'
        mes4 db 13, 10, 'Result: $'
        len1 = $-mes4-2
        buffer db 7, ?, 7 dup('$')
        end_line db 13, 10,'$'
    begin: print mes2
        scan buffer
        _StrToChar buffer, _A, begin
        mov ah, 3ch
        mov cx, 0
        lea dx, filename
        int 21h
        mov handle, ax
        print_file len-2, mes2+2
        print_file buffer+1, buffer+2
        w_b: print mes3
            scan buffer
        _StrToChar buffer, _B, w_b
        print_file len, mes3
        print_file buffer+1, buffer+2
        mov cx, 6
        mov ax, 5
        mov bl, 5
        xor di, di
        _for: mul bl
            sub al, _B
            sbb ah, 0
            add di, ax
            jo _end
            inc bl
            mov ax, bx
        loop _for
        mov ax, 5
        imul di
        push ax
        sal _A, 2
        jo _end
        pop bx
        mov al, _A
        cbw
        add ax, bx
        mov rez, ax
        lea di, buffer+2
        call OutInt
        mov byte ptr[di], ' '
        mov byte ptr buffer+1, al
        print mes4
        print buffer+2
        print_file len1, mes4
        print_file buffer+1, buffer+2
        mov ah, 3eh
        mov bx, handle
        int 21h
    _end: int 20h
    
    ;вход в al-число в bx адрес буфера куда следует писать число
    CharToStr proc
        push dx
        push cx
        xor dx, dx
        xor cx, cx
        xor ah, ah
        mov dl, 10
        test al, 80h
        jz short __while
        mov byte ptr[bx], '-'
        inc bx
        neg al
        __while: div dl
            inc cx
            add ah, '0'
            push ax
            and ax, 0FFh
            jz break
        jmp __while
        break: pop ax
            mov [bx], ah
            inc bx
        loop break
        pop cx
        pop dx
        mov byte ptr[bx], '$'
        ret
    CharToStr endp
    
    OutInt proc
;; Проверяем число на знак.
  test    ax, ax
  jns     oi1
;
;; Если оно отрицательное, выведем минус и оставим его модуль.
  mov  cx, ax
    mov byte ptr[di], '-'
    inc di
  mov  ax, cx
  neg     ax
;; Количество цифр будем держать в CX.
oi1:  
    xor     cx, cx
    mov     bx, 10 ; основание сс. 10 для десятеричной и т.п.
oi2:
    xor     dx,dx
    div     bx
; Делим число на основание сс. В остатке получается последняя цифра.
; Сразу выводить её нельзя, поэтому сохраним её в стэке.
    push    dx
    inc     cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
    test    ax, ax
    jnz     oi2
    mov al, cl
oi3:
    pop     dx
; Извлекаем очередную цифру, переводим её в символ и выводим.
;; раскоментировать если основание сс > 10, т.е. для вывода требуются буквы
;   cmp     dl,9
;   jbe     oi4
;   add     dl,7
;oi4:
    add     dl, '0'
    mov byte ptr[di], dl
    inc di
; Повторим ровно столько раз, сколько цифр насчитали.
    loop    oi3
    ret
OutInt endp 
    
    
    ;вход в bx адрес строки в которой число - размер байт, строка заканчивается 0Dh символом
    ;выход число в al
    StrToChar proc
        push bx
        push dx
        push di
        push cx
        xor di, di
        mov ah, '-'
        cmp ah, byte ptr[bx]
        jne short unsigned
        inc bx
        mov cl, 1
        unsigned:
            xor ax, ax
            mov dl, 10
        _while: mov dh, [bx]
            cmp dh, 0Dh
            je k
            inc di
            mul dl
            jo _Err
            cmp al, 81h
            jae _Err
            cmp dh, '0'
            jb _Err
            cmp dh, '9'
            ja _Err
            and dh, 0Fh
            add al, dh
            jc _Err
            cmp al, 81h
            jae _Err
            Next: inc bx
        jmp _while
        k: mov dx, ax
        cmp cl, 1
        je short signed
        cmp dl, 7fh
        ja _Err
        or di, 0
        jz _Err
        jmp _Exit
        _Err: print mes1
            stc 
            jmp Exit
        signed: or di, 0
            jz _Err
            neg dl
        _Exit:clc
        Exit: mov al, dl
        pop cx
        pop di
        pop dx
        pop bx
        ret
    StrToChar endp
    
codesg ends
    end main