Функция WinAPI CopyFile

call    CopyFile,offset intext,esi,0

tasm32 /ml copyfile.asm
tlink32 /Tpe /ap /c /x copyfile.obj
copyfile.exe inf.txt out.txt
pause

include typefile.inc
.386
.model FLAT,STDCALL
.data
infile          dd      ?
outfile         dd      ?
buf             db      100 dup(0)
bufer           db      300 dup(0)
numb            dd      ?
numw            dd      ?
nameout         db      'CONOUT$'
intext          db      'inf.txt',0
outext          db      'out.txt',0
.code
_start:         call    GetCommandLine          
                mov     esi,eax
                xor     ecx,ecx                 
                mov     edx,1                   
n1:             cmp     byte ptr [esi],0        
                je      end_                    
                cmp     byte ptr [esi],32       
                je      n3
                add     ecx,edx
                cmp     ecx,3                   
                je      n4
                xor     edx,edx
                jmp     n2
n3:             or      edx,1   
n2:             inc     esi
                jmp     n1
n4:             call    CopyFile,offset intext,esi,0
end_:           call    ExitProcess,0
end     _start

includelib      import32.lib
 
; имена используемых функций из kernel32.dll
                extrn   ExitProcess:near
                extrn   GetCommandLineA:near
                extrn   CreateFileA:near
                extrn   CloseHandle:near
                extrn   ReadFile:near
                extrn   WriteFile:near
                extrn   MoveFileA:near
                extrn   CopyFileA:near
; присваивания для облегчения читаемости кода
        GetCommandLine  equ     GetCommandLineA
        CreateFile      equ     CreateFileA
        CopyFile        equ     CopyFileA
; определения констант и типов
STD_OUTPUT_HANDLE               equ     -11
GENERIC_READ                    equ     80000000h
GENERIC_WRITE                   equ     40000000h
OPEN_EXISTING                   equ     3

;
.386
.MODEL FLAT, STDCALL
OPTION CASEMAP: NONE
;
IncLib MACRO LibFn
INCLUDE \Masm32\INCLUDE\LibFn.INC
INCLUDELIB \Masm32\LIB\LibFn.LIB
ENDM
;
INCLUDE \Masm32\INCLUDE\Windows.INC
IncLib Kernel32
IncLib User32
IncLib Masm32
;
copyFile    PROTO
getArg      PROTO ArgIndex:Dword, pchBuf:PSTR, pszNotFound:PSTR
;
CR          EQU   0Dh
LF          EQU   0Ah
;
OwnFnameInd EQU   0
SrcFnameInd EQU   OwnFnameInd + 1
DstFnameInd EQU   SrcFnameInd + 1
;
.DATA
szAppName   CHAR  "Test of CopyFile WinAPI Function", CR, LF, 0
szNoSrc     CHAR  " no source file name", CR, LF, 0
szNoDst     CHAR  " no destination file name", CR, LF, 0
szOpenQuot  CHAR  " non matching quotation marks", CR, LF, 0
szEmptQuot  CHAR  " no argument or empty quotation marks", CR, LF, 0
szFail      CHAR  " copying failed", CR, LF, 0
szDone      CHAR  " done"
szCrLf      CHAR  CR, LF, 0
;
.DATA?
chFnSrc     CHAR  MAX_PATH Dup(?)
chFnDst     CHAR  MAX_PATH Dup(?)
;
.CODE
START:
      INVOKE StdOut, Addr szAppName       ; Function from Masm32 Lib
      INVOKE copyFile
      INVOKE ExitProcess, EAX
;
copyFile PROC Uses EBX EDI
; Return: EAX = ExitCode
LOCAL pcherrbuf:PSTR
      XOR   EBX, EBX                      ; No Error Exit Code
      XOR   EDI, EDI                      ; pErrMsg
      INVOKE getArg, SrcFnameInd, Addr chFnSrc, Addr szNoSrc
      JC    error
      INVOKE getArg, DstFnameInd, Addr chFnDst, Addr szNoDst
      JC    error
      INVOKE CopyFile, Addr chFnSrc, Addr chFnDst, TRUE
      LEA   EDX, szDone
      TEST  EAX, EAX
      JNZ   showresult                    ; OK
      INVOKE GetLastError
      TEST  EAX, EAX
      JZ    copyerr
      MOV   EDX, EAX
      INVOKE FormatMessage, FORMAT_MESSAGE_ALLOCATE_BUFFER Or FORMAT_MESSAGE_FROM_SYSTEM Or \
            FORMAT_MESSAGE_MAX_WIDTH_MASK, 0, EDX, LANG_NEUTRAL OR (SUBLANG_NEUTRAL Shl 10), \
            Addr pcherrbuf,  0, 0
      TEST  EAX, EAX
      JZ    copyerr
      MOV   EDI, pcherrbuf
copyerr:
      LEA   EDX, szFail
error:
      INC   EBX                           ; Error Exit Code
showresult:
      INVOKE StdOut, EDX
      TEST  EDI, EDI
      JZ    exit
      INVOKE CharToOem, EDI, EDI
      INVOKE StdOut, EDI
      INVOKE StdOut, Addr szCrLf
      INVOKE LocalFree, EDI
exit:
      MOV   EAX, EBX
      RET
copyFile ENDP
;
getArg PROC argind:Dword, pchbuf:PSTR, psznotfound:PSTR
; Return: if error CF is set, EDX = error msg address
      INVOKE GetCL, argind, pchbuf        ; Function from Masm32 Lib
      CLC
      DEC   EAX
      JZ    exit                          ; OK
      MOV   EDX, psznotfound
      DEC   EAX
      JZ    error
      LEA   EDX, szOpenQuot
      DEC   EAX
      JZ    error
      LEA   EDX, szEmptQuot
error:
      STC
exit:
      RET
getArg ENDP
;
      END    START
;