Копирование однотипных файлов - MultiDRIVE File Copier

@echo off
color 02
title MultiDRIVE File Copier by FraidZZ v0.1
chcp 1251>nul
setlocal enabledelayedexpansion enableextensions
set type=mp3
set foldername=mp3\
call :drivescanner
:startmenu
cls
echo.MultiDRIVE File Copier by FraidZZ v0.1
echo.Имя папки^: !foldername!
echo.Тип файлов^: !type!
echo.Активные диски^: !diskcounter!
if "!OK!"=="0" (echo Неизвестная команда или синтаксис) else (echo.)
set OK=0
echo.
echo.Введите help чтобы получить помощь по командам.
set solutin=""
set /p solution=
if /I "!solution!"=="help" (set OK=1& call :help)
for /f "usebackq tokens=1*" %%a IN ('!solution!') DO (
 if /I "%%a"=="drive" (set OK=1& call :drive %%~b)
)
for /f "usebackq tokens=1*" %%a IN ('!solution!') DO (
 if /I "%%a"=="type" (set OK=1& call :type %%~b)
)
for /f "usebackq tokens=1*" %%a IN ('!solution!') DO (
 if /I "%%a"=="foldername" (set OK=1& call :folder %%~b)
)
if /I "!solution!"=="start" (set OK=1& call :start)
if /I "!solution!"=="quit" (exit /b)
if /I "!solution!"=="updrive" (set OK=1&call :drivescanner)
if /I "!solution!"=="viewfolder" (set OK=1&call :viewfolder)
goto :startmenu
 
:drivescanner
for /f "usebackq tokens=1*" %%a IN (`fsutil fsinfo drives`) DO (
 set diskcounter=%%b
 set fdiskc=%%b
)
exit /b
:start
md !foldername:~0,-1!
for /f "usebackq tokens=1*" %%a IN ('!diskcounter!') DO (
 echo.%%a
 call :diskrecoursive %%a !foldername:~0,-1!
 set diskcounter=%%b
)
if not "!diskcounter!"=="" (goto :again)
cls
dir "!foldername:~0,-1!"
echo OK
echo Нажмите кнопку
pause>nul
exit /b
:diskrecoursive
For /R "%1" %%i IN (*.!type!) DO (
if not exist "!foldername!%%~nxi" (
echo.Copying %%~nxi
copy "%%i" "%2">>nul
) else (echo.File %%~nxi already copied)
)
exit /b
:help
cls
echo.foldername ^<имя папки^> - смена имени папки назначения
echo.drive add ^<X^:\^> - добавление диска в список, где X - буква диска
echo.drive del ^<X^:\^> - удаление диска из списка
echo.type ^<тип файлов^> - задать тип файлов
echo.start - начать копирование ^(Около 15 минут^)
echo.help - вывод этой справки
echo.viewfolder - просмотр активной папки
echo.quit - выход
echo.updrive - восстановить список дисков
echo.Нажмите любую кнопку
pause>nul
exit /b
:drive
set commm=%~1
set diskd=%~2
if "!commm!"=="add" (
call :isdisca !diskd!
call :isdiscb !diskd!
 if "!isdisca_!"=="0" (
  if "!isdiscb_!"=="1" (
   call :diskadd !diskd!
   exit /b
  ) else (cls & echo.Диск отсутсвует на компьютере & echo. Нажмите кнопку& pause>nul&exit /b)
 ) else (cls & echo.Диск уже есть в списке & echo. Нажмите кнопку& pause>nul&exit /b) 
)
if "!commm!"=="del" (
call :isdisca !diskd!
 if "!isdisca_!"=="1" (
   call :diskdel !diskd!
   exit /b
 ) else (cls & echo.Диска нет в списке & echo. Нажмите кнопку& pause>nul&exit /b)
)
cls
echo Неизвестная команда диска
echo Нажмите кнопку
pause>nul
exit /b
:isdisca
set mydisk=%~1
set disklista=!diskcounter!
set isdisca_=0
:scart
for /f "usebackq tokens=1*" %%a IN ('!disklista!') DO (
 if "%%a"=="!mydisk!" (set isdisca_=1)
 set disklista=%%b
)
if "!disklista!"=="" (exit /b)
goto :scart
 
:isdiscb
set mydisk=%~1
set disklistb=!fdiskc!
set isdiscb_=0
:scartb
for /f "usebackq tokens=1*" %%a IN ('!disklistb!') DO (
 if "%%a"=="!mydisk!" (set isdiscb_=1)
 set disklistb=%%b
)
if "!disklistb!"=="" (exit /b)
goto :scartb
:diskadd
set diskcounter=!diskcounter! %~1
exit /b
:diskdel
set mydiskd=%~1
set ustring=
set diskdeltemp=!diskcounter!
:againers
for /f "usebackq tokens=1*" %%a IN ('!diskdeltemp!') DO (
 if not "%%a"=="!mydiskd!" (set ustring=!ustring! %%a)
 set diskdeltemp=%%b
)
if "!diskdeltemp!"=="" (set diskcounter=!ustring!&exit /b)
goto :againers
:type
set type=%~1
exit /b
:folder
set relfolder=%~1
if "!relfolder:~-1!"=="\" (set foldername=!relfolder!) else (set foldername=!relfolder!\)
exit /b
:viewfolder
cls
if exist "!foldername!" (dir "!foldername:~0,-1!" /B&echo.&echo.Нажмите кнопку&pause>nul&exit /b) else (echo.Ошибка. Папка не созданa&echo.&echo.Нажмите кнопку&pause>nul&exit /b)