Разобрать программу

;Program: 4.3
;
;Сложение, вычитание и умножение многочленов
;Максимальная степень задается в переменной N
;Коэффициенты беззнаковые <=65536
;
.model small
.stack 100h
.data
N equ 256
polynom struc
coef dw N dup (0)
polynom ends
polynom_big struc
coef dw N*2 dup (0)
polynom_big ends
polynom1 polynom <>
polynom2 polynom <>
temp polynom_big <>
_buff dw ?
pol dw ?
action db ?
mess_input db 'Enter polynom degree: $'
mess_input2 db 'Enter x^$'
mess_output db 'x^$'
mess_menu db 'Choose action:',0Dh,0Ah,'1.Addiction',0Dh,0Ah,'2.Subtraction',0Dh,0Ah,'3.Multiplication',0Dh,0Ah,'$'
mess_cont db 'Continue? [Y/N]$'
mess_cont1 db 'New polynoms? [Y/N]$'
.code
PUBLIC ReadInteger, WriteInteger, ReadChar, WriteChar
;Процедуры для ввода и вывода чисел
ReadInteger proc  
    push    cx
    push    bx
    xor     cx, cx
    mov     bx, 10
read:  
    call    ReadChar
    cmp     al, '0'
    jb      done
    cmp     al, '9'
    ja      done  
    sub     al, '0'  
    xor     ah, ah  
    xor     dx, dx
    xchg    cx, ax  
    mul     bx  
    add     ax, cx  
    xchg    ax, cx  
    jmp     short read  
done:  
    xchg    ax, cx  
    pop     bx  
    pop     cx 
    ret  
ReadInteger endp
  
ReadChar proc 
    mov     ah, 1
    int     21h
    ret 
ReadChar endp  
 
WriteInteger proc  
    push    ax  
    push    cx  
    push    bx  
    push    dx  
 
    xor     cx, cx  
    mov     bx, 10  
divloop:  
    xor     dx, dx  
    div     bx  
    push    dx  
    inc     cx  
    cmp     ax,0
    jnz     divloop  
poploop:  
    pop     ax  
    add     al, '0'  
    call    WriteChar  
    loop    poploop  
 
    pop     dx
    pop     bx  
    pop     cx  
    pop     ax 
    ret  
WriteInteger endp  
  
WriteChar proc  
    push    ax  
    push    dx  
    mov     dl, al  
    mov     ah, 2  
    int     21h  
    pop     dx  
    pop     ax  
    ret  
WriteChar endp
 
;Процедура ввода многочлена
input_polynom proc
    mov dx,offset mess_input    ;Выводим сообщение
    xor ax,ax
    mov ah,09h
    int 21h
    call ReadInteger    ;Вводим степень многочлена в _buff
    mov _buff,ax
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    mov cx,_buff    ;Цикл по степени многочлена+1
    inc cx
input_coef:
    mov dx,offset mess_input2   ;Выводим сообщение X^
    mov ah,09h
    int 21h
    mov ax,cx
    dec ax
    call WriteInteger   ;Пишем степень X
    mov dx,3Ah  ;Ставим : ...
    mov ah,02h
    int 21h
    mov dx,20h  ;и пробел
    int 21h
    call ReadInteger    ;Вводим число
    xor bx,bx
    mov bx,pol
    add bx,cx   ;добавляем к адресу переменной смещение = степень*2
    add bx,cx
    mov [bx],ax ;и записываем его в переменную, адрес которой в переменной pol
    mov ah,02h
    mov dx,0D0Ah
    int 21h
    loop input_coef
    ret
input_polynom endp
;Процедура печати многочлена
print_polynom proc
    mov cx,N-1
    cmp pol,offset temp ;Если печатается temp - cx=N*2-1 т.к. temp больше в 2 раза
    jne l3
    add cx,N
    l3:
    mov bx,pol  ;В bx адрес многочлена
    add bx,cx   ;И смещение в конец, т.к. печатаем с конца
    add bx,cx
print_coef: ;Цикл по многочлену, cx=степень-1
    mov ax,[bx]
    cmp ax,0    ;Если коэффициент=0 не печатаем
    je loop_end
    call WriteInteger
    cmp cx,1    ;Если степень=0, заканчиваем цикл ...
    je loop_end
    mov dx,offset mess_output ;Иначе печатаем X^(степень)
    mov ah,09h
    int 21h
    mov ax,cx
    dec ax
    call WriteInteger
    mov dx,2Bh ;Печатаем +
    mov ah,02h
    int 21h
loop_end:
    sub bx,2    ;Смещаемся на следующий коэффициент
    loop print_coef
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    ret
print_polynom endp
;Процедура сложения многочленов
addict_polynom proc
    mov cx,N-1 ;cx=максимальная степень многочлена-1
    xor si,si
    xor dx,dx
addict: ;Цикл по многочлену
    mov temp.coef[si],0 ;Записываем в temp ноль
    mov dx,polynom1.coef[si]    ;В dx коэффициент первого многочлена
    add dx,polynom2.coef[si]    ;В dx прибавляем коэффициент второго многочлена
    add temp.coef[si],dx    ;Записываем сумму в temp
    add si,2
    loop addict
    ret
