Нужно сделать чтобы сигнал сам выключался через 15 секунд

.286
.model small
.stack  100h
.data
    TIME        db  '00:00:00',13,10,10,'$'
    msg1    db  'PROGRAMM < ALARM >',13,10,'ESC exit',13,10,'$'
    msg2    db  'PLEASE ENTER ALARM TIME :$'
    msg3    db  13,10,'WAIT$'
    count   db  0   ;счетчик введенных цифр
    pos     dw  0   ;позиция курсора
    TIMER   dw  0   ;переменная заданного времени
.code
org 100h
start:
    mov ax,@data
    mov ds,ax
 
    mov ax,3        ;очистить экран
    int 10h
    
    call    GETTIME ;вызвать процедуру взятия текущего времени
    
    lea dx,TIME
    mov ah,09h
    int 21h     ;вывести время на экран
    
    lea dx,msg1
    mov ah,09h
    int 21h     ;вывод сообщений
    
    lea dx,msg2
    mov ah,09h
    int 21h
    
    mov ah,01   ;
    mov cx,2000h    ;ch=столбец cl-строка
    int 10h     ;убрать курсор (что бы не мерцал)
    ;цикл вывода времени и ввода таймера
L1:
    mov ah,03
    int 10h     ;взять текущее положение курсора
    mov pos,dx  ;сохранить позицию курсора
    
    mov dx,0        ;строка и столбец =0
    mov ah,02
    int 10h     ;установить курсор на начало 
    
    call    GETTIME ;взять текущее время
    lea dx,TIME
    mov ah,09h
    int 21h     ;вывести время 
    
    mov dx,pos  ;dx=сохраненная позиция курсора
    mov ah,02
    int 10h     ;установить курсор на прежнюю позицию
 
    mov ah,06h
    mov dl,-1       ;= 0ffH запрос ввода со стандартного ввода
    int 21h     ;считать нажатую клавишу в al
    jz  L1
    cmp al,27   ;если esp 
    je  exit        ;на выход
    cmp count,4 ;сравнить счетчик ввода
    jae L1      ;если больше 4 то таймер введен
    inc count   ;счетчик +1
    mov dl,al       ;поместить в dl нажатый символ
    mov ah,02h  
    int 21h     ;вывести на экран символ
    
    mov ax,TIMER    ;поместить текущее значение таймера
    rol ax,4        ;сдвиг влево на 4 бита
    sub dl,'0'      ;преобразовать символ в цифру
    or  al,dl       ;добавить к al
    mov TIMER,ax    ;сохранить в переменную
    cmp count,2 ;сравнить счетчик с введеными 2 символами
    jne next        ;продолжить если не равно
    mov dl,':'      ;вывести разделитель
    mov ah,02h
    int 21h     ;вывод символа ':'
next:   
    cmp [count],4   
    je  setalarm    ;если введены 4 символа установить таймер
    jmp L1      ;иначе продолжать цикл ввода и вывода времени
setalarm:   
    lea dx,msg3 ;вывести wait
    mov ah,9
    int 21h
    ;замена вектора  прерывания 4Ah на процедуру ALARM
    push    ds              ;сохраняем сегмент данных
    mov ax,seg ALARM        ;AX=сегмент процедуры 
    mov ds,ax           ;поместить  в DS
    mov dx,offset ALARM ;берем смещение процедуры
    mov al,4Ah          ;номер изменяемого вектора
    mov ah,25h          ;функция изменения вектора
    int 21h             ;поменять вектор
    pop ds              ;восстанавитьсегмент данных
    
    ;установить сигнал часов
    ;В указанное время вызывается пользовательская программа 
    ;по вектору прерывания INT 4aH
    xor dx,dx           ;DH    = секунды в коде BCD
    mov cx,TIMER            ;CH,CL = часы,минуты в коде BCD
    mov ah,06h          
    int 1Ah             ;установить сигнал часов
    inc [count]         ;увеличить счетчик 
    jmp L1              ;перейти в начало цикла
    
    
exit:
    mov ax,4c00h            ;завершить программу
    int 21h
 
