[masm32] Графика на ассемблере (рекурсия)

; #########################################################################
 
      .386
      .model flat, stdcall  ; 32 bit memory model
      option casemap :none  ; case sensitive
 
;     include files
;     ~~~~~~~~~~~~~
      include D:\MASM32\INCLUDE\windows.inc
      include D:\MASM32\INCLUDE\masm32.inc
      include D:\MASM32\INCLUDE\gdi32.inc
      include D:\MASM32\INCLUDE\user32.inc
      include D:\MASM32\INCLUDE\kernel32.inc
      include D:\MASM32\INCLUDE\Comctl32.inc
      include D:\MASM32\INCLUDE\comdlg32.inc
      include D:\MASM32\INCLUDE\shell32.inc
 
;     libraries
;     ~~~~~~~~~
      includelib D:\MASM32\LIB\masm32.lib
 
      includelib D:\MASM32\LIB\gdi32.lib
      includelib D:\MASM32\LIB\user32.lib
      includelib D:\MASM32\LIB\kernel32.lib
      includelib D:\MASM32\LIB\Comctl32.lib
      includelib D:\MASM32\LIB\comdlg32.lib
      includelib D:\MASM32\LIB\shell32.lib
 
; #########################################################################
 
        ;=================
        ; Local prototypes
        ;=================
        WinMain         PROTO :DWORD,:DWORD,:DWORD,:DWORD
        WndProc         PROTO :DWORD,:DWORD,:DWORD,:DWORD
        TopXY           PROTO :DWORD,:DWORD
        FillBuffer      PROTO :DWORD,:DWORD,:BYTE
        Paint_Proc      PROTO :DWORD,:DWORD
        Paint_Rectangles        PROTO :DWORD,:DWORD,:DWORD,:DWORD,:DWORD,:DWORD
 
      ;=============
      ; Local macros
      ;=============
 
      ;
      m2m MACRO M1, M2
        push M2
        pop  M1
      ENDM
 
      return MACRO arg
        mov eax, arg
        ret
      ENDM
 
    .data
        szDisplayName   db "Recursive Rectangles",0
        CommandLine     dd      0
        hWnd            dd      0
        hInstance       dd      0
        hIcon           dd      0
 
        szClassName     db      "GDIs_Class", 0
 
        cxClient        dw      0
        cyClient        dw      0
 
        iMaxDepth       dd      4
 
; ########################### Inserted modules ############################
 
; #########################################################################
 
.code
 
start:
      invoke GetModuleHandle, NULL
      mov hInstance, eax
 
      invoke GetCommandLine
      mov CommandLine, eax
 
      invoke WinMain,hInstance,NULL,CommandLine,SW_SHOWDEFAULT
      invoke ExitProcess,eax
 
; #########################################################################
 
