Загрузка файла на FTP-сервер с заменой имеющегося и проверкой целостности загруженного

Rem FTP and Clipboard ver.1.4
Rem Отправка на FTP и копирование ссылки в буфер - by (c) Alex Dragokas
 
Option Explicit
Dim objArgs, Server, DomainName, Port, User, Pass, Folder, SystemFolder, CloseDOS, DosStr, SendTo, WSHShell, objFSO, n
Dim isSilent, verify, noclipboard, FTPTempFld, FTP_DL_Name, Ret
 
'=== Данные учетной записи FTP ===
 
Server = "*******"
DomainName = "***********" 'Будет отображаться в ссылке для скачивания
'Если не задан ( DomainName = "" ) , тогда вместо него будет использоваться IP-адрес
if DomainName = "" then DomainName = Server
Port = "21"
User = "*****"
Pass = "******"
 
SystemFolder = "" 'Системная папка (на некоторых серверах она = public_html )
'Папка на FTP, куда будут складываться файлы
Folder = "Forum/Dl" 'подкаталог
 
isSilent = false
noclipboard = false
verify = true
 
Dim i
for i = 1 to WScript.Arguments.Count - 1
  if instr(1,WScript.Arguments(i), "subfolder:",1) <> 0 then Folder = mid(WScript.Arguments(i),instr(WScript.Arguments(i),":")+1)
  if instr(1,WScript.Arguments(i), "silent",1) <> 0 then isSilent = true
  if instr(1,WScript.Arguments(i), "noclipboard",1) <> 0 then noclipboard = true
  if instr(1,WScript.Arguments(i), "verify",1) <> 0 then verify = true
next
 
'Флаг - закрывать ли консольное окно после передачи данных (true или false)
CloseDOS = True
if not CloseDOS then DosStr = "&pause"
 
Set WSHShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
 
Set objArgs = wscript.Arguments
If objArgs.Count = 0 Then 'Проверяем аргументы (Drag & Drop "путь к файлу")
    SendTo = WSHShell.SpecialFolders("SendTo")
    objFSO.CopyFile WScript.ScriptFullname, SendTo & "\"
    WScript.Echo "Скрипт установлен в папку Отправить (SendTo)"
else
    Dim FName, Link, FF, TmpFile, objFile
    
    'Получаем имя файла
    FName = Mid(objArgs(0), InStrRev(objArgs(0), "\") + 1)
    'Интернет-адрес
    Link = DomainName & "/" & Folder & "/" & FName
    
    'Копируем в буфер обмена Windows
    if not noclipboard then WSHShell.Run "cmd.exe /C <nul set /p ""=" & Link & """ | CLIP", 0, False
 
    FTPTempFld = WSHShell.ExpandEnvironmentStrings("%temp%") & "\FTP_temp"
    if not objFSO.FolderExists(FTPTempFld) then objFSO.CreateFolder FTPTempFld
 
    'Формируем строку коннекта для утилиты FTP
    TmpFile = FTPTempFld & "\temp_" & CInt(Rnd() * 1000)   
 
    Set objFile = objFSO.OpenTextFile (TmpFile, 2, True, 0) 'True - создать файл, ForWriting = 2
        objFile.WriteLine "open " & Server & " " & Port
        objFile.WriteLine User
        objFile.WriteLine Pass
        objFile.WriteLine "quote pasv"
        objFile.WriteLine "cd " & SystemFolder & Folder
        objFile.WriteLine "binary"
        objFile.WriteLine "hash"
        objFile.WriteLine "put """ & objArgs(0) & """"
    if verify then
        FTP_DL_Name = FTPTempFld & "\" & objFSO.GetFileName(objArgs(0))
        objFile.WriteLine "lcd """ & FTPTempFld & """"      
        objFile.WriteLine "get """ & "/public_html/" & SystemFolder & Folder & "/" & objFSO.GetFileName(objArgs(0)) & """"
    end if
        objFile.WriteLine "disconnect"
        objFile.WriteLine "bye"
    objFile.Close
    
    'Добавляем утилиту FTP в исключения файрвола и запускаем
    WSHShell.Run "cmd.exe /c ""(netsh firewall add allowedprogram """ & WSHShell.ExpandEnvironmentStrings("%windir%") & _
      "\system32\ftp.exe"" ENABLE& ftp -s:""" & TmpFile & """" & DosStr & ")""", 1, True
 
    objFSO.DeleteFile TmpFile, True
 
    if verify then
        ret = FileCompare(objArgs(0), FTP_DL_Name)
 
        select case ret
        case 0
            n = inputbox("[ OK ] - Файл проверен." & vbcrlf & vbcrlf & "Путь к файлу на FTP",,Link)
        case 1
            msgbox "Ошибка !!!  Файл на FTP поврежден !", vbCritical
        case 2
            msgbox "Ошибка !!!  Не удалось закачать файл !", vbCritical
        end select
    else
        n = inputbox("Путь к файлу на FTP",,Link)
    end if
 
    On error resume next
    objFSO.DeleteFile FTP_DL_Name, True
    objFSO.DeleteFolder FTPTempFld, True
    on error goto 0
  
    'wscript.echo "Путь к файлу на FTP: " & vbLf & Link & String(2, vbLf) & _
    '"Путь к файлу скопирован в буфер обмена Windows."
End If
Set WSHShell = Nothing: Set objFile = Nothing: Set objFSO = Nothing: Set objArgs = Nothing
 
Function FileCompare(path1, path2)
    'возвращает результат двоичного сравнения двух файлов
    'с помощью системной утилиты fc.exe. Возвращаемое значение:
    '0 - файлы одинаковы;
    '1 - файлы различаются;
    '2 - файл не найден
    FileCompare = CreateObject("wscript.shell").Run("cmd /c fc /b """ & path1 & """ """ & path2 & """", 1, True)
End Function