Перенос строк

@Haart · Регистрация: 21.01.2015

Author24 — интернет-сервис помощи студентам

Всем привет, назрела у меня опять маленькая проблемка. Есть файл, помоему всего один, но большой. Приложу его ниже.
Так вот, есть текст оформленный в виде комментов:

C

    Dead                        = "SVM_52_Dead"                     ; //Aaaaaargl!
    Aargh_1                     = "SVM_52_Aargh_1"                  ; //Aargh
    Aargh_2                     = "SVM_52_Aargh_2"                  ; //Aargh
    Aargh_3                     = "SVM_52_Aargh_3"                  ; //Aargh

Выдрать их оттуда не проблема, проблема их вставить обратно за точку с запятой. Причем надо пропустить скобку с точкой и запятой. "};".
Вручную можно потратить NN часов, а батником пару минут) К тому же, он может быть и не один.
Вот и все)

@ComSpec · 07.02.2015, 20:45

Сообщение от Haart

Выдрать их оттуда не проблема

Проблема. Количество строк в файле, из которого строки "выдирают" должно равнятся количеству строк в файле, в который эти строки переносят. То есть каждой строке, в которой отсутствует комментарий (в том числе пустой), должна соответствовать пустая строка. Тогда файлы можно будет корректно "склеить".

Корректный код для выделения комментариев из исходного файла в другой файл (работает быстро, так как условие задачи довольно простое):

Bash

@echo off
 
set "in=svm.txt"
set "comments=comments.txt"
 
@<"%in%">"%comments%" (for /f "tokens=1* delims=;" %%i in ('"2>nul (find/n /v ""& del "%comments%")"') do @echo.%%j)
 
exit/b

.

Корректный код для раделения исходного файла на два (с Вашим файлом работал 15 минут, так как задача у него сложнее):

Bash

@echo off
 
set "in=svm.txt"
set "code=code.txt"
set "comments=comments.txt"
 
for /f "delims=" %%i in ('"2>nul (<"%in%" find/n /v ""& del "%code%" "%comments%")"') do (
 for /f "tokens=1* delims=;" %%j in ("%%i") do (
  set x=%%j
  >>"%code%" cmd/v/c "if "%%j" equ "%%i" (echo[!x:*]^=!) else (echo[!x:*]^=!;)"
  >>"%comments%" echo.%%k
  )
 )
 
exit/b

.

Если даже написать коды пакетных файлов для построчного слияния двух файлов без замены части строки в одном из файлов, а тем более с заменой таковой, то скорость обработки больших файлов будет "желать лучшего", поэтому об этих операциях мы с Вами, я надеюсь, поговорим в разделе "PowerShell", где я видел Вашу аналогичную тему. А для корректной подготовки файлов к построчному слиянию используйте вышеприведённые коды.

	07.02.2015, 20:45