Не могу разобраться с кодом

.286
.model tiny
.code
org 100h
start: 
 mov ax,3
 int 10h; очистил экран
 mov ah,9
 mov dx,offset string; вывел строку приглашение
 int 21h
@@: mov ah,0
 int 16h
 cmp ah,1Ch;Enter?
 je @@2
 cmp ah,1;Esc?
 jne @@
 jmp exit
@@2: xor ax,ax;Функция 00h предназначена для выяснения, загружен ли в память 
 int 33h;драйвер мыши. Если эта функция возвращает AX = 0, то драйвер 
 xchg ax,cx;отсутствует. Если драйвер загружен, то AX = 0FFFFh , а в 
 jcxz exit;регистре BX - число кнопок мыши
;------------------------------------------------------
 mov ah,3Ch;создание файла
 mov dx,offset filename
 xor cx,cx; обычные атрибуты
 int 21h
 mov handler,ax
 mov ah,2Ah;получить системную дату
 int 21h
 mov di,offset string1+5
 mov al,dl;день
 call func; перевод числа в строку
 mov al,dh;месяц
 call func
 inc di
 inc di
 sub cx,2000
 mov al,cl;год
 call func
 mov ah,2Ch;получить системное время
 int 21h
 mov al,ch;часы
 call func
 mov al,cl;минуты
 call func
 mov ah,40h; содержимое буфера пишем в файл
 mov cx,62
 mov bx,handler
 mov dx,offset string1
 int 21h
;------------------------------------------------------
 mov ax,0Ch;Функция 0Ch позволяет программно задать реакцию на события 
;связанные с мышью: ее перемещения, нажатие и отпускание кнопок. 
;События, на которые необходимо реагировать, должны быть отмечены 
 mov cx,100b;единицами в соответствующих разрядах регистра CX. CX=100 - 
;вызвать подпрограмму, если левая клавиша отпущена. После выполнения этой 
 mov dx,offset mouse;функции драйвер мыши на каждое из заданных событий 
 int 33h;будет реагировать вызовом обработчика событий - подпрограммы 
;--------------------------------------------------
; mov ax,1;Функция 01h включает изображение курсора мыши на экране.
; int 33h
mov ax,3
 int 10h; очистил экран 
push cs
 call paint
  mov ah,0
 int 1Ah; получить системное время
 mov temp,dx
;---------------------------------------------------------------------
 mov ah,0
 int 16h;жду пока не нажмут на клавиатуру
 mov ax,14h
 xor cx,cx;удалить обработчик событий мыши
 int 33h
 mov ah,3Eh ;закрыть файл
 mov bx,handler
 int 21h
exit: int 20h;выхожу из программы
;-------------------------------------------------
mouse proc far
 push cs
 pop ds
 mov bx,Y; проверяю что щелчек пришелся на
 cmp DX,BX; координаты между Y и Y+высота прямоугольника
 jb @@4 ; и Х и Х+ширина прямоугольника
 add BX,30h; если не попали, то выходим из процедуры 
 cmp DX,bx
 ja @@4
 mov BX,X
 cmp CX,BX
 jb @@4
 add BX,50h
 cmp CX,BX
 jb a6 
@@4: retf
a6: mov ax,0B800h;содержимое ES указывает на начало текстового
 mov es,ax
 xor color,0Eh; если попали, то стираем старый прямоугольник
 imul di,Y,20 ; случайно задаем координаты Х и Y
 mov bx,X ; рисуем новый прямоугольник
 shr bx,2
 add di,bx
 mov cx,7
@@5: push cx
 mov cx,10
 mov ah,color
 mov al,0DBh
 rep stosw
 pop cx
 add di,140
 loop @@5
 add Y,8
 cmp Y,152
 jb @@6
 mov Y,0 
@@6: cmp X,0
 jne @@7
 mov X,17
@@7: mov ax,X
 mul a
 div m
 shl dx,3
 mov X,dx
 cmp X,568
 jb @@8
 mov X,0
@@8: xor color,0Eh
 mov ah,0;получить системное время
 int 1Ah
 mov ax,dx
 sub ax,temp; смотрим разницу между последним замером времени
 mov bx,4 ; переводим число в символы и пишем их в буфер
@@9: xor dx,dx
 mov cx,10
 div cx
 add dl,30h
 mov buffer[bx],dl
 dec bx
 jns @@9
 mov ah,40h; содержимое буфера пишем в файл
 mov cx,11
 mov dx,offset buffer
 mov bx,handler
 int 21h
 mov ah,0;получить новое системное время
 int 1Ah
 mov temp,dx
mouse endp
 
paint proc; рисуем прямоугольник по заданным координатам
 mov ax,0B800h;содержимое ES указывает на начало текстового
 mov es,ax;видеобуфера
 imul di,cs:Y,20
 mov bx,cs:X
 shr bx,2
 add di,bx
 mov cx,7
@@10: push cx
 mov cx,10
 mov ah,cs:color
 mov al,0DBh
 rep stosw
 pop cx
 add di,140
 loop @@10
exit1: retf
paint endp
 
func proc
 aam
 xchg ah,al
 add ax,'00'
 stosw
 inc di
 retn
func endp
 
color db 0Eh;красный 
X dw 384; координата Х
Y dw 8 ; координата Y
a dw 11
m dw 79
temp dw 0
buffer db 5 dup (?),' tik',0Dh,0Ah; строка для вывода
filename db 'reaction.txt',0; название файла
handler dw ?; файловый указатель
string db "Programma dlya proverki reakcii",0Dh,0Ah,0Ah 
db "Dlya izmerenia reakcii nazhmite neskolko raz na zheltiy kvadrat",0Dh,0Ah
db "Rezlutati budut zapisani v file REACTION.TXT",0Dh,0Ah,0Ah
db "Nazhmite Enter dlya nachala testa ili Esc dlya vihoda iz programmi$"
string1 db 'Data 00.00.2000 00:00',0Dh,0Ah,'Vremya reakcii v tikah (1 tik=55 msec):',0Dh,0Ah
end start