Блокирование нажатия клавиши

.286c
PAGE  59,132
 
Kb_flags_1_     Equ 417h        ;
Kb_flags_3_     Equ 496h        ;
Vector_15h_off      Equ 54h     ;
Vector_15h_seg      Equ 56h             ;
Keybd_flags_1_      Equ 17h             ;
Keybd_flags_2_      Equ 18h             ;
Keybd_q_head_       Equ 1Ah             ;
Keybd_q_tail_       Equ 1Ch             ;
CapsLk          Equ 40h             ;
BothShift       Equ 3               ;
AltCtrl         Equ 0Ch             ;
Timer_command       Equ 00B6H       ; value for timer setup
Timer_command_register  Equ 0043H       ; port address
Timer_latch_register    Equ 0042H       ; port address
Port_pb         Equ 0061H       ; port address
Speaker_on      Equ 00000011B   ; bit mask
Clock_rate_high     Equ 0012H       ; 1.19318 MHz as 32 bit value
Clock_rate_low      Equ 34DCH           ;
Timer_low       Equ 6ch             ;
Tabl            Equ 5ch             ;
Tone_r          Equ 83h             ;
Rld_call        Equ 0ach            ;
Cyrillic        Equ 0B0h        ;
 
$VER$           equ 0101h
 
seg_a       segment byte public
        assume  cs:seg_a, ds:seg_a
 
        org 100h
 
 
start:
        jmp init
copyrt      db  'KB: by Kludge (c) 1994',0Dh,0Ah,'$'
 
 
old_isr15   dd  ?           ; previous INT 15h handler
;
 
;
;           INT 15h Entry Point
;
;
Int_15h_entry   proc    far
        pushf
        cmp ah,4Fh          ; Keyboard intercept ?
        jz  $$1         ; yes, processing
        popf
        jmp dword ptr cs:Old_isr15  ; go back
 
;
; Mode Toggle Section
;
 
$$1:
        cmp al,0ffh
        jnz $$001
        mov ax,$VER$
        popf
        clc
        retf    2
$$001:
        call    dword ptr cs:Old_isr15
        pusha
        push    ds          ;
        push    es          ;
 
        push    cs          ;
        pop ds          ;   ds = cs
        push    ax
        xor ax,ax           ;; set up BIOS data seg
        mov es,ax           ;;
        mov dx,word ptr es:Kb_flags_1_
        mov ax,dx
        mov bl,byte ptr es:Kb_flags_3_
        and bl,0ch
        AND ah,0f3h
        or  ah,bl
        and ax,0            ; This mask will be defined during startup
K_mask      equ $ - 2
 
        cmp ax,word ptr K_mask
        jnz $$3
$$03:       xor byte ptr ds:Cyrillic,0ffh ; Yes,toggle mode
        mov bx,300h
        jnz $$2         ;
        or  bx,550h         ; for Russ/Lat
$$2:        mov ax,Tone_r       ; beep
        call    ax
;$$2:       call    ds:Tone_r       ;; ??? KL - 02-27-93 02:55pm
$$3:
        pop ax
;
; Encoding Section
;
 
        push    ds
        pop es
        cmp byte ptr ds:Cyrillic,0  ; Cyrillic mode ?
        jz  $$9         ; No , nothing to do
        test    dl,08h
        jz     $$3b
        mov di, offset tabl3
        mov cx,6
        cld
        repne   scasb
        jnz $$3b
        add di,5
        test    dl,BothShift
        jz  $$3c
        add di,6
$$3c:       xchg    ah,al
        mov al, byte ptr es:[di]
        jmp $$8
$$3b:       test    dl,AltCtrl      ; Alt or Ctrl Active ?
        jnz $$9         ; Yes, nothing to do
        cmp al,36h          ; Keypad ?
        jae $$9         ; Yes, nothing to do
        cmp al,0Fh          ; Special processing for scans 1 - 15 ?
        ja  $$30            ; No,branch
        test    dl,BothShift
        jz  $$9
        test    dl,2            ; Pressing <RightShift> in cyrillic
                        ; mode with keys in the upper column
                        ; of main keyboard must be have NO
                        ; translation effect
        jnz $$9         ; Nothing to do if so