WinMain proc hInst     :DWORD,
             hPrevInst :DWORD,
             CmdLine   :DWORD,
             CmdShow   :DWORD
 
      ;====================
      ; Put LOCALs on stack
      ;====================
 
      LOCAL wc   :WNDCLASSEX
      LOCAL msg  :MSG
      LOCAL Wwd  :DWORD
      LOCAL Wht  :DWORD
      LOCAL Wtx  :DWORD
      LOCAL Wty  :DWORD
 
      ;==================================================
      ; Fill WNDCLASSEX structure with required variables
      ;==================================================
 
      invoke LoadIcon,hInst,0    ; icon ID (0-System ID)
      mov hIcon, eax
 
      mov wc.cbSize,         sizeof WNDCLASSEX
      mov wc.style,          CS_BYTEALIGNWINDOW+CS_HREDRAW+CS_VREDRAW
      mov wc.lpfnWndProc,    offset WndProc
      mov wc.cbClsExtra,     NULL
      mov wc.cbWndExtra,     NULL
      m2m wc.hInstance,      hInst
      mov wc.hbrBackground,  COLOR_BTNFACE+1
      mov wc.lpszMenuName,   NULL
      mov wc.lpszClassName,  offset szClassName
      m2m wc.hIcon,          hIcon
      invoke LoadCursor,NULL,IDC_ARROW
      mov wc.hCursor,        eax
      m2m wc.hIconSm,        hIcon
 
      invoke RegisterClassEx, ADDR wc
 
      ;================================
      ; Centre window at following size
      ;================================
 
      mov Wwd, 600
      mov Wht, 480
 
      m2m cxClient, Wwd
      m2m cyClient, Wht
 
      invoke GetSystemMetrics,SM_CXSCREEN
      invoke TopXY,Wwd,eax
      mov Wtx, eax
 
      invoke GetSystemMetrics,SM_CYSCREEN
      invoke TopXY,Wht,eax
      mov Wty, eax
 
      invoke CreateWindowEx,WS_EX_LEFT,
                            ADDR szClassName,
                            ADDR szDisplayName,
                            WS_OVERLAPPEDWINDOW,
                            Wtx,Wty,Wwd,Wht,
                            NULL,NULL,
                            hInst,NULL
      mov   hWnd,eax
 
      invoke LoadMenu,hInst,600  ; menu ID
      invoke SetMenu,hWnd,eax
 
      invoke ShowWindow,hWnd,SW_SHOWNORMAL
      invoke UpdateWindow,hWnd
 
      ;===================================
      ; Loop until PostQuitMessage is sent
      ;===================================
 
    StartLoop:
      invoke GetMessage,ADDR msg,NULL,0,0
      cmp eax, 0
      je ExitLoop
      invoke TranslateMessage, ADDR msg
      invoke DispatchMessage,  ADDR msg
      jmp StartLoop
    ExitLoop:
 
      return msg.wParam
 
WinMain endp
 
; #########################################################################
 
WndProc proc hWin   :DWORD,
             uMsg   :DWORD,
             wParam :DWORD,
             lParam :DWORD
 
    LOCAL var    :DWORD
    LOCAL caW    :DWORD
    LOCAL caH    :DWORD
    LOCAL Rct    :RECT
    LOCAL hDC    :DWORD
    LOCAL Ps     :PAINTSTRUCT
    LOCAL buffer1[128]:BYTE  ; these are two spare buffers
    LOCAL buffer2[128]:BYTE  ; for text manipulation etc..
 
    .if uMsg == WM_COMMAND
    ;======== menu commands ========
    .elseif uMsg == WM_CREATE
 
    .elseif uMsg == WM_SIZE
        push eax
        push ebx
        mov eax, lParam
        mov cxClient, ax
        shr eax, 16
        mov cyClient, ax
        pop ebx
        pop eax
        return 0
    .elseif uMsg == WM_PAINT
        invoke BeginPaint,hWin,ADDR Ps
          mov hDC, eax
          invoke Paint_Proc,hWin,hDC
        invoke EndPaint,hWin,ADDR Ps
        return 0
 
    .elseif uMsg == WM_CLOSE
 
    .elseif uMsg == WM_DESTROY
        invoke PostQuitMessage,NULL
        return 0
    .endif
 
    invoke DefWindowProc,hWin,uMsg,wParam,lParam
 
    ret
 
WndProc endp
 
; ########################################################################
 
TopXY proc wDim:DWORD, sDim:DWORD
 
    shr sDim, 1      ; divide screen dimension by 2
    shr wDim, 1      ; divide window dimension by 2
    mov eax, wDim    ; copy window dimension into eax
    sub sDim, eax    ; sub half win dimension from half screen dimension
 
    return sDim
 
TopXY endp
 
; #########################################################################
 
