KWClock mini (28kb)

CurrentTime .s
#SM_CXVIRTUALSCREEN = 78 
 
Procedure DrawInfo(hWnd) 
  Shared FontID, WinX, CurrentTime 
  TextSize.SIZE
  TextPos.RECT
  hDC=GetDC_(hWnd)
  If hDC
    SelectObject_(hDC, FontID)
    GetTextExtentPoint32_(hDC, @CurrentTime , Len(CurrentTime ), @TextSize)
    TextPos\left   = 10
    TextPos\top    = 10
    TextPos\right  = TextPos\left + TextSize\cx
    TextPos\bottom = TextPos\top  + TextSize\cy
    SetTextColor_(hDC, $787AFF)
    SetBkMode_(hDC, #TRANSPARENT)
    DrawText_(hDC, @CurrentTime , Len(CurrentTime),@TextPos,#DT_TOP|#DT_CENTER)
    ReleaseDC_(hWnd, hDC)
  EndIf
EndProcedure
 
Procedure WindowCallback(Window, Message, wParam, lParam)
  Shared CurrentTime 
  Select Message
    Case #WM_LBUTTONDBLCLK
      DestroyWindow_(Window)
    Case #WM_PAINT
      BeginPaint_(Window, ps.PAINTSTRUCT)
      Result  = DefWindowProc_(Window, Message, wParam, lParam)  
      DrawInfo(Window) 
      EndPaint_(Window, ps)
    Case #WM_TIMER
      CurrentTime = FormatDate("%hh:%ii:%ss", Date())
      ShowWindow_(hWndMain,  #SW_SHOWDEFAULT)
      InvalidateRect_(Window, #Null, #True)
    Case #WM_CLOSE 
      DestroyWindow_(Window) 
    Case #WM_DESTROY 
      PostQuitMessage_(0) 
      Result  = 0 
    Default 
      Result  = DefWindowProc_(Window, Message, wParam, lParam) 
  EndSelect 
  ProcedureReturn Result 
EndProcedure 
 
 
 
InitCommonControls_()
#Style  = #WS_POPUPWINDOW & (~ #WS_BORDER)  
#StyleEx  = #WS_EX_TOPMOST | #WS_EX_TOOLWINDOW| $00080000 
 
WindowClass.s    = "My_PB_Win" 
wc.WNDCLASSEX 
wc\cbsize        = SizeOf(WNDCLASSEX)
wc\lpfnWndProc   = @WindowCallback() 
wc\hCursor       = LoadCursor_(0, #IDC_ARROW)
wc\hbrBackground = CreateSolidBrush_($787AF0)
wc\style         = #CS_DBLCLKS
wc\lpszClassName = @WindowClass
 
RegisterClassEx_(@wc)
WinX=GetSystemMetrics_(#SM_CXVIRTUALSCREEN)-200
FontID=CreateFont_(40,0,0,0,#FW_BOLD,0,0,0,#RUSSIAN_CHARSET,0,0,0,0,"Werdana")
CurrentTime =  FormatDate("%hh:%ii:%ss", Date())
 
hWndMain  = CreateWindowEx_(#StyleEx, WindowClass, "", #Style, WinX,20,200,90, 0, 0, 0, 0) 
 
SetLayeredWindowAttributes_(hWndMain,$787AF0,0,1)
SetTimer_(hWndMain, 2, 1000, #Null)
ShowWindow_(hWndMain,  #SW_SHOWDEFAULT) 
UpdateWindow_(hWndMain)
 
While GetMessage_(msg.MSG, #Null, 0, 0 ) 
  TranslateMessage_(msg) 
  DispatchMessage_(msg) 
Wend