Копирование файла

    TITLE   Potok
    PAGE    52,72      
    INCLUDE ..\masm\macroio.inc
    INCLUDE ..\masm\dos.inc 
 
DATA   SEGMENT
cr  equ 13
lf  equ 10
nin db     'Введите имя входного файла:',cr,lf,'$'
nout    db     'Введите имя выходного файла:',cr,lf,'$'
ferr    db  'Файл не найден.',cr,lf,'$' 
erout   db  'Выходной файл не создан или не открыт',cr,lf,'$'    
eread   db  'Ошибка чтения',cr,lf,'$'   
ewrite  db  'Ошибка записи',cr,lf,'$'
namebuf db 66,?             ; префикс длины для @GetStr
fname   db 66 dup(0)            ; строка имени файла
f1hand  dw ?                ; номер дескриптора первого файла
f2hand  dw ?                ; номер дескриптора второго файла
input   db 512 dup(?)           ; буфер для обработки текста
output  db 512 dup (?)          ; буфер для обработки текста
nb  dw ?                ; длина текста в буфере
DATA   ENDS
 
PROG   SEGMENT 'CODE'
       ASSUME  DS:DATA,ES:DATA,CS:PROG,SS:SPROG
START:
       MOV     AX,DATA
       MOV     DS,AX
       MOV     ES,AX
; ввод имени и открытие входного файла
readnm: @DispStr nin            ; подсказка для ввода имени вх. файла
    @GetStr namebuf,0       ; ввод имени файла
    @OpenFil fname,0        ; открытие вх. файла
    jnc m1              ; переход, если нет ошибки
 
badf:   @DispStr ferr           ; сообщение об ошибке открытия
    jmp vih             ; выход из программы
 
m1: mov f1hand,AX       ; сохранение номера дескриптора вх. файла
    jnc m10         
    jmp badf
 
m10:    @DispStr nout           ; подсказка на ввод имени вых. файла
    @GetStr namebuf,0       ; ввод спецификации файла
    @MakFil fname,,,new     ; создать выходной файл
    jnc m20         ; нет ошибки создания
    jmp badout          ; переход по ошибке
 
m20:    mov f2hand,AX       ; сохранение номера дескриптора выходного файла
 
m2: mov nb,512          ; задаем длину сектора для чтения
    @Read   input,nb,f1hand     ; читаем 512 байтов
    jnc m3          ; переход, если нет ошибки чтения
 
bread:  @DispStr    eread       ; сообщение об ошибке чтения
    jmp exit            ; и выход из цикла обработки
; обработка и копирование
m3: mov nb,AX           ; фактическое число прочитанных
    cmp AX,0            ; байт, если равно 0,
    je  exit            ; то конец входного файла
    mov CX,AX           ; параметр цикла обработки
    mov si,0            ; обнуление
    mov di,0            ; регистров
m5: mov al,byte ptr input[si]   ; символ из входного буфера в al
    cmp al,cr           ; сравниваем с символом конца строки
    jne L1              ; переход на L1, если не равно
    inc si              ; увеличение si, если равно
L2: mov al,byte ptr input[si]   ; символ четной строки в al
    mov byte ptr output[di],al  ; al в выходной буфер
    inc si              ; увеличение si
    inc di              ; увеличение di
    cmp al,cr           ; сравниваем с символом конца строки 
    jne L2              ; повторение L2, если не равно
    dec si              ; уменьшение si (чтобы не было повторного увеличения)
L1:     inc si              ; увеличение si
    loop m5             ; проверка окончания
; запись обработанного буфера в выходной файл
    @Write  output,di,f2hand    ; запись сектора на диск
    jnc m4              ; переход, если нет ошибки
    @DispStr ewrite         ; вывод сообщения об ошибке
    jmp exit            ; переход на окончание
 
m4: jmp m2              ; возврат на чтение нового сектора
 
exit:   @ClosFil    f1hand      ; закрытие
    @ClosFil    f2hand      ; файлов
    jmp vih         ; на выход из программы
 
badout: @DispStr erout          ; сообщение об ошибке
    jmp vih         ; открытия вых. файла
; выход в DOS
vih:
       @Exit
PROG   ENDS
 
SPROG  SEGMENT STACK   'STACK'
       DB      512 DUP(?)
SPROG  ENDS
 
       END     START