Paint_Proc proc hWin:DWORD, hDC:DWORD
 
    LOCAL hPen      :DWORD
    LOCAL hPenOld   :DWORD
    LOCAL hBrush    :DWORD
    LOCAL hBrushOld :DWORD
 
    LOCAL lb        :LOGBRUSH
 
    LOCAL iXc       :DWORD
    LOCAL iYc       :DWORD
    LOCAL iSize     :DWORD
 
 
    invoke CreatePen,0,1,000000FFh  ; red
    mov hPen, eax
 
    mov lb.lbStyle, BS_SOLID
    mov lb.lbColor, 00FF0000h       ; blue
    mov lb.lbHatch, NULL
 
    invoke CreateBrushIndirect,ADDR lb
    mov hBrush, eax
 
    invoke SelectObject,hDC,hPen
    mov hPenOld, eax
 
    invoke SelectObject,hDC,hBrush
    mov hBrushOld, eax
 
  ; ------------------------------------------------
  ; The paint rectangles
  ; ------------------------------------------------
 
    push eax
    mov eax, 0
    mov ax, cxClient
    shr ax, 1
    mov iXc, eax
 
    mov eax, 0
    mov ax, cyClient
    shr ax, 1
    mov iYc, eax
 
    mov eax, 0          ;iSize=min(cxClient, cyClient)
    mov ax, cxClient
    mov iSize, eax
    mov ax, cyClient
    sub eax,iSize
    sbb ebx,ebx
    and ebx,eax
    add iSize,ebx
    mov eax, iSize
    shr eax, 2
    mov iSize, eax
    pop eax
 
    invoke Paint_Rectangles, hDC, hPen, iXc, iYc, iSize, 1
 
  ; ------------------------------------------------
 
    invoke SelectObject,hDC,hBrushOld
    invoke DeleteObject,hBrush
 
    invoke SelectObject,hDC,hPenOld
    invoke DeleteObject,hPen
 
    ret
 
Paint_Proc endp
 
; iXc, iYc - координаты центра квадрата
; iR - длина половины стороны квадрата
; iDepth - текущая глубина рекурсии
Paint_Rectangles        proc    hDC:DWORD, hPen:DWORD, iXc:DWORD, iYc:DWORD, iR:DWORD, iDepth:DWORD
        LOCAL   nLeftRect       :DWORD
        LOCAL   nTopRect        :DWORD
        LOCAL   nRightRect      :DWORD
        LOCAL   nBottomRect     :DWORD
        push    eax
        push    ebx
        push    ecx
        push    edx
 
        mov     eax,    iDepth
        cmp     eax,    iMaxDepth
        jae     @@Paint
        inc     eax
        ;Rectangle(x+r,y+r,r div 2);
        mov     ebx,    iXc
        add   ebx,  iR
        mov     ecx,    iYc
        add   ecx,  iR
        mov     edx,    iR
        shr     edx,    1
        invoke  Paint_Rectangles, hDC, hPen, ebx, ecx, edx, eax
 
        ;Rectangle(x+r,y-r,r div 2);
        mov     ebx,    iXc
        add   ebx,  iR
        mov     ecx,    iYc
        sub   ecx,  iR
        mov     edx,    iR
        shr     edx,    1
        invoke  Paint_Rectangles, hDC, hPen, ebx, ecx, edx, eax
 
        ;Rectangle(x-r,y+r,r div 2);
        mov     ebx,    iXc
        sub   ebx,  iR
        mov     ecx,    iYc
        add   ecx,  iR
        mov     edx,    iR
        shr     edx,    1
        invoke  Paint_Rectangles, hDC, hPen, ebx, ecx, edx, eax
        ;Rectangle(x-r,y+r,r div 2);
        mov     ebx,    iXc
        sub   ebx,  iR
        mov     ecx,    iYc
        sub   ecx,  iR
        mov     edx,    iR
        shr     edx,    1
        invoke  Paint_Rectangles, hDC, hPen, ebx, ecx, edx, eax
 
@@Paint:
        mov     eax,    iXc
        sub     eax,    iR
        mov     nLeftRect,      eax
        mov     eax,    iYc
        sub     eax,    iR
        mov     nTopRect,       eax
        mov     eax,    iXc
        add     eax,    iR
        mov     nRightRect,     eax
        mov     eax,    iYc
        add     eax,    iR
        mov     nBottomRect,    eax
 
        invoke  Rectangle, hDC, nLeftRect, nTopRect, nRightRect, nBottomRect
        pop     edx
        pop     ecx
        pop     ebx
        pop     eax
    ret
Paint_Rectangles endp
; ########################################################################
 
end start