Как создать тень вокруг POPUP окна

format PE64 GUI
include 'encoding\win1251.inc'
include 'win64w.inc'
 
prologue@proc equ static_rsp_prologue
epilogue@proc equ static_rsp_epilogue
close@proc equ static_rsp_close
 
entry $
  sub    rsp,8
  frame
  invoke CreateWindowExW,0,strStatic,0,WS_VISIBLE+WS_OVERLAPPEDWINDOW,0,0,640,480,0,0,0,0
  mov    rbx,rax
  invoke DwmExtendFrameIntoClientArea,rax,margins
  invoke SetWindowPos,rbx,0,0,0,0,0,$227
  invoke SetWindowLongPtrW,rbx,GWLP_WNDPROC,WndProc
  @@:invoke GetMessageW,msg,0,0,0
     invoke DispatchMessageW,msg
  jmp @b
  endf
 
proc WndProc wnd,msg,wParam,lParam
  cmp rdx,WM_NCCALCSIZE
  je .WM_NCCALCSIZE
  cmp rdx,WM_CLOSE
  je .WM_CLOSE
  add rsp,40
  jmp [DefWindowProcW]
  ret
  .WM_NCCALCSIZE:xor    eax,eax
                 test   r8,r8
                 je @f
                   invoke SetWindowLongW,rcx,0,0
                   mov    eax,1
                 @@:
                 ret
       .WM_CLOSE:invoke ExitProcess,0
  ret
endp
 
align 2
strStatic du 'STATIC',0
margins   dd 0,0,0,1
msg       MSG
 
data import
  library kernel,'KERNEL32.DLL',\
          user,'USER32',\
          dwmapi,'DWMAPI.dll'
 
  import kernel,\
         ExitProcess,'ExitProcess'
 
  import user,\
         CreateWindowExW,'CreateWindowExW',\
         SetWindowLongPtrW,'SetWindowLongPtrW',\
         SetWindowLongW,'SetWindowLongW',\
         GetMessageW,'GetMessageW',\
         DispatchMessageW,'DispatchMessageW',\
         DefWindowProcW,'DefWindowProcW',\
         SetWindowPos,'SetWindowPos'
 
  import dwmapi,\
         DwmExtendFrameIntoClientArea,'DwmExtendFrameIntoClientArea'
end data