Создание движущейся рамки

; Программа рисует в центре экрана квадрат из символов псевдографики.
; По нажатию стрелок квадрат смещается в соответствующую сторону (но не далее края экрана).
; По нажатию "Page Up" квадрат увеличивается, по "Page Down" - уменьшается. По нажатию пробела изменяется цвет внутренней части квадрата
 
SGSTACK SEGMENT PARA STACK 'STACK'
DB 32 DUP(?)
SGSTACK ENDS
 
DATA SEGMENT PARA PUBLIC 'DATA'
wsize   dw  5       ; начальный размер квадрата (будет не квадрат потому что высота символа и ширина не совпадают)
DATA ENDS
 
CODE SEGMENT PARA PUBLIC 'CODE'
ASSUME CS:CODE, DS:DATA, SS:SGSTACK
 
start:
    mov ax, DATA        ; загрузить в DS адрес сегмента данных
    mov ds, ax
 
    mov ax, 3       ; установим режим 80х25
    int 10h
 
    mov dx, 0c28h       ; для курсора  это середина экрана
    mov ax, wsize       ; размер окна
    shr ax, 1       ; пополам
    sub dl, al      ; установить курсор на верхний левый угол окна
    sub dh, al
    call    SetCursor       ; процедура установки курсора
    mov bx, 1       ; атрибут
MainLoop:
    call    CLR     ; очистим экран
    call    SetCursor       ; установим курсор
    call    window      ; нарисуем окно
    xor ax, ax      ; ждем нажатия клавиши
    int 16h
    or  al, al      ; функциональная клавиша?
    jz  FuncKey     ; перейдем на обработку функциональных клавиш
    cmp al, 27      ; ESC?
    jz  _EXIT       ; выход
    cmp al, 20h     ; пробел?
    jnz MainLoop
    add bx, 16      ; если да - поменяем цвет фона (младшие 4 разряда не трогаем - это цвет текста)
    jmp MainLoop
 
FuncKey:
    cmp ah, 49h     ; PageUp?
    jz  _PageUp
    cmp ah, 51h     ; PageDown?
    jz  _PageDown
    cmp ah, 48h     ; клавиша вверх?
    jz  _Up
    cmp ah, 4bh     ; клавиша  влево?
    jz  _Left
    cmp ah, 4dh     ; клавиша вправо?
    jz  _Right
    cmp ah, 50h     ; клавиша  вниз?
    jz  _Down
    jmp MainLoop
 
_PageUp:
    dec dh      ; курсор вверх
    jz  _borderUp       ; дошли до верхней границы?
    mov ax, wsize       ; загрузим размер
    add ax, 2       ; увеличим на 2 (на 1 во все стороны)
    mov cx, ax      ;
    add cl, dh      ; проверим не вылезло ли окно за экран
    cmp cx, 25      ; справа
    jnb _borderUp
    dec dl      ; курсор влево
    jz  _borderLeftUp   ; дошли до левой границы?
    mov cx, ax
    add cl, dl
    cmp cx, 80
    jnb _borderLeftUp
    mov wsize, ax
    jmp MainLoop
 
_PageDown:
    add dx, 0101h
    mov ax, wsize
    sub ax, 2
    cmp ax, 2
    jna _collaps
    mov wsize, ax
    jmp MainLoop
 
_EXIT:
    jmp EXIT
_Up:
    dec dh
    jz  _borderUp
    jmp MainLoop
 
_Left:
    dec dl
    jz  _borderLeft
    jmp MainLoop
 
_Right:
    inc dl
    mov ax, 80
    sub ax, wsize
    cmp dl, al
    jnb _borderRight
    jmp MainLoop
 
_Down:
    inc dh
    mov ax, 25
    sub ax, wsize
    cmp dh, al
    jnb _borderDown
    jmp MainLoop
 
_borderUp:
    inc dh
    jmp MainLoop
_borderLeft:
    inc dl
    jmp MainLoop
_borderRight:
    dec dl
    jmp MainLoop
_borderDown:
    dec dh
    jmp MainLoop
