Сохранять скопированные файлы в папках с теми же именами, что и у папок, в которых находятся копируемые файлы

@echo off
if "%~4" neq "" goto :begin
::1-й аргумент "Из какой папки копировать"
::2-й аргумент "Какое брать расширение(я)"
::3-й аргумент "В какую папку копировать"
::4-й аргумент - системное ключевое слово (не трогать)
call "%~f0" "f:" "*.dbf *.dmp" "w:\dbf\12104" do
call "%~f0" "A:" "*.dbf *.dmp" "w:\dbf\12104" do
::call "%~f0" "l:\Bash3" "*.tmp *.bak *.dmp" "l:\AllCMD3" do
goto :eof
 
:begin
::// В скрипт включена демонстрация поддержки файлов//папок с буквами украинского алфавита
Setlocal EnableDelayedExpansion
::Откуда копировать (берется из аргумента при запуске батника)
Set From=%~1
::Искомое расширение(я) файлов (берется из аргумента при запуске батника)
Set Ext=%~2
::Куда копировать (берется из аргумента при запуске батника)
Set To=%~3
 
if not exist "%To%\%DATE%" md "%To%\%DATE%"
 
chcp 1251>nul
Set LanguageFlag=true
 
if "%From:~-1%" neq "" Set From=%From%\
Call Set St="%From%%%ext: =","%From%%%"
 
for /f "delims=" %%A in ('dir /b /s /a:-d %St%') do (
  if defined LanguageFlag (chcp 866>nul& Set LanguageFlag=)
  echo Found %%~A  
  Call :GetEmptyName "%To%\%DATE%" "%%~nxA" NewName
  Echo --^> %To%\%DATE%\!NewName!
  copy "%%~A" "%To%\%DATE%\!NewName!" >nul
)
pause
goto :eof
 
:GetEmptyName %1-Folder %2-FileName %3-Var.Return %4-Optional.System.Num
if "%~4"=="" (
    Set "NewFileName=%~2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    Set Num=%~4
    Set /A Num+=1
    Call :GetEmptyName "%~1" "%~2" "%~3" "!Num!"
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B
)
Exit /B