Комментировать-раскомментировать определённые строки в ini-файле

@echo off
 
set "file=example.ini"
 
set "add#=1 3 5 7 9"
set "del#=2 4 6 8 10"
 
for /f %%i in ('
 ^<"%file%" find/c /v ""
') do <"%file%">.tmp (
 for /l %%j in (1 1 %%i) do (
  set "x="
  set/p x=
  if not defined x (
   echo.
  ) else (
   for /f %%k in ('set/a %%j') do (
    for %%l in (%add#%) do (
     if %%k equ %%l (
      cmd/v/c echo.#!x!
      set flag=*
     )
    )
    for %%l in (%del#%) do (
     if %%k equ %%l (
      cmd/v/c echo.!x:*#^^=!
      set flag=*
     )
    )
    if not defined flag (
     cmd/v/c echo.!x!
    )
    set "flag="
   )
  )
 )
)
>nul move .tmp "%file%"
 
exit/b 0

@echo off
 
set "add#=1 3 5 7 9"
set "del#=2 4 6 8 10"
 
for %%# in (
 
 "example_1.ini"
 "example_2.ini"
 "example_3.ini"
 
 ) do (
 
 for /f %%i in ('
  ^<"%%~#" find/c /v ""
 ') do <"%%~#">.tmp (
  for /l %%j in (1 1 %%i) do (
   set "x="
   set/p x=
   if not defined x (
    echo.
   ) else (
    for %%k in (%add#%) do (
     if %%j equ %%k (
      cmd/v/c echo.#!x!
      set flag=*
     )
    )
    for %%k in (%del#%) do (
     if %%j equ %%k (
      cmd/v/c echo.!x:*#^^=!
      set flag=*
     )
    )
    if not defined flag (
     cmd/v/c echo.!x!
    )
    set "flag="
   )
  )
 )
 >nul move .tmp "%%~#"
)
 
exit/b 0