Обработка текстового файла. Поиск и вывод отдельных значений нумерованным списком с доп. условием

@Echo Off
cls
    >nul Chcp 1251
    
    Set "indextxt=C:\Program Files\OpenVPN\easy-rsa\keys\index.txt"
    Set "word=name"
 
    If Not Exist "%indextxt%" (
        Echo Файл "%indextxt%" не найден. &Echo.
        Pause
        Exit /B 2 
    ) 
 
    Set /A i=0
 
    Echo Введите номер, соответствующий сертификату, который требуется отозвать (Enter - завершение работы):
    Echo.
    For /F "usebackq tokens=13 Skip=3 delims=/=" %%s In (`2^>nul Find /I "%word%" "%indextxt%"`) Do (
        Call Set /A i+=1
        Call Set "@@%%i%%=%%s"
        Call Echo %%i%%. %%s
    )
    )
    If %i%==0 (
        Echo Пользовательские сертификаты не найдены  &Echo.
        Pause
        Exit /B 1 
    ) 
 
    :Begin
        Echo.
        Set "NN="
        Set /P NN=N=
        If "%NN%"=="" Exit /B 0
        If %NN% GEQ 1 If %NN% LEQ %i% (Call Set "Select=%%@@%NN%%%" &GoTo :End)
        Echo Введено неверное значение "%NN%", введите верное: &GoTo :Begin
    :End
    Echo вы выбрали: %Select%
 
Pause
Exit /B 0

@echo off
set "file=C:\test\list.txt"
powershell -executionpolicy bypass -command "Get-Content '%file%' | select -Skip 1 | foreach {if ($_ -match '^V') {[regex]::Match("""$($_)""",'CN=.+$').value} else {[regex]::Match("$($_)",'CN=.+$').value + ' [ОТОЗВАН]'}}"
pause
exit

@Echo Off
cls
>nul Chcp 1251
    Set "FileIn=Z:\Program Files\OpenVPN\easy-rsa\keys\index.txt"
 
    If Not Exist "%FileIn%" (Echo Файл "%FileIn%" не найден. &Echo. &Pause &Exit /B 2)
    
    Set /A y=0
    FOR /F "usebackq skip=1 tokens=1,7 delims=/" %%i In ("%FileIn%") DO (
        Set /A y+=1
        Set "xx=%%j"
        Call Set "@@%%y%%=%%xx:~3%%"
        Echo %%i| >nul 2>nul FindStr /B /I /C:"R"&&Call Set "@@%%y%%=%%xx:~3%% [ОТОЗВАН]"
    )
    If %y% EQU 0 (Echo Пользовательские сертификаты не найдены. &Echo. &Pause &Exit /B 1)
 
    Echo Введите номер, соответствующий сертификату, который требуется отозвать (Enter - завершение работы):
    Echo.
    FOR /L %%i In (1,1,%y%) Do (Set "xx=     %%i"&Call Echo %%xx:~-4%%. %%@@%%i%%)
 
    :Begin
        Echo.
        Set "NN="
        Set /P NN=Выбираем номер N=
        If "%NN%"=="" Exit /B 0
        If 1 LEQ %NN% If %NN% LEQ %y% (Call Set "Select=%%@@%NN%%%" &GoTo :End)
        Echo Введено неверное значение "%NN%", введите верное: &GoTo :Begin
    :End
    Echo вы выбрали: "%Select%"
pause
Exit /B