FILE_LEN equ    14
N       equ     16
format mz
entry codeseg:main      ;точка входа в программу
segment codeseg         ;сегмент кода
main:
        mov     ax, dataseg
        mov     ds, ax
 
        mov     dx, nin
        mov     bx, sin
        mov     byte [bx], FILE_LEN
        call    input_str
        mov     dx, nout
        mov     bx, sout
        mov     byte [bx], FILE_LEN
        call    input_str
 
        call    open_file
        call    create_file
        xor     di, di
        mov     [wnum], 1       ; первая строка
        mov     [flast], 0
        cld
.next_buf:
        mov     si, buf         ; индекс начала строки (вначале 0)
        call    read_buf
        cmp     ax, cx
        je     .not_last
        mov     cx, ax
        jcxz    .close_and_exit
        inc     [flast]
.not_last:
 
.scanline:
        jcxz    .next_buf
        test    [wnum], 1
        jnz     .nechet         ; иначе четное копируем строку
        mov     di, si
        mov     bx, cx
.chet:
        lodsb
        dec     cx
        cmp     al, 10
        je      .write_substr
        jcxz    .write
        jmp     .chet
.write_substr:
        xchg    di, si
        sub     bx, cx
        xchg    bx, cx
        call    write_buf
        mov     si, di
        mov     cx, bx
.endline:
        inc     [wnum]
        jmp     .scanline
 
.nechet:                ; нечет - пропускаем до конца строки
        lodsb           ; предпологаем что строки только с завершающим 0Ah
        dec     cx
        cmp     al, 10
        je      .endline
        jcxz    .next_buf
        jmp     .nechet
 
.write: mov     si, di
        mov     cx, bx
        call    write_buf
        cmp     [flast], 1
        je      .close_and_exit
        jmp     .next_buf
 
.close_and_exit:
        mov     bx, [f2]
        call    fclose
        mov     bx, [f1]
        call    fclose
        mov     dx, strok
 
@print: mov     ah,9
        int     21h
exit:   xor     ax, ax
        int     16h
        mov     ax,4c00h        ;стандартный выход
        int     21h
 
 
input_str:
        mov     ah, 9
        int     21h
        mov     ah, 10
        mov     dx, bx
        int     21h
        movzx   si, byte [bx+1]
        mov     byte [bx+si+2], 0
        ret
 
open_file:
        mov     dx, sfin
        mov     ax, 3dC0h       ; открытие входного файла
        int     21h
        jc      .err1
        mov     [f1], ax
        ret
.err1:  mov     dx,err1
        jmp     @print
 
create_file:
        mov     dx, sfout
        mov     ah, 3ch       ; открытие выходного файла
        xor     cx, cx
        int     21h
        jc      .err2
        mov     [f2], ax
        ret
.err2:  mov     bx, [f1]
        call    fclose
        mov     dx,err2
        jmp     @print
 
fclose: mov     ah, 3eh ; bx - файловый номер
        int     21h
        ret
 
read_buf:
        push    bx dx
        mov     ah, 3fh         ; чтение буфера из входного файла
        mov     bx, [f1]
        mov     cx, N
        mov     dx, si
        int     21h
        jc      .err3
        pop     dx bx
        ret
.err3:  mov     dx,err3
        jmp     @print
 
write_buf:
        push    bx dx
        mov     ah, 40h
        mov     bx, [f2]
        mov     dx, si
        int     21h
        jc      .err4
        cmp     cx, ax
        ja      .err4
        pop     dx bx
        ret
.err4:  mov     dx,err4
        jmp     @print
 
segment dataseg                 ; сегмент данных
nin     db      'Введите имя входного файла: ',13,10,'$'
nout    db      'Введите имя выходного файла: ',13,10,'$'
err1    db      'Входной файл не найден.$'
err2    db      'Выходной файл не открыт.$'
err3    db      'Ошибка чтения.$'
err4    db      'Ошибка записи.$'
strok   db      13,10,'Ok.$'
flast   db      ?
wnum    dw      ?
len1    dw      ?
len2    dw      ?
f1      dw      ?
sin     db      ?, ?
sfin    rb      FILE_LEN
f2      dw      ?
sout     db      ?, ?
sfout   rb      FILE_LEN
buf     rb      N
 
stack 100h