Переделать strcpy в strcat на Tasm

; Определение публичных и внешних имен
public _my_strcpy
extern _strlen:near
 
.model flat
.code
 
_my_strcpy proc near
    push ebp                      ; Пролог процедуры
    mov ebp,esp
    
                              ; Определение параметров процедуры
    str1 equ [ebp+8]
    str2 equ [ebp+12] 
    
    cld
    
    push str1               ; Передача параметра для функции через стек
    call _strlen            ; Определение длины строки
    add esp,4               ; Очистка параметров
    mov ecx,eax             ; Cохранение длины строки
    
    mov esi,str1            ; Адрес основной строки в источник
    push str2                 ; Передача параметра для функции через стек
    mov  edi, str2          ; Адрес подстроки в приемник
 
    rep movsb                   ; Копирование строк
    mov eax,00h
    stosb   
          
                              ; Эпилог процедуры
    mov esp,ebp
    pop ebp
    ret
_my_strcpy endp
End

.386
;tasm /m3 /mx my_strct.asm
.model  flat,C
.code
; Определение публичных и внешних имен
public  my_strcat
 
my_strcat   proc C, str1:DWORD, str2:DWORD
    mov edi, str1
    call    @eos
    push    edi         ; EDI -> end-of-str1
    mov edi, str2
    mov esi, edi
    call    @eos
    not ecx         
    pop edi
; EDI -> end-of-str1
; ESI -> str2
; ECX = strlen(str2)
    rep movsb           ; Копирование строк
    xor al,al
    stosb
    mov eax, str1       ; due to ANSI C requirements
    ret
; Определение хвоста ASCIZ-строки  ES:EDI -> str
; побочный эффект: ECX - отрицательная длина строки ;)
@eos:   
    xor ecx,ecx
    mov al,cl
    dec ecx
    repne   scasb
    dec edi
    db  0C3h    ;ret опкодом, иначе аццкий ТАСМ вставит 
            ; перед ret leave, что нафиг не надо
 
my_strcat   endp
    End

@eos:   
    xor ecx,ecx
    mov al,cl
    dec ecx
    repne   scasb
    dec edi
    db  0C3h    ;ret опкодом, иначе аццкий ТАСМ вставит 
            ; перед ret leave, что нафиг не надо

; Определение хвоста ASCIZ-строки  ES:EDI -> str
@@eos:  
    xor ecx,ecx ;; cx = 0
    mov al,cl   ;; al = 0
    dec ecx     ;; cx = -1 - эта конструкция короче и быстрее, чем
            ;; mov ecx, 0FFFFFFFFh и mov al,0
    repne   scasb   ; ищем первый байт 00 в  ES:EDI, т.к. это Си, 
; он там обязательно будет, проверкой себя можно не утруждать.
;в итоге not(ECX) = длина строки
    dec edi ; ES:EDI -> на байт за 00, поэтому edi уменьшаем.