Вывод координат мыши в левом верхнем углу экрана

s_s segment stack  "stack"  ; S_S начало сегмента стека 
dw 5 dup(?)  
s_s ends 
 
d_s segment
 r db 10, 'Right x:  $'
 l db 10, 'Left  x:  $'
 n db 10, 'y:   $'
 x dw 0
 y dw 0
d_s ends
 
c_s segment
 assume ss:s_s, ds:d_s, cs:c_s ;определяет каким сегментным регистром соответствует адрес начала сгмента 
 begin:
  mov ax,d_s
  mov ds, ax   
 
   mov ax, 3; видео режим
   int 10h
 
  mov ax, 0
   int 33h ; ин. мыши
 
  mov ax, 1 ; видимый курсор
   int 33h
 
  progr:
 
  mov ax, 3 ; 3- обработка события мыши
   int 33h
    mov x, cx
    mov y, dx
 
 
  l1:
  cmp bx, 1 ; нажата ЛКМ
   je left
 
  cmp bx, 2 ; нажата ПКМ
   je right
  
  cmp bx, 3
   je exit
 
  right:
   mov ax, 0600h ;очистка экрана ;AH=06(прокрутка) AL=00(весь экран)
   mov bh, 07
   mov cx, 0000
   mov dx, 184FH
   int 10h 
 
  lea dx, r
   mov ah, 9
    int 21h
 
   mov  ax, x ; х помещаем в регистр ax    
 
   call koordproc  ; вызываем процедуру 
    lea dx, n  
     mov ah, 9h
     int 21h
  
   mov  ax, y
 
   call koordproc   
 
 jmp progr
 
 
  left:
   mov ax, 0600h ;очистка экрана ;AH=06(прокрутка) AL=00(весь экран)
   mov bh, 07
   mov cx, 0000
 
   mov dx, 184FH
   int 10h 
  
  lea dx, l
   mov ah, 9
    int 21h
 
   mov  ax, x ; х помещаем в регистр ax    
   call koordproc  ; вызываем процедуру 
    lea dx, n 
     mov ah, 9h
     int 21h
  
   mov  ax, y
   call koordproc 
 
 jmp progr
 
  exit:
   mov ah,4ch
    int 21h 
 
 
  koordproc proc near
 
 xor cx, cx
   mov  bx, 10
  
  DIVK:
   xor   dx, dx
   div  bx
   push dx
   inc cx 
   cmp ax, 0
  jnz DIVK
  
   write:
   pop dx
    xor dh, dh
    add dl, 48
    mov ah, 2
     int 21h
   loop write
  
  ret 
 
  koordproc endp
 
 
c_s ends
end begin

  cmp bx, 0
   je progr

.286
.MODEL  tiny
.CODE
    ORG 100h
 
start:
; Инициализация 
    mov ax, 3
    int 10h
 
; Инициализация мыши
    mov ax, 0
    int 33h
 
; Обработчик событий
    mov ax, 000Ch
    mov cx, 07Fh    ; флаги событий для вызова п/п
;Bitfields for mouse call mask:
 
;Bit(s) Description 
; 0 call if mouse moves
; 1 call if left button pressed
; 2 call if left button released
; 3 call if right button pressed
; 4 call if right button released
; 5 call if middle button pressed (Mouse Systems/Logitech/Genius mouse)
; 6 call if middle button released (Mouse Systems/Logitech/Genius mouse)
; 7-15  unused
    lea dx, msISR   ; адрес п/п
    int 33h
 
; Показать курсор
    mov ax, 1
    int 33h
; вызываем п/п для первичной отрисовки шаблончика координат
    call    far ptr msISR
; Ожидание ввода символа
    mov ah, 0
    int 16h
 
; Отменить обработчик
    mov ax, 000Ch
    mov cx, 0000h
    int 33h
 
; Выходим из программы
    int 20h
 
msISR:
    push    ds
    push    es
    push    cs
    pop es
    test    ax, 1   ; перемещение?
    jnz @1
    call    btn
;   jmp @2
@1: lea di, y_end   ; хвост шаблончика координат
; чтобы выводить в знакоместах, CX и DX надо делить на 8 -> shr dx, 3
    push    cx
    mov ax,dx
    std     ; писать будем с хвоста, задом наперёд
    mov bx, 10  ; делитель
    call    cnv ; преобразуем Y
    dec di      ; пропускаем ':'
    pop ax
    call    cnv ; преобразуем X
@2: cld
    push    cs
    pop ds
; Вывод в видеопамять
    mov cx, tpt_sz  ; длина шаблончика
    mov ax, 0B800h  ; видеосегмент
    mov es, ax
    mov di, 008Ch   ; смещение в видеобуффере (80-tpt_sz)*2
    mov ah, 00000011B   ; color: cyan on black
    lea si, x
; цикл вывода
disp:
    lodsb
    stosw
    loop    disp
    pop es
    pop ds
    retf
; обработка кнопок
btn:    test    ax, 110b    ; левая кнопка?
    jz  @3
    xor cs:_l, 6Ch      ; да, перебрасываем флаг: 20 xor 6Ch = 'L' или пробел
@3: test    ax, 11000b  ; правая кнопка?
    jz  @4
    xor cs:_r, 72h  ; да, перебрасываем флаг: 20 xor 72h = 'R' или пробел
@4: test    bx, 1100000b    ; средняя кнопка?
    jz  @5
    xor cs:_m, 6Dh  ; да, перебрасываем флаг: 20 xor 6Dh = 'M' или пробел
@5: ret
; Преобразование числа в строку
;   es:di - endbuf
cnv:    call    @@1
    call    @@1
@@1:    div bl      ; делим на 10.
    xchg    ah, al
    add al, 30h     ; в ASCII
    stosb                   ; сохраняем
    shr ax, 8
    ret
x   db '000:000'        ; шаблончик для вывода
y_end   = $ - 1
_l  db  20h     ;
_m  db  20h
_r  db  20h
tpt_sz  = $ - x
    end start