Изменение программы

.286
TITLE  DIRECT (COM) Прямой табличный доступ
CODESG SEGMENT PARA 'Code'
       ASSUME   CS:CODESG,DS:CODESG,SS:CODESG,ES:CODESG
        ORG     100H       ;Начало в конце PSP
BEGIN:  JMP     SHORT MAIN ;Обход через данные
;-------------------------------------------------------
THREE   DB      3                  ;Элементы данных
MONIN   DB      '11'
ALFMON  DB      '???','$'
MONTAB  DB      'JAN','FEB','MAR','APR','MAY','JUN'
        DB      'JUL','AUG','SEP','OKT','NOV','DEC'
;--------------------------------------------------------
MAIN    PROC    NEAR               ;Основная процедура
        CALL    C10CONV            ;Получить дв. значение
        CALL    D10LOC             ;Выделить месяц
        CALL    F10DISP            ;Выдать месяц на экран
        RET
MAIN    ENDP
;               Перевод ASCII в двоичное
;               ------------------------
C10CONV PROC
        MOV     AH,MONIN           ;Загрузить номер месяца
        MOV     AL,MONIN+1
        XOR     AX,3030H           ;Удалить ASCII тройки
        CMP     AH,00              ;Месяц 01-09?
        JZ      C20                ;Да - обойти
        SUB     AH,AH              ;Нет - очистить АН
        ADD     AL,10              ;и перевести в дв.
C20:    RET
C10CONV ENDP
;               Выделение месяца из таблицы
;               ---------------------------
D10LOC  PROC
        LEA     SI,MONTAB
        DEC     AL                 ;Коррекция для таблицы
        MUL     THREE              ;Умножить AL на 3
        ADD     SI,AX
        MOV     CX,03              ;Трехсимв. пересылка
        CLD
        LEA     DI,ALFMON
        REP MOVSB                  ;Переслать 3 символа
        RET
D10LOC  ENDP
;               Вывод на экран симв. месяца
;               ---------------------------
F10DISP PROC
        LEA     DX, ALFMON
        MOV     AH, 09
        INT     21H
        RET
F10DISP ENDP
CODESG  ENDS
        END     BEGIN

LEA     DX, ALFMON
        MOV     AH, 09
        INT     21H

.286
TITLE  DIRECT (COM) Прямой табличный доступ
CODESG SEGMENT PARA 'Code'
       ASSUME   CS:CODESG,DS:CODESG,SS:CODESG,ES:CODESG
        ORG     100H       ;Начало в конце PSP

.486
    .model flat, stdcall
    option casemap :none
    include \masm32\include\windows.inc
    include \masm32\include\masm32.inc
    include \masm32\include\msvcrt.inc
    include \masm32\macros\macros.asm
    includelib \masm32\lib\masm32.lib
    includelib \masm32\lib\msvcrt.lib
.data
msg db  'Current month name abbrev: %s',0
fmt db  '%b',0
time_p  dd  ?
.data?
buf db  4 dup(?)
.code
start:  invoke  crt_time, 0
    mov time_p, eax
    invoke  crt_localtime, ADDR time_p
    invoke  crt_strftime, ADDR buf, 4, ADDR fmt, eax
    invoke  crt_printf, ADDR msg, addr buf
    invoke  crt_exit, 0
    end start

; tasm windows console #
.386
.model flat
includelib import32.lib
include windows32.inc;содержит описание типов данных Windows 
;ввод строки в консольном режиме и вывод ее же другим цветом
;для использования в ассемблерных программах
;объявление используемых функций Windows (внешние ссылки)
extern GetStdHandle:PROC;
extern WriteConsoleA:PROC;
extern SetConsoleCursorPosition:PROC;
extern SetConsoleTitleA:PROC;
extern FreeConsole:PROC;
extern AllocConsole:PROC;
extern SetConsoleTextAttribute:PROC;
extern ReadConsoleA:PROC;
extern SetConsoleScreenBufferSize:PROC;
extern ExitProcess:PROC;
COL1 = 2+8;цвет выводимого текста
COL2 = 1+2+8;цвет выводимого текста 2
.code
start:   xor ebx,ebx
         call FreeConsole;освободим существующую консоль
         call AllocConsole;образуем свою консоль
         push STD_INPUT_HANDLE
         call GetStdHandle;получаем HANDL1 для ввода
         mov HANDL1,eax
         push STD_OUTPUT_HANDLE
         call GetStdHandle;получаем HANDL для вывода
         mov HANDL,eax
         push 190064h;Y=25(19h)X=100(64h)
         push eax
         call SetConsoleScreenBufferSize;устанавливаем новый размер окна консоли
         push offset STR2
         call SetConsoleTitleA;определение заголовка окна
         push 0A0000h;Y=10(Ah)X=0
         push HANDL
         call SetConsoleCursorPosition;устанавливаем позицию курсора
         push COL1
         push HANDL
         call SetConsoleTextAttribute;задаем цветовые атрибуты выводимого текста
         push offset STR1
         push ebx;0
         push offset LENS
         push LEN1
         push offset STR1
         push HANDL
         call WriteConsoleA;выводим строку символов
         push ebx;0
         push offset LENS
         push 2
         push offset BUF
         push HANDL1
         call ReadConsoleA;ждем ввод строки символов
     mov ax,word ptr BUF
     xor ax,'00'
     xchg ah,al
     aad
     mov edi,eax
     push COL2
         push HANDL
         call SetConsoleTextAttribute;задаем цветовые атрибуты выводимого текста
         push ebx;0
         push offset LENS
         push table2[edi*4];длина выводимой строки
         push table1[edi*4]
         push HANDL
         call WriteConsoleA
         mov ecx,8FFFFFFh;небольшая задержка
l1:  loop l1
         call FreeConsole;закрываем консоль
         push ebx;0
         call ExitProcess
.data
HANDL  dd ?
HANDL1 dd ?
STR1 db 'Введите номер месяца двумя цифрами и нажмите Enter:',13,10,0
LEN1 = $ - STR1 - 1
STR2 db 'Простой пример консоли',0
LEN2 = $ - STR2 - 1
BUF db 0,0
LENS db 0;количество выведенных символов
table1 dd 0,jan,feb,mar,apr,may,jun,jul,aug,sep,oct,nov,dcm
table2 dd 0,6,7,4,6,3,4,4,6,8,7,6,7
jan db "январь"
feb db "февраль"
mar db "март"
apr db "апрель"
may db "май"
jun db "июнь"
jul db "июль"
aug db "август"
sep db "сентябрь"
oct db "октябрь"
nov db "ноябрь"
dcm db "декабрь"
end start