Копирование логов из различных, по дате, папок

@echo off & prompt $G
setlocal EnableExtensions EnableDelayedExpansion
                                                :: корневой каталог логов
set "rootIN=c:\etc\logs"
                                                :: корневой каталог бэкапа логов
set "rootOUT=с:\etc\backup\logs"
 
for /f "usebackq delims=" %%D in (`dir "%rootIN%" /s/b/a:d`) do ( 
  echo:%%D
  if exist "%%D\*.*" (
    set "din1=%%D" & set "din2=!din1:%rootIN%=!"
    2>nul md "%rootOUT%!din2!"
    >nul copy /y "%%D\*.*" "%rootOUT%!din2!"
  )
)
pause
exit /b

@echo off & prompt $G & cls
setlocal EnableExtensions EnableDelayedExpansion
                                                :: корневой каталог логов
set "rootIN=c:\etc\logs"
                                                :: корневой каталог бэкапа логов
set "rootOUT=с:\etc\backup\logs"
                                                :: каталог для бэкапа
set "dirBackup=CompanyName2"
 
set /a cnt=0
for /f "usebackq delims=" %%D in (`dir "%rootIN%" /s/b/a:d`) do ( 
  call :GetLast "%%D"
  if /i "!GetLast!" == "%dirBackup%" if exist "%%D\*.*" (
    set /a "cnt+=1" & set "din1=%%D" & set "din2=!din1:%rootIN%=!"
    2>nul md "%rootOUT%!din2!"
    >nul copy /y "%%D\*.*" "%rootOUT%!din2!"||(echo:error copy "%%D\*.*")
  )
)
if %cnt% == 0 (echo:nothing copied...) else (echo:%cnt% file^(s^) copied...)
pause
exit /b
                        получить последний токен из %1
                        https://www.cyberforum.ru/post4304619.html
:GetLast
setlocal
  set "RC=%0" & set "RC=!RC:~1!"
  set "st=%~1"
  set "st="%st:\=" "%""
  for %%a in (%st%) do set st=%%~a
endlocal & set "%RC%=%st%" & exit /b 0