Создание отчета в Word

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  wdAlignParagraphCenter = 1;
  wdAlignParagraphLeft = 0;
  wdAlignParagraphRight = 2;
 
  wdLineStyleSingle = 1;
var
  wdApp, wdDoc, wdRng, wdTable : Variant;
  i, j, Res : Integer;
  D : TDateTime;
  Bm : TBookMark;
  Sd : TSaveDialog;
begin
  //{
  Sd := SaveDialog1; //SaveDialog1 уже должен быть на форме.
  //Если начальная папка диалога не задана, то в качестве начальной берём ту папку,
  //в которой расположен исполняемый файл нашей программы.
  if Sd.InitialDir = '' then Sd.InitialDir := ExtractFilePath( ParamStr(0) );
  //Запуск диалога сохранения файла.
  if not Sd.Execute then Exit;
  //Если файл с заданным именем существует, то запускаем диалог с пользователем.
  if FileExists(Sd.FileName) then begin
    Res := MessageBox(0, 'Файл с заданным именем уже существует. Перезаписать?'
      ,'Внимание!', MB_YESNO + MB_ICONQUESTION + MB_APPLMODAL);
    if Res <> IDYES then Exit;
  end;
  
  //Попытка запустить MS Word.
  try
    wdApp := CreateOleObject('Word.Application');
  except
    MessageBox(0, 'Не удалось запустить MS Word. Действие отменено.'
      ,'Внимание!', MB_OK + MB_ICONERROR + MB_APPLMODAL);
    Exit;
  end;
 
  //Делаем видимым окно MS Word. На постоянной основе или на время отладки.
  wdApp.Visible := True;
  //Создаём новый документ.
  wdDoc := wdApp.Documents.Add;
  //На случай, если очень много данных и wdApp.Visible := True - тогда
  //для ускорения работы отключаем перерисовку окна MS Word.
  wdApp.ScreenUpdating := False;
  try
    wdRng := wdDoc.Content; //Диапазон, охватывающий всё содержимое документа.
 
    //Параграф 1. Заголовок отчёта.
 
    //Заголовок отчёта и перевод строки.
    wdRng.InsertAfter('Отчёт'#13#10);
    //Выравнивание по центру.
    wdRng.ParagraphFormat.Alignment := wdAlignParagraphCenter;
    //Параметры шрифта.
    wdRng.Font.Name := 'Times New Roman';
    wdRng.Font.Bold := True;
    wdRng.Font.Size := 14;
 
    //Параграф 2. Общие сведения.
 
    //Формируем диапазон нового параграфа непосредственно за текущим диапазоном.
    wdRng.Start := wdRng.End;
    wdRng.InsertAfter(#13#10);
    D := Now;
    wdRng.InsertAfter('Дата: ' + FormatDateTime('dd.mm.yyyy', D) + #13#10);
    wdRng.InsertAfter('Время: ' + FormatDateTime('hh:nn:ss:zzz', D) + #13#10);
    //Сброс параметров параграфа.
    wdRng.ParagraphFormat.Reset;
    //Выравнивание по левому краю.
    wdRng.ParagraphFormat.Alignment := wdAlignParagraphLeft;
    //Отступ слева на 2 сантиметра. Размер отступа задаётся в типографских
    //единицах - в пунктах. 1 пункт = 0.035 сантиметра.
    //При записи в поле LeftIndent, отступ отсчитывается от левого поля на странице.
    //wdRng.ParagraphFormat.LeftIndent := 2 / 0.035;
    //Параметры шрифта.
    wdRng.Font.Reset; //Сброс параметров шрифта.
    wdRng.Font.Size := 12;
    wdRng.Font.Bold := True;
 
    //Параграф 3. Заголовок таблицы.
 
    wdRng.Start := wdRng.End;
    wdRng.InsertAfter(#13#10);
    wdRng.InsertAfter('Таблица 1. Размер и население стран.'#13#10);
    wdRng.ParagraphFormat.Reset;
    wdRng.Font.Reset;
    wdRng.Font.Size := 12;
    wdRng.Font.Bold := False;
 
    //Параграф 4. Таблица.
 
    if not Query1.Active then Query1.Open;
 
    wdRng.Start := wdRng.End;
    //Добавляем таблицу MS Word. Пока создаём таблицу с двумя строками.
    wdTable := wdDoc.Tables.Add(wdRng.Characters.Last, 2, Query1.Fields.Count);
    //Параметры линий таблицы.
    wdTable.Borders.InsideLineStyle := wdLineStyleSingle;
    wdTable.Borders.OutsideLineStyle := wdLineStyleSingle;
    //Сброс параметров параграфа.
    wdRng.ParagraphFormat.Reset;
    //Выравнивание всей таблицы - по левому краю.
    wdRng.ParagraphFormat.Alignment := wdAlignParagraphLeft;
    //Оформление шапки.
    wdRng := wdTable.Rows.Item(1).Range; //Диапазон первой строки.
    wdRng.ParagraphFormat.Alignment := wdAlignParagraphCenter;
    wdRng.Font.Size := 10;
    wdRng.Font.Bold := True;
    //Оформление первой строки данных - это вторая строка в таблице.
    //При добавлении следующих строк, их оформление будет копироваться с этой строки.
    wdRng := wdTable.Rows.Item(2).Range; //Диапазон второй строки.
    wdRng.ParagraphFormat.Alignment := wdAlignParagraphLeft;
    wdRng.Font.Size := 10;
    wdRng.Font.Bold := False;
 
    //Записываем шапку таблицы.
    for i := 0 to Query1.Fields.Count - 1 do
      wdTable.Cell(1, i + 1).Range.Text := Query1.Fields[i].DisplayName;
    //Записываем данные таблицы.
    Query1.DisableControls;
    Bm := Query1.GetBookMark;
    Query1.First;
    i := 1; //Текущая строка в таблице MS Word.
    while not Query1.Eof do begin
      Inc(i);
      //Если требуется, добавляем новую строку в конец таблицы.
      if i > 2 then wdTable.Rows.Add;
      //Записываем данные в строку таблицы MS Word.
      for j := 0 to Query1.Fields.Count - 1 do
        wdTable.Cell(i, j + 1).Range.Text := Query1.Fields[j].AsString;
      Query1.Next;
    end;
    Query1.GotoBookMark(Bm);
    Query1.EnableControls;
 
  finally
    //Включение перерисовки окна MS Word. В случае, если wdApp.Visible := True.
    wdApp.ScreenUpdating := True;
  end;
 
  wdApp.DisplayAlerts := False; //Отключаем режим показа предупреждений.
  try
    wdDoc.SaveAs(FileName:=Sd.FileName); //Запись документа в файл.
  finally
    wdApp.DisplayAlerts := True; //Включаем режим показа предупреждений.
  end;
 
  //Закрываем документ.
  //wdDoc.Close;
  //Закрываем MS Word.
  //wdApp.Quit;
end;

wdApp.Activate;

  //Делаем видимым окно MS Word. На постоянной основе или на время отладки.
  wdApp.Visible := True;
  //Активируем окно MS Word.
  wdApp.Activate;

unit Unit2;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, DB, Grids, DBGrids, DBTables, Menus,
  ExtCtrls, DBCtrls, BDE,   Mask,ComObj,
 Buttons, ExtDlgs, JPEG,  Consts,ShellAPI;
 
type
  TForm2 = class(TForm)
    Table1: TTable;
    DBGrid1: TDBGrid;
    DataSource1: TDataSource;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    MainMenu1: TMainMenu;
    N1: TMenuItem;
    N2: TMenuItem;
    N3: TMenuItem;
    N4: TMenuItem;
    N5: TMenuItem;
    N6: TMenuItem;
    N7: TMenuItem;
    N8: TMenuItem;
    N9: TMenuItem;
    N10: TMenuItem;
    N11: TMenuItem;
    N12: TMenuItem;
    Edit1: TEdit;
    ComboBox1: TComboBox;
    N13: TMenuItem;
    N14: TMenuItem;
    N15: TMenuItem;
    N16: TMenuItem;
    GroupBox1: TGroupBox;
    CheckBox1: TCheckBox;
    CheckBox2: TCheckBox;
    CheckBox3: TCheckBox;
    CheckBox4: TCheckBox;
    CheckBox5: TCheckBox;
    CheckBox6: TCheckBox;
    DBImage1: TDBImage;
    DBMemo1: TDBMemo;
    Image1: TImage;
    Label1: TLabel;
    Label2: TLabel;
    N17: TMenuItem;
    Excel1: TMenuItem;
    Excel2: TMenuItem;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button2Click(Sender: TObject);
    procedure N7Click(Sender: TObject);
    procedure N8Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Table1FilterRecord(DataSet: TDataSet; var Accept: Boolean);
    procedure Edit1Change(Sender: TObject);
    procedure N15Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure N12Click(Sender: TObject);
    procedure N16Click(Sender: TObject);
    procedure CheckBox1Click(Sender: TObject);
    procedure CheckBox2Click(Sender: TObject);
    procedure CheckBox3Click(Sender: TObject);
    procedure CheckBox4Click(Sender: TObject);
    procedure CheckBox5Click(Sender: TObject);
    procedure CheckBox6Click(Sender: TObject);
    procedure N13Click(Sender: TObject);
    procedure N11Click(Sender: TObject);
    procedure N9Click(Sender: TObject);
    procedure N5Click(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure Excel2Click(Sender: TObject);
    procedure Excel1Click(Sender: TObject);
    procedure N17Click(Sender: TObject);
 
  private
    { Private declarations }
    procedure NewGridWinProc(var Msg: TMessage);
  public
    { Public declarations }
  end;
Type MyRec=Record
           Name:string[255];
           Age:byte;
           Ar:array[1..10] of integer;
        End;
var
  Form2: TForm2;
  MyVar:MyRec;
 f:File of MyRec;
 
implementation
 
uses Unit1, Unit3, Unit4, Unit5;
{$R *.dfm}
 
var OldGridWinProc: TWndMethod;
 
 
 
 
procedure TForm2.Button1Click(Sender: TObject);
begin
form5.show;
form2.hide;
end;
 
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
if Table1.Active then // ???? ??????? ???????, ??
    begin
      Table1.FlushBuffers; // ????? ????????? ?? ??????? ? ???? biolifes.db
      Table1.Close; // ???????? ???????
      form1.Close;
    end;
 
end;
 
procedure TForm2.Button2Click(Sender: TObject);
begin
form3.show;
table1.insert;
end;
              
procedure TForm2.N7Click(Sender: TObject);
begin
Close;
end;
 
procedure TForm2.N8Click(Sender: TObject);
begin
form3.show;
table1.insert;
end;
 
procedure TForm2.Button3Click(Sender: TObject);
begin
form3.Show;
form2.Table1.Edit
 
end;
 
procedure TForm2.Button4Click(Sender: TObject);
begin
table1.Delete;
application.Title:=('Îïîâåùåíèå');
showmessage('Çàïèñü óäàëåíà!');
end;
 
procedure TForm2.Table1FilterRecord(DataSet: TDataSet;
  var Accept: Boolean);
var
    a,f:string;
begin
  case ComboBox1.ItemIndex of
  0:  f:='Name';
  1:  f:='Year';
  2:  f:='Country';
  3:  f:='Mass';
  4:  f:='Len';
  5:  f:='Capacity';
  end;
  if VarIsNull(DataSet[f]) then
  begin
 
  end
  else
  begin
    a := Copy(DataSet[f],1, Length(Edit1.Text));
    Accept := a = Edit1.text;
  end;
end;
 
 
 
procedure TForm2.Edit1Change(Sender: TObject);
begin
if Edit1.Text = ('') then begin
  Table1.Filtered:=False end
  else Table1.Filtered:=True;
end;
 
procedure TForm2.N15Click(Sender: TObject);
begin
if N15.Checked=true then begin
label1.Show;
label2.Show;
combobox1.Show;
edit1.Show;
end
else
begin
label1.hide;
label2.hide;
combobox1.hide;
edit1.hide;
end;
end;
 
procedure TForm2.FormCreate(Sender: TObject);
begin
label1.hide;
label2.hide;
combobox1.hide;
edit1.hide;
groupbox1.Hide;
checkbox1.Hide;
checkbox2.Hide;
checkbox3.Hide;
checkbox4.Hide;
checkbox5.Hide;
checkbox6.Hide;
 
 
 OldGridWinProc := DBGrid1.WindowProc;
 DBGrid1.WindowProc := NewGridWinProc;
end;
 
procedure TForm2.N12Click(Sender: TObject);
begin
Form4.Show;
end;
 
procedure TForm2.N16Click(Sender: TObject);
begin
Close;
end;
 
procedure TForm2.CheckBox1Click(Sender: TObject);
begin
if checkbox1.Checked=true then
begin
table1.IndexName:='N';
end;
 end;
procedure TForm2.CheckBox2Click(Sender: TObject);
begin
if checkbox2.Checked=true then
begin
table1.IndexName:='G';
end;
end;
 
procedure TForm2.CheckBox3Click(Sender: TObject);
begin
if checkbox3.Checked=true then
begin
table1.IndexName:='S';
end;
end;
 
procedure TForm2.CheckBox4Click(Sender: TObject);
begin
if checkbox4.Checked=true then
begin
table1.IndexName:='M';
end;
end;
 
procedure TForm2.CheckBox5Click(Sender: TObject);
begin
if checkbox5.Checked=true then
begin
table1.IndexName:='D';
end;
end;
 
procedure TForm2.CheckBox6Click(Sender: TObject);
begin
if checkbox6.Checked=true then
begin
table1.IndexName:='V';
end;
end;
 
procedure TForm2.N13Click(Sender: TObject);
begin
if N13.Checked=true then begin
groupbox1.Show;
checkbox1.Show;
checkbox2.Show;
checkbox3.Show;
checkbox4.Show;
checkbox5.Show;
checkbox6.Show;
end
else
begin
groupbox1.hide;
checkbox1.Hide;
checkbox2.Hide;
checkbox3.Hide;
checkbox4.Hide;
checkbox5.Hide;
checkbox6.Hide;
 
end;
   end;
   
procedure TForm2.N11Click(Sender: TObject);
begin
table1.Delete;
application.Title:=('Îïîâåùåíèå..');
showmessage('Çàïèñü óäàëåíà!');
end;
 
procedure TForm2.N9Click(Sender: TObject);
begin
form3.Show;
end;
 
procedure TForm2.N5Click(Sender: TObject);
begin
form5.Show;
form2.Hide;
end;
 
function BDEInstalled: Boolean;
begin
  Result:= (dbiInit(nil) = 0);
  if not Result then ShowMessage('BDE íå óñòàíîâëåí.');
end;
 
function TableActivate: boolean;
 var ExeDir, DbDir, DbFile: String;
begin
  Result:= false;
  if  BDEInstalled then
     begin
        ExeDir:= ExtractFilePath(Application.ExeName);
        DbDir:= ExeDir+'db\';
        DbFile:= DbDir+Form2.Table1.TableName;
        if FileExists(DbFile) then
           begin
              Form2.Table1.DataBaseName:= DbDir;
              Form2.Table1.Open;
              Result:= true;
          end;
    end;
end;
procedure TForm2.FormActivate(Sender: TObject);
begin
   if not TableActivate then ShowMessage('Íå óäàëîñü îòêðûòü òàáëèöó ÁÄ.');
 
end;
 
 
 
procedure TForm2.NewGridWinProc(var Msg: TMessage);
begin
   if Msg.Msg = WM_MOUSEWHEEL then 
     begin
       if SmallInt(HiWord(Msg.wParam)) > 0 then DBGrid1.DataSource.DataSet.Prior
        else DBGrid1.DataSource.DataSet.Next;
       Msg.Result := 1;
     end else OldGridWinProc(Msg);
end;
procedure TForm2.Excel2Click(Sender: TObject);
var
 XL, XArr: Variant;
 i: Integer;
 j: Integer;
begin
 
 XArr:=VarArrayCreate([1,form2.Table1.FieldCount],varVariant);
 XL:=CreateOLEObject('Excel.Application');     
 XL.WorkBooks.add;
 XL.visible:=true;
 
 j := 1;
 form2.Table1.First;
 while not form2.Table1.Eof do
  begin
   i:=1;
   while i<=form2.Table1.FieldCount do
    begin
     XArr[i] := form2.Table1.Fields[i-1].Value;
     i := i+1;
    end;
   XL.Range['A'+IntToStr(j),
   CHR(64+form2.Table1.FieldCount)+IntToStr(j)].Value := XArr;
   form2.Table1.Next;
   j:=j+1;
  end;
 XL.Range['A1',CHR(64+form2.Table1.FieldCount)+IntToStr(j)].select;
 // XL.cells.select;                     
 XL.Selection.Font.Name:='Arial cur';
 XL.Selection.Font.Size:=10;
 XL.selection.Columns.AutoFit;
 XL.Range['A1','A1'].select;
end;
 
procedure TForm2.Excel1Click(Sender: TObject);
begin
AssignFile(f,'MyFile.rec');
Rewrite(f);
MyVar.Name:='Yaroslav';
MyVar.Age:=17;
seek(f,100);
Write(f,MyVar);
Closefile(f);
end;
procedure TForm2.N17Click(Sender: TObject);
begin
  ShellExecute(Handle, 'open', 'Help\drexplain.chm',nil, nil, SW_SHOW);
end;
 
end.

XArr := VarArrayCreate([1, 1, 1, Table1.FieldCount], varVariant);

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Толщина линий.
  xlHairline = 1;   //Очень тонкая.
  xlThin = 2;       //Тонкая.
  xlMedium = -4138; //Средняя.
  xlThick = 4;      //Толстая.
  //Вид линии.
  xlContinuous = 1; //Непрерывная линия.
var
  exApp, exBook, exSh, exRng : OleVariant;
  VArr : Variant;
  Bm : TBookmark;
  i, j : Integer;
begin
  //1. Подготовка.
 
  //Запуск экземпляра Excel и получение ссылки на интерфейс корневого объекта (Excel.Application).
  exApp := CreateOleObject('Excel.Application');
  //Делаем видимым окно MS Excel.
  exApp.Visible := True;
  //Создаём рабочую книгу и получаем ссылку на её интерфейс.
  exBook := exApp.Workbooks.Add;
  //Ссылка на интерфейс первого рабочего листа в книге.
  exSh := exBook.Worksheets[1];
 
  //Открываем набор данных.
  Query1.Open;
  //Создаём двумерный вариантый массив. Он предназначен для записи всей таблицы.
  //Query1.RecordCount + 1 - здесь +1 для учёта шапки таблицы.
  VArr := VarArrayCreate([1, Query1.RecordCount + 1, 1, Query1.FieldCount], varVariant);
  //Определяем диапазон MS Excel, в который мы запишем таблицу.
  exRng := exSh.Range[exSh.Cells[3, 2],
    exSh.Cells[3, 2].Offset[Query1.RecordCount, Query1.FieldCount - 1]];
 
  //2. Запись шапки таблицы в вариантный массив.
 
  //Записываем в вариантный массив шапку таблицы с именами столбцов.
  j := 1; //Номер очередной строки в вариантном массиве.
  for i := 0 to Query1.FieldCount - 1 do
    VArr[j, i + 1] := Query1.Fields[i].FieldName;
 
  //3. Записываем в вариантный массив данные таблицы.
 
  //Запоминаем текущее положение в наборе данных.
  Bm := Query1.GetBookmark;
  //Отключаем набор от элементов просмотра и навигации.
  Query1.DisableControls;
  try
    //Перебор записей в наборе данных и их запись в Ms Excel.
    Query1.First;
    while not Query1.Eof do
    begin
      Inc(j); //Номер очередной строки в вариантном массиве.
      //Записываем в вариантный массив очередную строку набора данных.
      for i := 0 to Query1.FieldCount - 1 do
        VArr[j, i + 1] := Query1.Fields[i].Value;
      //Переход к следующей записи набора данных.
      Query1.Next;
    end;
  finally
    //Переходим к прежнему положению в наборе данных.
    Query1.GotoBookmark(Bm);
    //Подключаем набор к элементам просмотра и навигации.
    Query1.EnableControls;
  end;
 
  //4. Записываем вариантный массив на лист MS Excel.
  exRng.Value := VArr;
 
  //5. Оформление таблицы на листе MS Excel.
 
  //Оформление всей таблицы.
  exRng.Borders.LineStyle := xlContinuous;  //Обрамляющие линии - непрерывная.
  exRng.Borders.Weight := xlThin;           //Толщина обрамляющих линий - тонкая.
  //Дполнительное оформление шапки таблицы.
  exRng.Rows[1].Font.Bold := True;          //Шрифт - жирный.
  exRng.Rows[1].Borders.Weight := xlMedium; //Толщина обрамляющих линий - средняя.
  //Подбор ширины столбцов по содержимому.
  exRng.Columns.AutoFit;
end;

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Толщина линий.
  xlHairline = 1;   //Очень тонкая.
  xlThin = 2;       //Тонкая.
  xlMedium = -4138; //Средняя.
  xlThick = 4;      //Толстая.
  //Вид линии.
  xlContinuous = 1; //Непрерывная линия.
var
  exApp, exBook, exSh, exRng : OleVariant;
  VArr : Variant;
  Bm : TBookmark;
  i : Integer;
begin
  //1. Подготовка.
 
  //Запуск экземпляра Excel и получение ссылки на интерфейс корневого объекта (Excel.Application).
  exApp := CreateOleObject('Excel.Application');
  //Делаем видимым окно MS Excel.
  exApp.Visible := True;
  //Создаём рабочую книгу и получаем ссылку на её интерфейс.
  exBook := exApp.Workbooks.Add;
  //Ссылка на интерфейс первого рабочего листа в книге.
  exSh := exBook.Worksheets[1];
 
  //Открываем набор данных.
  Query1.Open;
  //Создаём двумерный вариантый массив. Он предназначен для записи отдельных строк.
  VArr := VarArrayCreate([1, 1, 1, Query1.FieldCount], varVariant);
  //Определяем диапазон MS Excel, который представляет одну строку в области,
  //где будет распечатана таблица. Вначале этот диапазон определяет верхнуюю строку.
  exRng := exSh.Range[exSh.Cells[3, 2],
    exSh.Cells[3, 2].Offset[0, Query1.FieldCount - 1]];
 
  //2. Запись шапки таблицы на лист MS Excel.
 
  //Записываем в вариантный массив шапку таблицы с именами столбцов.
  for i := 0 to Query1.FieldCount - 1 do
    VArr[1, i + 1] := Query1.Fields[i].FieldName;
  //Записываем вариантный массив на лист MS Excel.
  exRng.Value := VArr;
 
  //3. Запись данных таблицы на лист MS Excel.
 
  //Запоминаем текущее положение в наборе данных.
  Bm := Query1.GetBookmark;
  //Отключаем набор от элементов просмотра и навигации.
  Query1.DisableControls;
  try
    //Перебор записей в наборе данных и их запись в Ms Excel.
    Query1.First;
    while not Query1.Eof do
    begin
      //Переходим к следующей строке на листе MS Excel.
      exRng := exRng.Offset[1, 0];
      //Записываем в вариантный массив очередную строку набора данных.
      for i := 0 to Query1.FieldCount - 1 do
        VArr[1, i + 1] := Query1.Fields[i].Value;
      //Записываем вариантный массив на лист MS Excel.
      exRng.Value := VArr;
      //Переход к следующей записи набора данных.
      Query1.Next;
    end;
  finally
    //Переходим к прежнему положению в наборе данных.
    Query1.GotoBookmark(Bm);
    //Подключаем набор к элементам просмотра и навигации.
    Query1.EnableControls;
  end;
 
  //4. Оформление таблицы на листе MS Excel.
 
  //Определяем диапазон, в который мы записали данные.
  exRng := exSh.Range[exSh.Cells[3, 2], exRng.Cells[1, Query1.FieldCount]];
 
  //Оформление всей таблицы.
  exRng.Borders.LineStyle := xlContinuous;  //Обрамляющие линии - непрерывная.
  exRng.Borders.Weight := xlThin;           //Толщина обрамляющих линий - тонкая.
  //Дполнительное оформление шапки таблицы.
  exRng.Rows[1].Font.Bold := True;          //Шрифт - жирный.
  exRng.Rows[1].Borders.Weight := xlMedium; //Толщина обрамляющих линий - средняя.
  //Подбор ширины столбцов по содержимому.
  exRng.Columns.AutoFit;
end;

exSh.Cells[1, 2].Value := 'Заголовок';
exSh.Cells[1, 2].Font.Size := 16; //Размер шрифта = 16.
exSh.Cells[1, 2].Font.Bold := True; //Стиль шрифта - полужирный.

  //Например, если надо удалить столбцы с порядковыми номерами 7 и 9:
  exRng.Columns[9].Delete; //Удаление 9-го столбца.
  exRng.Columns[7].Delete; //Удаление 7-го столбца.

  exSh.Cells[2, 2].Value := 'Дата создания: '
    + FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now);