;взятие времени
GETTIME proc 
    mov ah,02h
    int 1Ah             ;взять время ch=часы cl=минуты в формате BCD
    push    cx              ;сохранить в стек
    lea si,TIME         ;адрес переменной
    mov cl,ch               ;в ch и сl часы
    and cx,0FF0h            ;преобразовать в неупакованное BCD 
    ror cl,4                ;сдвиг младшей цифры часа на 4 вправо
    add cx,'00'         ;преобразовать в ASCII символы
    mov word ptr [si],cx        ;записать в переменную
    
    pop cx              ;восстановить cx из стека
    mov ch,cl               ;в ch и сl минуты
    and cx,0FF0h
    ror cl,4
    add cx,'00'         ;преобразовать в ASCII
    mov word ptr [si+3],cx  ;сохранить на место минут в time
    
    mov dl,dh           ;в dh и dl секунды
    and dx,0FF0h
    ror dl,4
    add dx,'00'
    mov word ptr [si+6],dx  ;сохранить в time на место секунд
    ret
GETTIME endp
 
;сигнал
ALARM proc far              ;FAR-дальний вызов
    mov  cx,10000 
beep:
    in  al,61h          ;получим значение порта 61h в al
    or  al,3                ;инициализируем динамик и подаем ток в порт 61h
    out 61h,al
    mov dx,50000            ;внутренний цикл задержка
    dec dx              ;отнимать от dx
    jnz $-1             ;перейти на dec dx
    and al,0FCh         ;выключить динамик
    out 61h,al          ;в порт 61h
    loop    beep
    iret            ;возврат из аппаратного прерывания
ALARM endp
 
end start

int_1C:
inc count
cmp count, 18.2*15
jae stop
iret
stop:
;bla bla bla
iret
count dw 0

;DOS, TASM, COM-файл
;
;Компиляция СОМ-файла:
;tasm.exe /m filename.asm
;tlink.exe /t /x filename.obj
;Выход: filename.com
;
.model tiny
.code
.386
ORG 100h
START:
;часы будут выводиться в видеопамять
;ES на буфер в видеопамяти
    push 0B800h
    pop es
 
    mov ax,3        ;очистить экран
    int 10h
    
    call GETTIME    ;вызвать процедуру взятия текущего времени
    
    lea dx,TIME
    mov ah,09h
    int 21h     ;вывести время на экран
    
    lea dx,msg1
    mov ah,09h
    int 21h     ;вывод сообщений
    
    lea dx,msg2
    mov ah,09h
    int 21h
    
    mov ah,01
    mov cx,2000h    ;ch=столбец cl-строка
    int 10h     ;убрать курсор (что бы не мерцал)
 
;получить с клавиатуры вребя будильника
L2:
    mov ah,06h
    mov dl,-1       ;= 0ffH запрос ввода со стандартного ввода
    int 21h     ;считать нажатую клавишу в al
    jz short L2
    cmp al,27       ;если esp 
    je short exit   ;на выход
    cmp [count],4   ;сравнить счетчик ввода
    jae short L2    ;если больше 4 то таймер введен
    inc [count]     ;счетчик +1
    mov dl,al       ;поместить в dl нажатый символ
    mov ah,02h
    int 21h     ;вывести на экран символ
    
    mov ax,[TIMER]  ;поместить текущее значение таймера
    rol ax,4        ;сдвиг влево на 4 бита
    sub dl,'0'      ;преобразовать символ в цифру
    or  al,dl       ;добавить к al
    mov [TIMER],ax  ;сохранить в переменную
    cmp [count],2   ;сравнить счетчик с введеными 2 символами
    jne short next  ;продолжить если не равно
    mov dl,':'      ;вывести разделитель
    mov ah,02h
    int 21h     ;вывод символа ':'
next:   
    cmp [count],4   
    je  short setalarm  ;если введены 4 символа установить таймер
    jmp short L2    ;иначе продолжать цикл ввода и вывода времени
