Составить программу, которая подсчитывает количество ключевых слов «begin» и «end», и выводит соответствующее сообщение.

procedure TForm1.Button1Click(Sender: TObject);
const
  //Список разделителей, которые в программе могут выделять зарезервированные
  //слова.
  D = [' ', #9, #10, #13, '.', ',', ':', ';', '(', ')', '{', '}', '[', ']', ''''];
var
  S, StrWord : String;
  i, Len, LenW, CntBegin, CntEnd : Integer;
  IsComment1, IsComment2, IsComment3, IsStrConst : Boolean;
begin
  {
  Эта программа подсчитывает количество зарезервированных слов "BEGIN" и "END"
  в исходном тексте программы на языке PASCAL. При подсчёте программа
  не учитвает те "BEGIN" и "END", которые присутствуют внутри комментариев
  и внути строковых литералов.
  Если с помощью этой программы проверить исходный код этой же программы, то
  ответ будет таким:
  Статистика:
  Зарезервированное слово "BEGIN" встречается 12 раз.
  Зарезервированное слово "END" встречается 14 раз.
  ---
  При этом, общее количество слов "BEGIN" и "END" в этом коде такое:
  BEGIN: 19
  END:   21
  }
 
  //Исходный текст.
  S := Memo1.Text;
 
  Len := Length(S);
  LenW := 0;
  IsComment1 := False;
  IsComment2 := False;
  IsComment3 := False;
  IsStrConst := False;
  CntBegin := 0;
  CntEnd := 0;
  for i := 1 to Len do begin
    //Отслеживаем конец комментариев и записей строковых констант.
    if IsComment1 and ( S[i] in [#10, #13] ) then begin
      IsComment1 := False;
      Continue;
    end else if IsComment2 and ( S[i] = ')' ) and ( S[i - 1] = '*' ) then begin
      IsComment2 := False;
      Continue;
    end else if IsComment3 and ( S[i] = '}' ) then begin
      IsComment3 := False;
      Continue;
    end else if IsStrConst and ( S[i] = '''' ) then begin
      IsStrConst := False;
      Continue;
    end;
 
    //Если текущий символ расположен внутри комментария или внутри
    //записи строковой константы - пропускаем итерацию.
    if IsComment1 or IsComment2 or IsComment3 or IsStrConst then Continue;
 
    //Отслеживаем начало комментариев и записей строковых констант.
    if ( i > 1 ) then begin
      if ( S[i] = '/' ) and ( S[i - 1] = '/') then begin
        IsComment1 := True;
        Continue;
      end else if ( S[i] = '*' ) and ( S[i - 1] = '(' ) then begin
        IsComment2 := True;
        Continue;
      end;
    end;
    if S[i] = '{' then begin
      IsComment3 := True;
      Continue;
    end else if S[i] = '''' then begin
      IsStrConst := True;
      Continue;
    end;
 
    //Пропускаем разделители.
    if S[i] in D then Continue;
    //Уточняем длину слова.
    Inc(LenW);
    //Отслеживаем конец слова.
    if (i = Len) or (S[i + 1] in D) then begin
      //Исследуем найденное слово.
      StrWord := AnsiUpperCase( Copy(S, i - LenW + 1, LenW) );
      if StrWord = 'BEGIN' then
        Inc(CntBegin)
      else if StrWord = 'END' then
        Inc(CntEnd)
      ;
      //Сброс длины слова.
      LenW := 0;
    end;
  end;
 
  //Показ результатов.
  ShowMessage(
    'Статистика:' + #10
    + 'Зарезервированное слово "BEGIN" встречается ' + IntToStr(CntBegin) + ' раз.' + #10
    + 'Зарезервированное слово "END" встречается ' + IntToStr(CntEnd) + ' раз.'
  );
end;