_collaps:
    sub dx, 0101h
    jmp MainLoop
_borderLeftUp:
    add dx, 0101h
    jmp MainLoop
 
EXIT:
    XOR AL, AL  ; выход в OS
    MOV AH, 4CH
    INT 21H
 
window  proc    near
    push    dx
    push    bx
    mov si, bx
    mov bx, 1
; верхняя линия
    call    SetCursor
    mov al, 0c9h
    mov cx, 1
    call    OutSym
    inc dl
    call    SetCursor
    mov al, 0cdh
    mov cx, wsize
    sub cl, 2
    call    OutSym
    add dx, wsize
    sub dl, 2
    call    SetCursor
    mov al, 0bbh
    mov cx, 1
    call    OutSym
; середина
    mov cx, wsize
    sub cl, 2
window_1:
    push    cx
    sub dx, wsize
    inc dl
    inc dh
    call    SetCursor
    mov al, 0bah
    mov cx, 1
    call    OutSym
    inc dl
    call    SetCursor
    mov bx, si
    mov al, ' '
    mov cx, wsize
    sub cl, 2
    call    OutSym
    mov bx, 1
    add dx, wsize
    sub dl, 2
    call    SetCursor
    mov al, 0bah
    mov cx, 1
    call    OutSym
    pop cx
    loop    window_1
; нижняя линия
    sub dx, wsize
    inc dl
    inc dh
    call    SetCursor
    mov al, 0c8h
    mov cx, 1
    call    OutSym
    inc dl
    call    SetCursor
    mov al, 0cdh
    mov cx, wsize
    sub cl, 2
    call    OutSym
    add dx, wsize
    sub dl, 2
    call    SetCursor
    mov al, 0bch
    mov cx, 1
    call    OutSym
    pop bx
    pop dx
    ret
window  endp
 
; вывод символа в текущее положение курсора
OutSym  proc
    mov ah, 09h     ; вывод символа
    xor bh, bh
    int 10h
    ret
OutSym  endp 
 
; процедура установки положения курсора
; положение курсора: dl - строка dh - столбец
SetCursor   proc
    mov ah, 2
    xor bh, bh
    int 10h
    ret
SetCursor   endp
 
;               Очистка экрана:
CLR proc
    push    bx
    push    dx
    mov ah, 06h ; Прокрутить  вверх
    mov al, 24  ; на 24 строки
    mov bh, 7   ; Нормальный ч/б
    xor cx, cx  ; Координаты от 00,00
    mov dx, 184Fh   ; до 24,79 (полный экран)
    int 10h ;Вызов BIOS
    pop dx
    pop bx
    ret
CLR endp
 
 
CODE ENDS
END START

; masm dos com #
.286
.model tiny
.code
org 100h 
start:  push 0B800h
    pop es
    mov cx,12
    mov ax,3; чистим экран
    int 10h
a0: push cx
    mov ax,0CDBh; красный квадрат на черном фоне
    mov di,x1; первоначальное положение рамки
    mov cx,x2; рисуем верхнюю полосу
    rep stosw
    add di,x5
    mov cx,x3
a1: stosw; боковушки
    add di,x4
    stosw
    add di,x5
    loop a1
    mov cx,x2
    rep stosw; рисуем нижнюю полосу
    mov ah,2Ch
    int 21h
    mov bl,dh      
@@: int 21h; крутимся до тех пор пока не получится
    cmp bl,dh; задержка в 1 Сек
    jz @b
    mov ax,00DBh; черный квадрат на черном фоне
    mov di,x1; стираем предыдущую рамку
    mov cx,x2
    rep stosw
    add di,x5
    mov cx,x3
a2: stosw
    add di,x4
    stosw
    add di,x5
    loop a2
    mov cx,x2
    rep stosw
    add x1,162
    sub x2,2
    sub x3,2
    sub x4,4
    add x5,4
    pop cx
    loop a0
    retn; выходим из программы
x1 dw 0
x2 dw 80
x3 dw 23
x4 dw 156
x5 dw 0
end start