$$30:       lea bx,ds:Tabl      ; Load encoding table addr to ds:bx
        mov cx,ax           ; save orginal scancode
        mov ah,al           ;
        xlat                ; al=[al+[bx]] table
        or  al,al
        jnz $$4         ; Yes, bye
        xchg    ax,cx
        jmp $$9
;
$$4:        cmp ah,0Fh          ; No , translation in progress
        jb  $$8
 
$$40:       test    dl,CapsLk       ; Caps Lock ?
        jz  $$5         ; no
        test    dl,BothShift        ;
        jz  $$8         ; UPPER CASE
        jmp short $$6       ;
$$5:                        ; Caps Lock set
        test    dl,BothShift        ; cleared
        jnz $$8         ; set
 
; drop to lower case
 
$$6:                        ;
        add al,20h          ; drop to lower
        cmp al,0B0h         ;
        jb  $$7
        add al,30h          ;
$$7:        cmp al,0E0h         ; it's russian lower 'r' ? (35/224)
        jnz $$8         ; Jump if not equal
        xor ah,ah           ; Clear scancode
 
$$8:
        xchg    cx,ax           ;
        mov ah,5            ;
        int 16h         ;
        stc
;
$$9:
        pop es          ; restore registers
        pop ds          ;
        popa
        jc  $$80
        iret                ; interrupt return / end of isr
$$80:       xor ax,ax
        retf    2
Int_15h_entry   endp
 
_end_:                      ; End of TSR section

;
; This section being relocated to PSP:[5c] during startup
;
Tabl_2:
        db  0,0,0,'@/":,._?%', 0,'!', 0,0
        db  'ЙЦУКЕНГШЩЗХЪ', 0, 0
        db  'ФЫВАПРОЛДЖЭ', 0, 0, 0
        db  'ЯЧСМИТЬБЮ', 0, 0
tabl3:      db  26,27,39,40,51,52
        db  '[];',27h,',.'
        db  '{}:"<>'
 
Tab_len     equ $ - Tabl_2
tone        proc    near
        push    cx
    ; 1.19318 MHz / frequency
 
    ; select timer channel 2; read/write LSB, MSB; mode 3; binary
        MOV AL, TIMER_COMMAND
        OUT TIMER_COMMAND_REGISTER, AL
 
        MOV DX, CLOCK_RATE_HIGH
        MOV AX, CLOCK_RATE_LOW
 
        DIV BX          ; AX = correct Hz divisor
 
    ; output LSB, MSB (this sets the frequency)
        OUT TIMER_LATCH_REGISTER, AL
        MOV AL, AH
        OUT TIMER_LATCH_REGISTER, AL
 
    ; save current setting of port pb
        IN  AL, PORT_PB
        PUSH    AX
 
    ; turn on speaker data and timer gate bits
        OR  AL, SPEAKER_ON
        OUT PORT_PB, AL
 
    ; speaker is on..wait the requested duration
        MOV cX, 0ffffh
xx:     loop    xx
        MOV cX, 0ffffh
xx1:        loop    xx1
    ; shut that thing off!!
        POP AX
        OUT PORT_PB, AL
        pop cx
 
TONE_RET:   retn
        dw  tone_r
        dw  0
tone        endp
rld_len     equ $ - tabl_2

;
; Startup code
;
init:
;       mov ah,0c0h         ;
;       int 15h                     ;
;       jc  old_bios                ;
;       cmp ah,86h                  ;
;       je  old_bios                ;
;       test    byte ptr es:[bx+5],16h  ;
;       jz  old_bios                ;
        cld             ; Clear direction
        xor ax,ax           ; Zero register
        mov es,ax                   ;
        mov ax,es:vector_15h_off    ; (0000:0024=507h)
        cmp ax,offset cs:int_15h_entry
        jnz loc_8           ; Jump if not equal
        cmp byte ptr cs:[80h],0     ;
        jnz q2                      ;
        JMP SHORT $21               ;
