Можно ли и как запустить в программе, написанной на Delphi 7, 12 разных циклов одновременно?

unit Unit1;
 
interface
 
uses
  classes, types, forms, ExtCtrls, Controls, StdCtrls, SysUtils, Dialogs,
  System.Generics.Collections, vcl.imaging.jpeg;
 
type
  TMyThread=class(TThread)
    FCount:integer;
    Result:integer;
    constructor Create(ACount:integer; TermProc:TNotifyEvent);
    procedure Execute; override;
  end;
 
 
  TForm1 = class(TForm)
    bStart: TButton;
    m1: TMemo;
    procedure bStartClick(Sender: TObject);
  private
    T1:int64;
    Started:integer;
    Finished:integer;
    Sum:integer;
    procedure ThreadTerminated(Sender: TObject);
    procedure RunThread;
  end;
 
var
  Form1: TForm1;
 
implementation
 
const
  max_th=1000;
  max_same_time=10;
 
 
{$R *.dfm}
 
 
{ TForm1 }
 
 
procedure TForm1.RunThread;
var
  th:TMyThread;
begin
  th:=TMyThread.Create(random(20),ThreadTerminated);
//  m1.lines.add('begin -- '+inttostr(Started));
  th.Start;
  Inc(Started);
end;
 
procedure TForm1.bStartClick(Sender: TObject);
begin
  bStart.Enabled := false;
  m1.lines.clear;
  t1:=TThread.GetTickCount;
  Started := 0;
  Finished := 0;
  Sum := 0;
  while Started < max_same_time do
    runThread;
end;
 
 
procedure TForm1.ThreadTerminated(Sender:TObject);
var
  th:TMyThread absolute Sender;
begin
  Inc(Finished);
//  m1.lines.add('end -- '+inttostr(th.Result));
  Sum:=Sum+th.Result;
 
  if Started<max_th then
    RunThread;
 
  if Finished=max_th then
  begin
    m1.lines.add('========================');
    m1.lines.add('Итог: '+inttostr(sum));
    m1.Lines.Add(IntToStr(max_th)+' threads');
    m1.Lines.Add(IntToStr(TThread.GetTickCount-t1)+' msec');
    bStart.Enabled:=true;
  end;
end;
 
 
{ TMyThread }
constructor TMyThread.Create(ACount: integer; TermProc: TNotifyEvent);
begin
  inherited Create(true);
  FreeOnTerminate := true;
  FCount := ACount;
  OnTerminate := TermProc;
end;
 
 
procedure TMyThread.Execute;
var
  i: Integer;
begin
  for i := 0 to FCount-1 do
    result := result + Random(100);
end;
 
end.

unit Unit1;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
 
type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure EndThreadWork(Sender: TObject);
  end;
 
  TMyThread = class(TThread)
    FThreadNumber: byte;
    FStartValue: integer;
    FEndValue: integer;
    FResult: integer;
  protected
    procedure Execute; override;
  end;
 
var
  Form1: TForm1;
  thrCount: byte;
  totalSumm: integer;
 
implementation
 
{$R *.dfm}
 
{ TMyThread }
 
procedure TMyThread.Execute;
var
  i: word;
begin
  FResult:= 0;
  for i:= FStartValue to FEndValue do
    FResult:= FResult + i;
end;
 
// ========================================================================================
 
procedure TForm1.Button1Click(Sender: TObject);
var
  i: byte;
  MyThread: TMyThread;
begin
  // START
  Memo1.Clear;
  thrCount:= 11;
  totalSumm:= 0;
  // create Threads
  for i:= 0 to Pred(thrCount) do
  begin
    MyThread:= TMyThread.Create(true);
    MyThread.FreeOnTerminate:= true;
    MyThread.OnTerminate:= EndThreadWork;
    MyThread.FThreadNumber:= i;    // для контроля
    MyThread.FStartValue:= i * 1000;
    MyThread.FEndValue:= i * 1000 + 999;
    MyThread.Start;
  end;
end;
 
// ========================================================================================
 
procedure TForm1.EndThreadWork(Sender: TObject);
var
  MyThread: TMyThread absolute Sender;
begin
  // очередной поток завершил работу. считывание результата
  Memo1.Lines.Add(Format('Поток %d завершил работу. Результат %d',[MyThread.FThreadNumber,MyThread.FResult]));
  totalSumm:= totalSumm + MyThread.FResult;
  Dec(thrCount);
  if thrCount = 0 then  // все потоки завершили работу
  begin
    Memo1.Lines.Add('=========================');
    Memo1.Lines.Add(Format('Total Summ: %d',[totalSumm]));
    // МОЖЕШЬ ТЕПЕРЬ ХОТЬ ДО СКОНЧАНИЯ ВЕКОВ ПРОИЗВОДИТЬ СЛОЖНЫЕ ВЫЧИСЛЕНИЯ С РЕЗУЛЬТАТОМ!
  end;
end;
 
end.