Нужен батник для сканирования сетевой папки

Option Explicit
Dim sComputer, sFullName, sDrive, sPath, relPath, sExt, sBaseName, oFSO, oWMI, oEvents, oLastEvent, sSavedLog, oFile
 
sFullName = "h:\_C++\1.txt"
sSavedLog = "h:\_C++\Saved.txt"
sComputer = "."
 
Set oFSO = CreateObject("Scripting.FileSystemObject")
 
sDrive    = oFSO.GetDriveName(sFullName)
sDrive    = Left(sDrive, 1)
sPath     = oFSO.GetParentFolderName(sFullName)
relPath   = "\\" & Mid(sPath, 4) & "\\"
sExt      = oFSO.GetExtensionName(sFullName)
sBaseName = oFSO.GetBaseName(sFullName)
 
Set oFile = oFSO.GetFile(sFullName)
 
Set oWMI = GetObject("winmgmts:\\" & sComputer & "\root\cimv2")
Set oEvents = oWMI.ExecNotificationQuery _
  ("SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE " _
  & "TargetInstance ISA 'CIM_DataFile' AND " _
  & "TargetInstance.Drive='"       & sDrive & ":' AND " _
  & "TargetInstance.Path = '"      & relPath & "' AND " _
  & "TargetInstance.FileName = '"  & sBaseName & "' AND " _
  & "TargetInstance.Extension = '" & sExt & "' ")
 
msgbox "Начинается мониторинг... Нажмите ОК."
 
Do
  Set oLastEvent = oEvents.NextEvent()
  With oLastEvent
    if .Path_.Class = "__InstanceModificationEvent" or .Path_.Class = "__InstanceCreationEvent" then
        If .TargetInstance.LastModified <> .PreviousInstance.LastModified Then
            if oFile.Size <> 0 then
                oFile.Copy sSavedLog, true
            end if
        End If
    end if
  End With
Loop
 
Set oWMI = Nothing: Set oEvents = Nothing: Set oLastEvent = Nothing: Set oFile = nothing