Копирование папки на FTP-сервер

@echo off
Setlocal EnableDelayedExpansion EnableExtensions
 
::========= Настройки для отправляемых файлов ========
::Исходная папка с отправляемыми файлами (на сервере будет создана автоматически)
set SourceDir=D:\ftp
::Маска для отправляемых файлов
set mask=*.*
 
::Временный файл команд для утилиты FTP.exe
set CommFTP=%temp%\FTP_out.tmp
 
::========= Настройки для подключения к серверу FTP =========
::Адрес сервера - имя, либо IP-адрес
set host=*************
::Номер порта (по-умолчанию: 21)
set port=21
::Имя пользователя
set user=*********
::Пароль
set password=********
::Системная папка FTP (если на Вашем сервере такая отсутствует, не указывать)
set Mainfolder=public_html
::Подкаталог на FTP
set SubFolder=upload
 
::Убираем лишний концевой слэш, если такой указан
if "%SourceDir:~-1%"=="\" Set "SourceDir=%SourceDir:~0,-1%"
 
::Отделить только имя папки
For /D %%a In ("%SourceDir%") Do Set onlyDir=%%~na
 
Call :CheckConnection
Call :FTP_Init_String
ftp.exe -s:"%CommFTP%"
 
pause
endlocal
exit /B
 
 
:FTP_Init_String
::Начальная конфигурация подключения к FTP
> "%CommFTP%" (
  echo open %host% %port%
  echo %user%
  echo.%password%
  echo binary
  echo prompt
  echo hash
  echo lcd "%SourceDir%"
  if "%Mainfolder%" neq "" echo cd "%Mainfolder%"
  if "%SubFolder%" neq "" echo cd "%SubFolder%"
  echo mkdir "%onlyDir%"
  echo cd "%onlyDir%"
  echo mput %mask%
  echo disconnect
  echo bye
)
exit /b
 
:CheckConnection
  ping -n 1 8.8.8.8 |>nul find /i "TTL=" || (echo Нет подключения к сети Интернет& Goto :CheckConnection)
exit /b

@echo off
Setlocal EnableExtensions
 
::========= Настройки для отправляемых файлов ========
::Исходная папка с отправляемыми файлами (на сервере будет создана автоматически)
set "SourceDir=%~dp0struct"
::Маска для отправляемых файлов
set mask=*.*
 
::Временный файл команд для утилиты FTP.exe
set CommFTP=FTP_out.tmp
 
::========= Настройки для подключения к серверу FTP =========
::Адрес сервера - имя, либо IP-адрес
set host=dragokas.ftp.ukraine.com.ua
::Номер порта (по-умолчанию: 21)
set port=21
::Имя пользователя
set "user=xxxxx"
::Пароль
set "password=xxxxx"
::Системная папка FTP (если на Вашем сервере такая отсутствует, не указывать)
set Mainfolder=/dragokas.com/www
::Подкаталог на FTP
set SubFolder=temp
 
::Добавляем утилиту FTP в исключения брандмауера Windows
netsh firewall add allowedprogram "%windir%\system32\ftp.exe" ENABLE >nul
 
::Убираем лишний концевой слэш, если такой указан
if "%SourceDir:~-1%"=="" Set "SourceDir=%SourceDir:~0,-1%"
 
::Отделить только имя папки
For /D %%a In ("%SourceDir%") Do Set "onlyDir=%%~nxa"& set "PrefixDir=%%~dpa"
set "PrefixDir=%PrefixDir:\=/%"
 
Call :CheckConnection
Call :FTP_Init_String
 
ftp.exe -s:"%CommFTP%"
 
del /f /a "%CommFTP%"
 
pause
endlocal
exit /B
 
:FTP_Init_String
::Начальная конфигурация подключения к FTP
if "%Mainfolder%" neq "" (
  if "%SubFolder%" neq "" (
    set "RootFld=%Mainfolder%/%SubFolder%"
  ) else (
    set "RootFld=%Mainfolder%"
  )
)
 
> "%CommFTP%" (
  echo open %host% %port%
  echo %user%
  cmd /v /c echo(!password!
  echo quote PASV
  echo binary
  echo prompt
  echo hash
  echo lcd "%SourceDir%"
  echo cd "%RootFld%"
  echo mkdir "%onlyDir%"
  echo cd "%onlyDir%"
  echo mput %mask%
  for /f "delims=" %%a in ('dir /b /s /ad "%SourceDir%\*"') do call :substitute "%%a"
  echo disconnect
  echo bye
)
exit /b
 
:substitute
  :: заменяю родительскую директорию локального диска на родительскую директорию FTP
  set "fld=%~1"
  set "fld=%fld:\=/%"
  cmd /v /c echo mkdir "!fld:%PrefixDir%=%RootFld%/!"
  cmd /v /c echo cd "!fld:%PrefixDir%=%RootFld%/!"
  echo lcd "%~1"
  echo mput %mask%
exit /b
 
:CheckConnection
  ping -n 1 8.8.8.8 |>nul find /i "TTL=" || (echo Нет подключения к сети Интернет& Goto :CheckConnection)
exit /b