Объединение содержимого одноимённых текстовых файлов

@echo off
 
2>nul del/a/f *.txt
 
for /f "delims=" %%i in ('2^>nul dir/a-d/b/s "*.txt"') do (
 set "*%%~nxi=*"
)
for /f "delims=*=" %%i in ('set *') do (
 for /f "delims=" %%j in ('2^>nul dir/a-d/b/s "%%i"') do (
  <"%%j">>"%%i" more
 )
)
 
exit/b

@echo off
 
set "source=D:\back"
set "destination=D:\rezult"
 
for /f "delims=" %%i in ('2^>nul dir/a-d/b/s "%source%\*.txt"') do (
 set "*%%~nxi=*"
)
for /f "delims=*=" %%i in ('set *') do >"%destination%\%%i" (
 for /f "delims=" %%j in ('2^>nul dir/a-d/b/s "%source%\%%i"') do @(
  <"%%j" more
 )
)
 
exit/b

@echo off
if exist "%temp%\~?.tmp" (2>nul del /f "%temp%\~?.tmp")
 
:: корневая папка
set "root=d:\root"
:: папка куда будут записаны объединенные файлы
set "result=d:\result"
if not exist "%result%\" md "%result%"
 
chcp 1251
:: составление списка
for /f "delims=" %%i in ('2^>nul dir /b/s/a-d "%root%"') do (
  echo %%~nxi^|%%i>>%temp%\~1.tmp
)
:: слияние файлов
for /f "tokens=1,2 delims=|" %%i in (%temp%\~1.tmp) do (
  type "%%j">>"%result%\%%i"
  echo.>>"%result%\%%i"
)
exit/b
 
::-------------------------------------------------------------------
:: слияние файлов - вариант с созданием доп. подпапок с именем файла
for /f "tokens=1,2 delims=|" %%i in (%temp%\~1.tmp) do (
  if not exist "%result%\%%~nj\" md "%result%\%%~nj" 
  type "%%j">>"%result%\%%~nj\%%i"
  echo.>>"%result%\%%~nj\%%i"  
 
)

@echo off
set "input=C:\test_1"
set "output=C:\test_2"
for /f "tokens=* delims=" %%a in ('powershell -executionpolicy bypass -command "$group=Get-ChildItem '%input%' -file -recurse -include '*.txt' | foreach -Begin {$array=@()} -process {$array+=$_.name} -end {$array} | Group-Object; foreach ($a in $group) {if ($a.count -ge 2) {$a.name}}"') do (
    for /f "tokens=* delims=" %%b in ('dir /a-d/b/s "%input%\*.txt"') do (
        if "%%a"=="%%~nxb" (
            type "%%b" >>"%output%\result_%%~na.txt"
        )
    )
)
pause
exit