Обработка отжатий

org 7c00h
start:
use16
 
mov ax,cs
mov ds,ax
mov ss,ax
mov es,ax
mov sp,-10
 
mov ax,203h
mov dh,0
mov cx,2
mov bx,m
int 13h
jc @f
 
jmp m
 
@@:
mov ax,5307h
mov cx,3
mov bx,1
int 15h
 
db (510-($-start)) dup 0
dw 0aa55h
 
; -------------------------------------------------------------------------
m:
mov ax,3
int 10h
 
cli
 
in al,70h
or al,80h
out 70h,al
 
mov al,11h
out 20h,al
out 0a0h,al
 
mov al,20h
out 21h,al
add al,8
out 0a1h,al
 
mov al,4
out 21h,al
mov al,2
out 0a1h,al
 
mov al,1
out 21h,al
out 0a1h,al
 
and al,0f8h
out 21h,al
and al,0eeh
out 0a1h,al
 
in al,92h
or al,2
out 92h,al
 
lgdt [Gdtr]
lidt [Idtr]
 
mov eax,cr0
or al,1
mov cr0,eax
 
jmp 8:P_M
 
; -------------------------------------------------------------------------
 
use32
 
P_M:
 
mov eax,10h
mov ds,ax
mov fs,ax
mov gs,ax
mov ss,ax
mov eax,18h
mov es,ax
 
in al,70h
and al,7fh
out 70h,al
 
xor edi,edi
xor eax,eax
mov ecx,400h
rep stosd
 
sti
 
@@:
hlt
cmp [key],1
jz switch_rm
jmp @b
 
; -------------------------------------------------------------------------
 
GP_handler:
mov edi,160*12+80
mov eax,('G'+0b00h) shl 16 + 'P'+0b00h
stosd
pop eax
iretd
 
; -------------------------------------------------------------------------
 
int8:
push ax
mov al,20h
out 20h,al
pop ax
 
iretd
 
; -------------------------------------------------------------------------
 
int9:
pushad
 
in al,60h
test al,al
jns @print
cmp al,0bah
jnz @f
cmp [capslock],2
jnz reset
and [capslock],0
jmp reset
 
@@:
sub al,0aah
jz @f
sub al,0ch
jnz reset
 
@@:
and [shift],0
jmp reset
 
@print:
mov [key],al
cmp al,3ah
jnz @f
inc [capslock]
jmp reset
 
@@:
cmp al,2ah
je @shift
cmp al,36h
jnz @f
 
@shift:
mov [shift],1
jmp reset
 
@@:
mov edi,[position]
mov ebx,asci_table
 
cmp al,0eh
jnz @n
test edi,edi
je reset
 
@@:
mov eax,edi
mov ebx,160
xor edx,edx
div ebx
test edx,edx
jnz @f
 
@return:
sub edi,2
cmp byte [es:edi],0dh
jnz @return
jmp @b
 
@@:
sub edi,2
mov word [es:edi],0
mov [position],edi
jmp reset
 
@n:
mov ah,[shift]
add ah,[capslock]
cmp ah,1
jnz @f
add ebx,len
 
@@:
xlatb
test al,al
je reset
cmp al,0dh
jnz @f
 
xor ah,ah
stosw
mov eax,[position]
mov ebx,160
xor edx,edx
div ebx
 
inc eax
mul ebx
mov [position],eax
jmp reset
 
@@:
 
mov ah,0eh
stosw
mov [position],edi
reset:
mov al,20h
out 20h,al
popad
 
iretd
 
; -------------------------------------------------------------------------
 
eoi:
mov al,20h
out 0a0h,al
out 20h,al
 
iretd
 
; -------------------------------------------------------------------------
switch_rm:
 
cli
 
in al,70h
or al,80h
out 70h,al
 
lidt [real_idt]
 
mov al,11h
out 20h,al
out 0a0h,al
 
mov al,8
out 21h,al
mov al,70h
out 0a1h,al
 
mov al,4
out 21h,al
mov al,2
out 0a1h,al
 
mov al,1
out 21h,al
out 0a1h,al
 
dec al
out 21h,al
out 0a1h,al
 
jmp 20h:switch
 
switch:
 
mov eax,cr0
and al,0feh
mov cr0,eax
 
jmp 0:@rm
 
@rm:
 
mov ax,cs
mov ss,ax
mov es,ax
mov ds,ax
mov fs,ax
mov gs,ax
 
in al,92h
and al,0fdh
out 92h,al
 
in al,70h
and al,7fh
out 70h,al
 
sti
use16
 
mov ax,1301h
mov cx,strlen
mov bp,string
mov bx,0eh
mov dx,300h
int 10h
 
xor ax,ax
int 16h
 
mov ax,1301h
mov cx,msglen
mov bp,msg
mov bx,0ah
mov dx,500h
int 10h
 
xor ax,ax
int 16h
 
cmp al,31h
je shutdown
 
; reboot
 
@@:
in al,64h
test al,2
jnz @b
 
mov al,0feh
out 64h,al
 
shutdown:
 
mov ax,5301h
xor bx,bx  
int 15h
mov ax,5308h
mov bx,1
mov cx,bx
int 15h
mov ax,530dh
mov bx,1
mov cx,bx
int 15h
mov ax,530fh
mov bx,1
mov cx,bx
int 15h
mov ax,530eh
xor bx,bx
mov cx,102h
int 15h  
 
mov ax,5307h
mov cx,3
mov bx,1
int 15h
 
; -------------------------------------------------------------------------
 
align 8
 
gdt:
dq 0
db -1,-1,0,0,0,10011010b,11001111b,0 ; code
db -1,-1,0,0,0,10010010b,11001111b,0 ; data
db -1,-1,0,80h,0bh,10010010b,01000000b,0 ; video
db -1,-1,0,0,0,10011010b,0,0 ; real mode
 
Gdtr:
dw Gdtr-gdt-1
dd gdt
 
align 8
 
idt:
dq 13 dup 0
dw GP_handler,8,1000111000000000b,0
dq 18 dup 0
dw int8,8,1000111000000000b,0
dw int9,8,1000111000000000b,0
dq 6 dup 0
dw 9 dup  (eoi,8,1000111000000000b,0)
 
Idtr:
dw idt-Idtr-1
dd idt
 
real_idt: 
dw 3ffh
dd 0
 
shift db 0
capslock db 0
position dd 0
string db 'REAL MODE'
strlen = $-string
key db 0
msg db 'SHUTDOWN'
msglen = $-msg
asci_table db 0,0,'1234567890-=',0,0,'qwertyuiop[]',0dh,0,'asdfghjkl;"`',0,'\zxcvbnm,./',0,0,0,20h,44 dup (0)
len=$-asci_table
db 0,0,'!@#$%^&*()_+',0,0,'QWERTYUIOP{}',0dh,0,"ASDFGHJKL:'~",0,'|ZXCVBNM<>?',0,0,0,20h,44 dup (0)
 
db (1536-($-m)) dup 0