Автоматизация перезагрузки роутера по значению внешнего IP

;——————————————————————————————————————————————————————————————————
; Перезапуск роутера до смены значения первого октета во внешнем IP
;                            ver. 1.0.1 (28.02.2021, авт. FlasherX)
;——————————————————————————————————————————————————————————————————
#NoTrayIcon
Opt('MustDeclareVars', 1)
Const $Octet = 85
Const $Limit = 100  ; макс. число перезапусков роутера
Const $Login = 'admin'
Const $Passw = '12345'
Const $RoIP  = '192.168.0.1'
Const $IpURL = 'http://ipinfo.io/ip'
;———————————————————————————————————
Global $c, $Socket, $hTimer, $Recv, $oIP
If Ping(StringRegExp($IpURL, '://\K[^/]+', 1)[0], 100) = 0 Then
   TT('Смените URL для получения IP!', 2)
   OnExit()
EndIf
Global $IP = BinaryToString(InetRead($IpURL, 16))
$oIP = ' (' & $IP & ')'
TCPStartup()
 
While StringSplit($IP, ".", 2)[0] = $Octet
   $c += 1
   If $c > $Limit Then
      TT('Достигнут предел перезапусков роутера!', 2)
      OnExit(1)
   EndIf
   $Socket = TCPConnect($RoIP, 23)
   If $Socket = -1 Then
      TT('С ' & $RoIP & ' связь отсутствует!', 2)
      OnExit(1)
   EndIf
   $hTimer = TimerInit()
   While 1
      Sleep(100)
      $Recv = TCPRecv($Socket, 2048)
      If @error Or ($Recv = '' And TimerDiff($hTimer) > 2000) Then
         TT('Роутер не вернул никаких данных!', 2)
         OnExit(1)
      EndIf
      If $Recv <> '' Then
         Switch $Recv
            Case StringInStr($Recv, '$') > 0
               TCPSend($Socket, 'reboot' & @CRLF)
               TT('Перезапуск роутера ...', 1)
               While Ping('ya.ru', 100)
               Wend
               While Ping('ya.ru', 500) = 0
               Wend
               $IP = BinaryToString(InetRead($IpURL, 16))
               TT('Внешний IP: ' & $IP, 1)
               TCPCloseSocket($Socket)
               $oIP = ' (' & $IP & ')'
               ExitLoop
            Case StringInStr($Recv, 'Password:') > 0
               TCPSend($Socket, $Passw & @CRLF)
            Case StringInStr($Recv, 'login:') > 0
               TCPSend($Socket, $Login & @CRLF)
         EndSwitch
      EndIf
   WEnd
WEnd
 
TCPShutdown()
TT('Успех! Внешний IP: ' & $IP, 1)
Sleep(5000)
 
Func TT($m, $i)
   ToolTip($m, @DesktopWidth/2, @DesktopHeight/2, ' Смена IP' & $oIP & ' роутера', $i, 7)
EndFunc
 
Func OnExit($check)
   If $check Then
      TCPCloseSocket($Socket)
      TCPShutdown()
   EndIf
   Sleep(3000)
   Exit
EndFunc