Командный файл, переименовывающий файл по тегу строки внутри файла с добавлением текущей даты и времени ГГГГММДД_ЧЧММСС

@echo off&pushd %~dp0&chcp 1251>nul
@set f=итог.txt
for /f "tokens=2 delims==" %%d in ('wmic os get localdatetime /format:list') do @set "d=%%~nd"
for /f "tokens=2 delims==" %%n in ('^<%f% find/i "номер="') do set n=%%n
if %n%==654987 (set x=1) else if %n%==123456 (set x=2) else if %n%==456987 (set x=3) else exit
if not exist D:\%x% md D:\%x%
move %f% D:\%x%\Группа%x%_%n%_%d:~,8%_%d:~8%.txt

@echo off
pushd %~dp0
chcp 1251>nul
set f=итог.txt
 
if not exist %f% (
   echo Рядом с %~nx0 нет файла %f%^!
   pause
   exit
)
 
for /f "tokens=2 delims==" %%d in (
   'wmic os get localdatetime /format:list'
) do set "d=%%~nd"
 
if not defined d (
   echo Проблема получения даты через wmic^!
   pause
   exit
)
 
for /f "tokens=2 delims==" %%n in (
   '^<%f% find/i "номер="'
) do set n=%%n
 
if not defined n (
   echo Проблема получения номера из файла. Проверьте кодировку %f%^!
   pause
   exit
)
 
 
if %n%==654987 (
   set x=1
) else (
   if %n%==123456 (
      set x=2
   ) else (
      if %n%==456987 (
         set x=3
      ) else (
         exit
      )
   )
)
 
if not exist i:\%x% md i:\%x%
move %f% i:\%x%\Группа%x%_%n%_%d:~,8%_%d:~8%.txt

for /f "tokens=2 delims==" %d in ('wmic os get localdatetime /format:list') do @echo %~nd

if not exist O:\%x% md O:\%x%
move %f% O:\%x%\Группа%x%_%n%_%d:~,8%_%d:~8%.txt

@echo off&pushd %~dp0&chcp 1251>nul
@set f=итог.txt
for /f "tokens=2 delims==." %%d in ('wmic os get localdatetime /format:list^|find "="') do @set "d=%%~nd"
for /f "tokens=2 delims==" %%n in ('^<%f% find/i "номер="') do set n=%%n
if %n%==654987 (set x=1) else if %n%==123456 (set x=2) else if %n%==456987 (set x=3) else exit
if not exist D:\%x% md D:\%x%
move %f% D:\%x%\Группа%x%_%n%_%d:~,8%_%d:~8%.txt