Находить файлы с определённым расширением и поочередно их открывать

#include <ScreenCapture.au3>
Global $aFiles, $sDir, $sScreensDir, $sMaskExt
Local $sImgName, $hwnd
 
$sDir = "C:\Windows"; папка с файлами которые запускать
$sScreensDir = @ScriptDir&"\screenshots"; папка где хранить скриншоты
$sMaskExt = "*.wav"; расширение искомых файлов
$aFiles = _FileSearch($sDir, $sMaskExt)
If IsArray($aFiles) And UBound($aFiles) > 1 Then
    For $i = 1 To $aFiles[0]
        $sImgName = $sScreensDir&"\"&_GetNameByPath($aFiles[$i])&"_"&_GetParentDirByPath($aFiles[$i])&".jpg"; имя скриншота
        ShellExecute($aFiles[$i])
        $hwnd = WinWaitActive("myprogaWind")
        Sleep(500)
        _ScreenCapture_CaptureWnd($sImgName, $hwnd)
        Sleep(500)
        WinClose($hwnd)
        Sleep(500)
    Next
Else
    MsgBox(16, "Ошибка", "Файлы не найдены"&$sDir)
EndIf
 
 
; ---------- functions ----------;
Func _FileSearch($sPath, $sFileMask)
    Local $sOut, $aOut, $hDir
 
    $sOut = StringToBinary("0" & @CRLF, 2)
    $hDir = Run(@ComSpec & ' /U /C DIR "' & $sPath & '\' & $sFileMask & '" /S /B /A-D', @SystemDir, @SW_HIDE, 6)
 
    While 1
        $sOut &= StdoutRead($hDir, False, True)
        If @error Then ExitLoop
    Wend
 
    $aOut = StringRegExp(BinaryToString($sOut, 2), "[^\r\n]+", 3)
    If @error Then Return SetError(1)
 
    $aOut[0] = UBound($aOut)-1
    Return $aOut
EndFunc
 
Func _GetNameByPath($sPath)
    Local $aPathRet = StringSplit($sPath, "\")
    Local $sNameRet = $aPathRet[$aPathRet[0]]
    Return $sNameRet
EndFunc
Func _GetParentDirByPath($sPath)
    Local $aPathRet = StringSplit($sPath, "\")
    Local $sNameRet = $aPathRet[$aPathRet[0]-1]
    Return $sNameRet
EndFunc
; ---------- end functions ----------;