setalarm:   
    lea dx,msg3     ;вывести wait
    mov ah,9
    int 21h
    ;замена вектора  прерывания 4Ah на процедуру ALARM
    mov dx,offset ALARM ;берем смещение процедуры
    mov al,4Ah      ;номер изменяемого вектора
    mov ah,25h      ;функция изменения вектора
    int 21h     ;поменять вектор
 
    ;установить сигнал часов
    ;В указанное время вызывается пользовательская программа 
    ;по вектору прерывания INT 4aH
    xor dx,dx       ;DH    = секунды в коде BCD
    mov cx,[TIMER]  ;CH,CL = часы,минуты в коде BCD
    mov ah,06h          
    int 1Ah     ;установить сигнал часов
 
L1:
    call GETTIME    ;взять текущее время и вывести его на экран
 
;проверка нажатой клавиши
    mov ah,06h
    mov dl,-1       ;= 0ffH запрос ввода со стандартного ввода
    int 21h     ;считать нажатую клавишу в al
    jz short L1
    cmp al,27       ;если esp 
    je short exit   ;на выход
 
    jmp short L1    ;перейти в начало цикла
 
exit:
    mov ah,7    ;отключить будильник
    int 1Ah
 
    ret     ;выход из программы
 
;взятие времени
GETTIME proc
push si         ;сохранить адрес строки времени для вывода
    mov ah,02h
    int 1Ah     ;взять время ch=часы cl=минуты в формате BCD
    push cx     ;сохранить в стек
    lea si,TIME     ;адрес переменной
    mov cl,ch       ;в ch и сl часы
    and cx,0FF0h    ;преобразовать в неупакованное BCD 
    ror cl,4        ;сдвиг младшей цифры часа на 4 вправо
    add cx,'00'     ;преобразовать в ASCII символы
    mov word ptr [si],cx;записать в переменную
    
    pop cx      ;восстановить cx из стека
    mov ch,cl       ;в ch и сl минуты
    and cx,0FF0h
    ror cl,4
    add cx,'00'     ;преобразовать в ASCII
    mov word ptr [si+3],cx;сохранить на место минут в time
    
    mov dl,dh       ;в dh и dl секунды
    and dx,0FF0h
    ror dl,4
    add dx,'00'
    mov word ptr [si+6],dx;сохранить в time на место секунд
pop si
;Вывод времени на экран
    lea si,TIME ;строка
    mov di,0    ;позиция на экране
    mov ah,7    ;цвет символа и фона
m1:
    lodsb       ;прочитать символ из строки
    cmp al,13
    jz short m2
    stosw       ;записать символ и цвет на экран
    jmp short m1
m2:
    ret
GETTIME endp
 
;сигнал
ALARM proc
pusha
     cli
     mov al,10110110b
     mov dx,43h
     out dx,al
     mov ax,8E8h;10CFh;96Fh   ;нота Си-493,88Гц
     dec dx
     out dx,al
     mov al,ah
     out dx,al     
     add dx,1Fh
     in al,dx       ;включить динамик
     or  al,11b
     out dx,al
     sti
;-----------------------
push dx
    mov ah,0
    int 1Ah
    add dx,18*15 ;18*3 задержка примерно на 3 секунды
    adc cx,0
    mov di,dx
    mov si,cx
DELAY:
    int 1Ah
    cmp cx,si
    ja  short EndDELAY
    cmp dx,di
    jb  short DELAY
EndDELAY:
pop dx
;---------------------------
     cli     
     in al,dx       ;выключить динамик
     and al,11111100b
     out dx,al
     sti
popa
    iret        ;возврат из аппаратного прерывания
ALARM endp
 
;-----------------------------------------------------------------
    TIME        db  '00:00:00',13,10,10,'$'
    msg1    db  'PROGRAMM < ALARM >',13,10,'ESC - exit',13,10,'$'
    msg2    db  'PLEASE ENTER ALARM TIME: $'
    msg3    db  13,10,'WAIT$'
    count   db  0   ;счетчик введенных цифр
    TIMER   dw  0   ;переменная заданного времени
;-------------------------------------------------------------------
 
    end start