Ошибка при компиляции

.386
.model flat,stdcall
option casemap :none  
 
include windows.inc
include user32.inc
include kernel32.inc
 
includelib user32.lib
includelib kernel32.lib
 
 
.data
FileName            db  "readme.txt",0
CryptFile           db  "Crypt.txt",0                
DecryptFile     db  "Decrypt.txt",0    
hFileRead           dd  ?              
hFileWriteEn        dd  ?     
hFileWriteDe        dd  ?     
read                dd  ?   
szFile                          dd  ?          
N1              dd  ?
N2              dd  ?     
S               dd  ?
dCRC32          dd  -1  ;начальное значение CRC32
fcrc32          db  FALSE
Sbox                db  4,10,9,2,13,8,0,14,6,11,1,12,7,15,5,3
                db  14,11,4,12,6,13,15,10,2,3,8,1,0,7,5,9
                db  5,8,1,13,10,3,4,2,14,15,12,7,6,0,9,11
                db  7,13,10,1,0,8,9,15,14,4,6,12,11,2,5,3
                db  6,12,7,1,5,15,13,8,4,10,9,14,0,3,11,2
                db  4,11,10,0,7,2,1,13,3,6,8,5,9,12,15,14
                db  13,11,4,1,3,15,5,9,0,10,14,7,6,8,2,12
                db  1,15,13,0,5,7,10,4,9,2,3,14,6,11,8,12
                
key             dd  31h,32h,33h,34h,35h,36h,37h,38h
fBuff               dd  1024 dup (0)    ; 4Кб буфер для считывания файла 
conHandle       dd  ?
fmt             db  '%X',0
msgcrc32            db  13,10,16 dup (0)
.code
start:
    invoke GetStdHandle,STD_OUTPUT_HANDLE
    mov conHandle,eax
    ;Открываем файл для чтения
    invoke CreateFile,addr  FileName,GENERIC_ALL,0,NULL,OPEN_EXISTING,FILE_ATTRIBUTE_READONLY,NULL
    mov hFileRead,eax
    ;взять размер файла
    invoke GetFileSize,hFileRead,NULL
    mov szFile,eax
    mov     ebx,8
    xor     edx,edx
    div     ebx         ;разделить размер файла на 8
    test    edx,edx
    jne @exit       ;если размер файла не кратен 8,на выход
    
    ;Открываем файл для записи
    invoke CreateFile,addr CryptFile,GENERIC_ALL,0,NULL,CREATE_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
    mov hFileWriteEn,eax
    
    mov eax,szFile
    mov ebx,4096
    xor edx,edx
    div ebx
    test    eax,eax
    je  @rest
    push    edx
    mov ecx,eax
    @@:
        push    ecx
        invoke ReadFile,hFileRead,addr fBuff,4096,addr read,NULL
        mov ecx,4096
        call    CRC32
        mov dCRC32,eax
        pop ecx
    loop    @b
    pop edx
@rest:
    push    edx
    invoke ReadFile,hFileRead,addr fBuff,edx,addr read,NULL
    mov fcrc32,TRUE
    pop ecx
    call    CRC32
    mov dCRC32,eax      ;CRC32 файла
    
    invoke  wsprintf,addr msgcrc32+2,addr fmt,eax
    INVOKE WriteConsole,conHandle,ADDR msgcrc32, sizeof msgcrc32,ADDR read,0                    
        
  
    invoke SetFilePointer,hFileRead,0,NULL,FILE_BEGIN
    ;зашифровать файл
    mov eax,szFile
    mov ebx,8
    xor edx,edx
    div ebx
    mov ecx,eax
    @@:
        push    ecx
        invoke ReadFile,hFileRead,addr N1,8,addr read,NULL
        call    Encrypt
        invoke WriteFile,hFileWriteEn,addr N1,8,addr read,NULL  
        pop ecx
    loop    @b
    invoke CloseHandle,hFileRead
    
    ;Открываем файл для записи
    invoke CreateFile,addr DecryptFile,GENERIC_ALL,0,NULL,CREATE_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
    mov hFileWriteDe,eax
    
    invoke SetFilePointer,hFileWriteEn,0,NULL,FILE_BEGIN
    ;расшифровать файл
    mov eax,szFile
    mov ebx,8
    xor edx,edx
    div ebx
    mov ecx,eax
    @@:
        push    ecx
        invoke ReadFile,hFileWriteEn,addr N1,8,addr read,NULL
        call    Decrypt
        invoke WriteFile,hFileWriteDe,addr N1,8,addr read,NULL  
        pop ecx
    loop    @b       
 
    invoke GetFileSize,hFileWriteDe,NULL
    mov szFile,eax
    
    mov eax,szFile
    mov ebx,4096
    xor edx,edx
    div ebx
    test    eax,eax
    je  @derest
    push    edx
    mov ecx,eax
    @@:
        push    ecx
        invoke ReadFile,hFileWriteDe,addr fBuff,4096,addr read,NULL
        mov ecx,4096
        call    CRC32
        mov dCRC32,eax
        pop ecx
    loop    @b
    pop edx
@derest:
    push    edx
    invoke ReadFile,hFileWriteDe,addr fBuff,edx,addr read,NULL
    mov fcrc32,TRUE
    pop ecx
    call    CRC32
    mov dCRC32,eax      ;CRC32 файла
    
    INVOKE WriteConsole,
    conHandle,        ; console output handle
    ADDR msgcrc32,       ; string pointer
    sizeof msgcrc32,                ; string length
    ADDR read,          ; returns num bytes written
    0                     ; not used
    
    invoke CloseHandle,hFileWriteEn
    invoke CloseHandle,hFileWriteDe
