Отыскать и скопировать цифры, содержащиеся в самой нижней строке текстового файла, в другой текстовый файл

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::Исходный файл
set src=lom.txt
::Куда записывать
set dest=rom.txt
::Маска для поиска числа
set Num_Mask=87?????????
 
2>nul del "%dest%"
 
::Модифицируем маску согласно требованиям регулярных выражений
set Num_Mask=%Num_Mask:?=[0-9]%
::Получить последнюю строку
for /f "UseBackQ delims=" %%a in ("%src%") do set last=%%a
::Разбиваем по словам
set "words="!last: =" "!""
for %%w in (%words%) do (
  echo %%~w |>nul findstr /R "^%Num_Mask%$" && echo %%~w>>"%dest%"
)
 
pause
EndLocal
exit /B

::Поиск в строках в обратном порядке
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::Исходный файл
set src=lom.txt
::Куда записывать
set dest=rom.txt
::Маска для поиска числа
set Num_Mask=87?????????
 
2>nul del "%dest%"
 
::Модифицируем маску согласно требованиям регулярных выражений
set Num_Mask=%Num_Mask:?=[0-9]%
::Получить все строки в массив
for /f "UseBackQ delims=" %%a in ("%src%") do set n+=1& set line.!n!=%%a
::Читаем массив строк в обратном порядке
for /L %%C in (%n%,-1,1) do (
  rem Разбиваем по словам
  set "words="!line.%%C: =" "!""
  for %%w in (%words%) do (
    echo %%~w |>nul findstr /R "^%Num_Mask%$" && (echo %%~w>>"%dest%"& set found=true)
  )
  if defined found goto ext
)
:ext
 
pause
EndLocal
exit /B

::Поиск в строках в обратном порядке
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::Исходный файл
set src=log.txt
::Куда записывать
set dest=rom.txt
::Маска для поиска числа
set Num_Mask=87?????????
 
2>nul del "%dest%"
 
::Модифицируем маску согласно требованиям регулярных выражений
set Num_Mask=%Num_Mask:?=[0-9]%
::Получить все строки в массив
for /f "UseBackQ delims=" %%a in ("%src%") do set /A n+=1& set line.!n!=%%a
::Читаем массив строк в обратном порядке
for /L %%C in (%n%,-1,1) do (
  rem Разбиваем по словам
  set "words="!line.%%C: =" "!""
  for %%w in (!words!) do (
    echo %%~w|>nul findstr /R "^%Num_Mask%$" && (echo %%~w>>"%dest%"& set found=true)
  )
  if defined found goto ext
)
:ext
 
pause
EndLocal
exit /B

::Поиск в строках в обратном порядке
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
::Исходный файл
set src=log.txt
::Куда записывать
set dest=rom.txt
::Маска для поиска числа
set Num_Mask=87?????????
 
2>nul del "%dest%"
 
::Модифицируем маску согласно требованиям регулярных выражений
set Num_Mask=%Num_Mask:?=[0-9]%
::Фильтрация файла
findstr /R "%Num_Mask%" < "%src%" > "%dest%_"
::Получить все строки с отфильтрованного файла в массив
for /f "UseBackQ delims=" %%a in ("%dest%_") do set /A n+=1& set line.!n!=%%a
::Читаем массив строк в обратном порядке
for /L %%C in (%n%,-1,1) do (
  rem Разбиваем по словам
  set "words="!line.%%C: =" "!""
  for %%w in (!words!) do (
    echo %%~w|>nul findstr /R "^%Num_Mask%$" && (echo %%~w>>"%dest%"& goto ext)
  )
)
:ext
2>nul del "%dest%_"
 
pause
EndLocal
exit /B