addict_polynom endp
;Процедура вычитания многочленов
subtr_polynom proc
    mov cx,N-1
    xor si,si
    xor dx,dx
subtr:
    mov temp.coef[si],0
    mov dx,polynom1.coef[si]
    sub dx,polynom2.coef[si]    ;Отличается от сложения только этой строкой
    add temp.coef[si],dx
    add si,2
    loop subtr
    ret
subtr_polynom endp
;Процедура умножения многочленов
mul_polynom proc
    mov cx,(N*2)-1
    xor si,si
prepare:    ;Обнуление многочлена temp т.к. там может быть мусор
    mov temp.coef[si],0
    add si,2
    loop prepare
    xor si,si   ;si - индекс в первом многочлене
multloop:   ;Цикл по первому многочлену
    xor ax,ax
    mov cx,N-1  ;cx=степень-1
    xor bx,bx
mult:   ;Вложенный цикл по второму многочлену
    mov ax,polynom1.coef[si]    ;В ax коэффициент первого многочлена
    mul polynom2.coef[bx]   ;Умножаем на коэффициент второго
    add temp.coef[si][bx-2],ax  ;Записываем в temp где степень=степень1+степень2
    add bx,2
    loop mult
    add si,2
    cmp si,(N-1)*2  ;Если дошли до конца многочлена - конец
    jl multloop
    ret
mul_polynom endp
 
main:
    mov ax,DGROUP
    mov ds,ax
input:
    mov pol,offset polynom1 ;Пишем в pol адрес первого многочлена
    call input_polynom  ;И вводим его
    call print_polynom  ;Печатаем
    mov pol,offset polynom2 ;То же самое для второго
    call input_polynom
    call print_polynom
menu:
    mov dx,offset mess_menu ;Выводим меню
    mov ah,09h
    int 21h
    mov ah,07h
    int 21h
    mov action,al
    cmp action,'2'  ;Сравниваем выбор
    jl addictl  ;Если <2 - сложение
    je subtrl   ;=2 - вычитание
    jg multl    ;>2 - умножение
    jmp menu
    addictl: call addict_polynom
    jmp print_result
    subtrl: call subtr_polynom
    jmp print_result
    multl: call mul_polynom
    jmp print_result
print_result:
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    mov pol,offset polynom1 ;Печатаем первый многочлен
    call print_polynom
    cmp action,'2'  ;Печатаем знак в зависимости от действия
    jl plus
    je minus
    jg multiply
    plus: mov dx,'+'
    jmp l1
    minus: mov dx,'-'
    jmp l1
    multiply: mov dx,'*'
    jmp l1
    l1:
    mov ah,02h
    int 21h
    mov dx,0D0Ah
    int 21h
    mov pol,offset polynom2 ;Печатаем второй многочлен
    call print_polynom
    mov dx,'='  ;Печатаем =
    mov ah,02h
    int 21h
    mov dx,0D0Ah
    int 21h
    mov pol,offset temp ;Печатаем результат
    call print_polynom
    mov dx,offset mess_cont ;Спрашиваем надо ли продолжать
    mov ah,09h
    int 21h
    mov ah,07h
    int 21h
    cmp al,'N'  ;Если N - выход
    je main_end
    cmp al,'n'  ;Если n - выход
    je main_end
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    mov dx,offset mess_cont1    ;Спрашиваем надо ли вводить новые многочлены
    mov ah,09h
    int 21h
    mov ah,07h
    int 21h
    cmp al,'N' ;Если N - переход к меню
    je l2
    cmp al,'n'  ;Если n - переход к меню
    je l2
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    jmp input   ;Иначе переход к вводу многочленов
    l2:     ;Перевод строки и прыжок на меню
    mov dx,0D0Ah
    mov ah,02h
    int 21h
    jmp menu
    main_end:   ;Завершение программы
    mov ah,4Ch
    int 21h
end main

.data ; Сегмент данных
N equ 256 ;  N=256 (константа)
polynom struc ; Структура, описывающая полином
coef dw N dup (0) ; Массив коэффициентов полинома
polynom ends ;
polynom_big struc ; Структура, состоящая из 2*N коэф.полинома
coef dw N*2 dup (0)
polynom_big ends
polynom1 polynom <> ; Неинициализированная переменная polynom1 типа polynom
polynom2 polynom <> ; Неинициализированная переменная polynom2 типа polynom
temp polynom_big <> ; Неинициализированная переменная типа polynom_big
_buff dw ? ; Переменные программы
pol dw ? ;
action db ? ;
mess_input db 'Enter polynom degree: $'
mess_input2 db 'Enter x^$'
mess_output db 'x^$'
mess_menu db 'Choose action:',0Dh,0Ah,'1.Addiction',0Dh,0Ah,'2.Subtraction',0Dh,0Ah,'3.Multiplication',0Dh,0Ah,'$'
mess_cont db 'Continue? [Y/N]$'
mess_cont1 db 'New polynoms? [Y/N]$'