@exit:
        invoke ExitProcess, NULL
 
Function    proc
    push    ecx
;Шаг 1.  
;   Сложение с ключом. 
;   Младшая половина преобразуемого блока складывается по модулю 2^32
;   с используемым на шаге элементом ключа,результат передается на следующий шаг
    mov eax,N1
    add eax,[edx]       
    mov S,eax
    
;Шаг 2.  
;   Поблочная замена.  
;   32-битовое значение,полученное на предыдущем шаге,интерпретируется как массив из восьми 4-битовых
;   блоков кода:  S = (S0,S1,S2,S3,S4,S5,S6,S7).
;   Далее значение каждого из восьми блоков заменяется новым, которое выбирается по таблице
;   замен следующим образом: 
;   значение блока  Si меняется на  Si-тый по порядку элемент (нумерацияс нуля)  
;   i-того узла замен (т.е. i-той строки таблицы замен, нумерация также с нуля).  
;   Другими словами,в качестве замены для значения блока выбирается элемент из таблицы замен с номером строки,
;   равным номеру заменяемого блока, и номером столбца, равным значению заменяемого блока как
;   4-битового целого неотрицательного числа. 
;   Теперь становится понятным размер таблицы замен: число строк в ней равно числу 4-битовых элементов 
;   в 32-битовом блоке данных, то есть восьми, а число столбцов равно числу различных значений 
;   4-битового блока данных, равному как известно шестнадцати.
    mov ecx,8       
    rol S,4
@@:         
    ror S,4     
    mov eax,S
    and eax,0Fh     ;оставить в eax маладшие 4 бита
    xlat                ;al=число из таблицы
    and S,-1-0Fh        ;обнулить младшие 4 бита
    add S,eax       ;вставить 4 бита из таблицы
    add ebx,10h
    loop @b
    
;Шаг 3.  
;   Циклический сдвиг на 11 бит влево.  
;   Результат предыдущего шага сдвигается циклически на 11 бит 
;   в сторону старших разрядов и передается на следующий шаг.   
    rol S,7         ;сдвиг на 7 бит влево,
                    ;предыдущее значение S после цикла было сдвинуто на 4 бита слево
 
 ;Шаг 4.  
;   Побитовое сложение: 
;   значение, полученное на шаге 3, побитно складывается по модулю 2
;   со старшей половиной преобразуемого блока.
    mov eax,S
    xor N2,eax
 
;Шаг 5.  
;   Сдвиг по цепочке:  младшая часть преобразуемого блока сдвигается на место старшей, а на
;   ее место помещается результат выполнения предыдущего шага.
    push    N2
    mov eax,N1
    mov N2,eax
    pop N1
    pop ecx
    Ret
Function EndP
 
Encrypt proc
    mov ecx,3
    @increase:
        mov edx,offset key
        push    ecx
        mov ecx,8
        @@:
            mov ebx,offset Sbox
            call    Function
            add edx,4
        loop    @b
        pop ecx
    loop     @increase
 
    @decrease:
        sub edx,4
        mov ecx,8
        @@:
            mov ebx,offset Sbox
            call    Function
            sub edx,4
        loop    @b
    push N2
    mov eax,N1
    mov N2,eax
    pop N1
    Ret
Encrypt EndP
 
Decrypt proc
 
    @increase:
        mov edx,offset key
        mov ecx,8
        @@:
            mov ebx,offset Sbox
            call    Function
            add edx,4
        loop    @b
 
 
    mov ecx,3
    @decrease:
        push    ecx
        mov edx,offset key+28
        mov ecx,8
        @@:
            mov ebx,offset Sbox
            call    Function
            sub edx,4
        loop    @b
        pop ecx
    loop     @decrease
    
    push N2
    mov eax,N1
    mov N2,eax
    pop N1
    Ret
Decrypt EndP
 
CRC32 proc
;Вход:
;ESI    <- указатель на участок памяти для расчета CRC32
;ECX    <-размер участка в байтах
;EDX    <-начальное значение CRC32, при первом расчете должно быть -1,
;          при промежуточном равняется CRC32 предыдущего блока
;Выход:
;EAX = CRC32 заданного участка памяти
 
    mov edx,dCRC32      ; Начальное значение CRC32
    mov esi,offset fBuff        ; Указатель на блок данных
    xor eax,eax
    @calccrc32:
        lodsb           ; Получить следующий символ строки
        mov ebx,edx     ; Скопировать текущее значение CRC32
        and ebx,0FFh
        xor bl,al           ; XOR с текущим символом блока данных
        shr edx,8
        and edx,0FFFFFFh
        push    ecx     ; Сохранить счетчик символов
        mov     ecx,8       ; Вложенный цикл расчета полинома
        @polynom:
                    shr     ebx,1   ; Проверить четность байта
                jnc     @f      ; XOR выполняется только если байт нечетный
                    xor     ebx,0EDB88320h 
        @@:
             loop   @polynom ; Следующий бит
        pop ecx                 ; Восстановить счетчик
        
        xor edx,ebx         ; XOR CRC32 с вычисленным значением
    loop    @calccrc32          ; Перейти к следующему символу
 
    mov     eax,edx                 ; EAX <- CRC32 строки
        ; Если дальнейшая обработка не требуется, то проXORить CRC32
        ; для завершения расчетов
    cmp fcrc32,TRUE
    jne @f
    xor eax,-1
@@:
    ret
CRC32 endp          
                  
end start