;old_bios:       mov    dx,offset bad_news      ;
;       jmp short $20               ;
$21:        mov dx,offset loaded        ;
$20:        mov ah,9                    ;
        int 21h         ; DOS Services  ah=function 09h
                        ;  display char string at ds:dx
quit:       mov ax,4C01h        ; DOS Services  ah=function 4Ch
        int 21h         ;  terminate with al=return code
q2:     jmp uninst                  ;
loc_8:                      ;
        mov word ptr cs:old_isr15,ax;
        mov ax,es:vector_15h_seg    ;
        mov word ptr cs:old_isr15+2,ax
        push    cs                      ;
        pop ds                      ;
        mov dx,offset int_15h_entry ;
        mov ax,2515h                ;
        int 21h                     ;
        mov dx,offset copyrt    ;
        mov ah,9                    ;
        int 21h         ; DOS Services  ah=function 09h
                        ;  display char string at ds:dx
        mov dx,offset sw_info   ;
        mov ah,9                    ;
        int 21h         ; DOS Services  ah=function 09h
                        ;  display char string at ds:dx
        push    es                      ;
        mov ax,cs:[2ch]             ;
        mov es,ax                   ;
        mov ah,49h                  ;
        int 21h                     ;
                        ;
        push    cs                      ;
        push    cs                      ;
        pop es                      ;
        pop ds                      ;
        mov cx,rld_len      ; fill unused DTA/Parm area
        mov si,offset tabl_2        ;
        mov di,tabl                 ;
        rep movsb                   ;
                        ;
        mov byte ptr cs:Cyrillic,0  ;
        mov cs:rld_call+2,cs        ;
;
        mov ax,0F3h                 ; set typematic : delay 250 ms, rept rate 30 cps
        call    out_ax          ;
        xor ax,ax           ; Zero register
        mov es,ax                   ;
        and byte ptr es:417h,8Fh    ; clear all flags except INS
                        ;
        mov ax,0EDh                 ; set LEDs : all LEDs off
        call    out_ax          ;
        mov cx,1                    ;
 
locloop_4:
        push    cx                      ;
        mov ax,07EDh                ; set LEDs : all LEDs on
        call    out_ax          ;
        mov ax,0EDh                 ; set LEDs : all LEDs off
        call    out_ax          ;
        pop cx                      ;
        loop    locloop_4       ; Loop if cx > 0
        pop es                      ;
 
        mov dx,offset cs:_end_
        mov ax,dx
        shr dx,4            ; Shift w/zeros fill
        test    ax,0fh
        jz  ts_1
        inc dx
ts_1:
        mov ax,3100h
        int 21h         ; DOS Services  ah=function 31h
                        ; TERMINATE & STAY RESIDENT
 
uninst:                                         ;
        push    ds                      ;
        mov ax,3515h                ;
        int 21h                     ;
        push    es                      ;
        mov ax,word ptr es:[old_isr15+2]
        mov ds,ax                   ;
        mov dx,word ptr es:[old_isr15]
        pop es                      ;
        mov ax,4900h                ;
        int 21h                     ;
        mov ax,2515h                ;
        int 21h                     ;
        pop ds                      ;
        mov dx,offset cs:unl        ;
        mov ah,9                    ;
        int 21h                     ;
        jmp quit                    ;
;
;       SUBROUTINE out_ax
;               perform call for output al,ah to port 60h
 
out_ax      proc    near
        call    xfr
        xchg    ah,al
        call    xfr
        retn
out_ax      endp
;
;       SUBROUTINE xfr
;               perform output to port 60h with delay for I/O
xfr     proc    near
        out 60h,al          ; port 60h, keybd data write
        mov cx,9FFFh
$d1:        loop    $d1         ; Loop if cx > 0
        retn
xfr     endp
;
sw_info:    db  'Use <LeftShift><LeftAlt> for toggle', 0Ah, 0Dh, '$'
loaded:     db  'KB: -- already active.', 0Ah, 0Dh, '$'
unl:        db  'KB: -- Unloaded.',10,13,'$'
bad_news:   db  'KB: -- FATAL -- Keyboard intercept feature not supported.',10,13,'$'
 
seg_a       ends
 
 
 
        end start