Соответствие между ATA Signals и адресами портов I/O

DeviceReady:           ;<----- функция проверки диска на готовность ---------|
       mov   dx,1F7h             ; регистр состояния первого канала
busy:  in    al,dx               ; читаем байт состояния..
       test  al,10001000b        ; проверяем в нём биты BSY(7) и DRQ(3) - должны быть 0.
       jnz   busy                ;   ..циклимся, если не нуль..
       test  al,01000000b        ; теперь проверяем бит DRDY(6) - должен быть 1.
       jz    busy                ;   ..циклимся, если нуль..
retn                             ; значит диск свободен - на выход!

; fasm-code
;------------
org  100h
jmp  start
 
mes0     db  13,10,' READY DEVICE: $'
mes1     db  13,10,'    SAVE DATA: $'
mes2     db  13,10,'  DEVICE NAME: $'
mes3     db  13,10,'SERIAL NUMBER: $'
mes4     db  13,10,'     FIRMWARE: $'
mOk      db  'OK! $'
mErr     db  'ERROR! $'
buff     db  512 dup(0)
 
start:   mov   dx,mes0            ;// = READY DEVICE =
         call  Message            ;
 
         call  DeviceReady        ; DX = 1F7h. ждём готовности мастера на первом..
         jnc   @ok                ; 
         mov   dx,mErr            ; CF=1 - ошибка!
         call  Message            ; 
         jmp   @exit              ; на выход..
 
@ok:     mov   dx,mOk             ; винт готов!
         call  Message            ;
         mov   dx,mes1            ;// = SAVE_DATA =
         call  Message            ;
;;;
         mov   dx,1f7h            ; 
         mov   al,0ECh            ;
         out   dx,al              ; код 'Device_Id' в 1F7h
         cld                      ; дефолтный direction (слева-направо)
         mov   di,buff            ; ES:DI для INSW (адрес приёмного буфера)
         mov   dx,1f0h            ; регистр данных
         mov   cx,256             ; сколько читать (512 байт, или 256 слов)
         rep   insw               ; читаем с порта словами! (в режиме PIO)
 
         mov   dx,1f7h            ; проверим последнюю операцию!
         in    al,dx              ;
         and   al,1               ; сбросим всё, кроме бита(ERR)
         jz    @next              ; если ERR=0
         mov   dx,mErr            ; иначе: ошибка и на выход!
         call  Message            ;
         jmp   @exit              ;
;;;
@next:   mov   dx,mOk             ; OK!
         call  Message            ;
         mov   dx,mes2            ; выводим из буфера "DEVICE-NAME"
         call  Message
         mov   si,buff            ; адрес начала буфера в DS:SI
         push  si si              ; (запомнить 2-раза)
         add   si,27*2            ; перемещаемся в нём на нужный адрес
         mov   cx,20              ; считать 20 слов (40 ascii символов)
         call  Print              ; Выводим инфу на экран
;;;
         mov   dx,mes3            ; выводим "SERIAL-NUMBER"
         call  Message            ;
         pop   si                 ; 
         add   si,10*2            ; адрес инфы в буфере
         mov   cx,10              ; считать 10 слов
         call  Print              ; выводим инфу на экран
;;;
         mov   dx,mes4            ; версия микрокода "FIRMWARE"
         call  Message            ;
         pop   si                 ;
         add   si,23*2            ; 
         mov   cx,4               ; считать 4 слова
         call  Print              ; выводим инфу на экран
 
@exit:   xor   ax,ax              ; ждём клаву..
         int   16h                ; 
         ret                      ; выйти в MS-DOS!!!
 
;//==========================================================|
;----- Функция вывода сообщений
Message:
       mov   ah,9
       int   21h
       ret
 
;----- Функция чтения ASCII-строк из буфера "Stuff"
Print: lodsw                 ; читаем в АХ словами
       xchg  ah,al           ; байты лежат наоборот, и нужно их поменять местами. 
       int   29h             ; выводим AХ на экран
       shr   ax,8            ;
       int   29h             ;
       loop  Print           ; мотаем цикл CX раз
ret
 
;----- Функция проверки диска на готовность
DeviceReady:
       mov   bx,4             ; три попытки
       mov   dx,1F6h          ; выбираем устройство
       mov   al,0E0h          ;   ..мастер на первом.
       out   dx,al            ;
       mov   dx,1F7h          ; регистр состояния
@busy: stc                    ; выставим флаг ошибки CF (set carry)
       mov   cx,-1            ; повторов для 'loop' (макс)
       loop  $                ; небольшая пауза (стоим на месте)
       dec   bx               ; уменьшить счётчик попыток!
       jz    @stop            ; выйти с флагом(cf), если три попытки кончились.
       in    al,dx            ; иначе: читаем байт-состояния из 1F7h
       test  al,10001000b     ; BSY и DRQ ???
       jnz   @busy            ;   ..нет готовности
       test  al,01000000b     ; DRDY ???
       jz    @busy            ;   ..нет готовности
       clc                    ; иначе: снять флаг ошибки(cf)
@stop: retn                   ; ОК (или ошибка)

DeviceReady:           ;<----- функция проверки диска на готовность ---------|
       mov   dx,1F7h             ; регистр состояния первого канала
busy:  in    al,dx               ; читаем байт состояния
       and   al,11001000b        ; выделяем в нём биты BSY(7), DRDY(6) и DRQ(3)
       cmp   al,01000000b        ; проверяем биты (BSY и DRQ должны быть 0, DRDY должен быть 1)
       jne   busy                ; циклимся, если совпадают
retn                             ; значит диск свободен - на выход!