Особенности HRGN

unit Unit2;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;
 
type
  TForm2 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    RadioGroup1: TRadioGroup;
    ListBox1: TListBox;
    Label1: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure RadioGroup1Click(Sender: TObject);
  end;
 
  // режим рисования
  TMode = (mFullFigure,mDrawing);
 
const
  // статический массив
  ptsStatic: array[0..2] of TPoint = ((X:10;Y:50),(X:10;Y:300),(X:300;Y:50));
var
  // или так
  // ptsStatic: array[0..2] of TPoint = ((X:10;Y:50),(X:10;Y:300),(X:300;Y:50));
  Form2: TForm2;
  mode: TMode = mFullFigure;
  ptsDynamic: array of TPoint;
  hrgnStatic: HRGN = 0;
  hrgnDynamic: HRGN = 0;
 
implementation
 
{$R *.dfm}
 
// рисование жирной точки (для красоты :)
procedure DrawPoint(X,Y: word);
begin
  with Form2.Canvas do
  begin
    Pen.Width:= 5;
    MoveTo(X,Y);
    LineTo(X,Y);
    Pen.Width:= 1;
  end;
end;
 
procedure TForm2.Button1Click(Sender: TObject);
begin
  // начало рисования
  SetLength(ptsDynamic,0);
  mode:= mDrawing;
  RadioGroup1.Enabled:= false;
  Button1.Enabled:= false;
  Button2.Enabled:= true;
  Invalidate;
end;
 
procedure TForm2.Button2Click(Sender: TObject);
begin
  // конец рисования
  mode:= mFullFigure;
  RadioGroup1.Enabled:= true;
  Button1.Enabled:= true;
  Button2.Enabled:= false;
  // создаю регион из динамического массива точек
  hrgnDynamic:= CreatePolygonRgn(ptsDynamic,Length(ptsDynamic),WINDING);
  ListBox1.Items.Values['хэндл динамического региона']:= IntToStr(hrgnDynamic);
  Invalidate;
end;
 
procedure TForm2.FormCreate(Sender: TObject);
begin
  Canvas.Brush.Color:= clSkyBlue;
  // создаю регион из статического массива точек
  hrgnStatic:= CreatePolygonRgn(ptsStatic,Length(ptsStatic),WINDING);
  ListBox1.Items.Values['хэндл статического региона']:= IntToStr(hrgnStatic);
end;
 
procedure TForm2.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  // режим рисования фигуры. добавляю точку в массив
  if mode = mDrawing then
  begin
    SetLength(ptsDynamic,Length(ptsDynamic)+1);
    ptsDynamic[High(ptsDynamic)].X:= X;
    ptsDynamic[High(ptsDynamic)].Y:= Y;
    Invalidate;
  end else
  // или проверяю вхождение точки в регион
  begin
    DrawPoint(X,Y);
    if (ssCtrl in Shift)
      then ShowMessage('Точка принадлежит динамическому региону: ' +
                        BoolToStr(PtInRegion(hrgnDynamic,X,Y),true))
      else ShowMessage('Точка принадлежит статическому региону: ' +
                        BoolToStr(PtInRegion(hrgnStatic,X,Y),true));
  end;
end;
 
procedure TForm2.FormPaint(Sender: TObject);
var
  i: word;
begin
  // рисую статический регион
  PaintRgn(Canvas.Handle,hrgnStatic);
 
  case mode of
    // рисую динамический регион либо полигон
    mFullFigure:
    case RadioGroup1.ItemIndex of
      0: Canvas.Polygon(ptsDynamic);
      1: PaintRgn(Canvas.Handle,hrgnDynamic);
    end;
    // рисую поли-линию
    mDrawing:
    begin
      if Length(ptsDynamic) > 0 then
        for i:= Low(ptsDynamic) to High(ptsDynamic)
        do DrawPoint(ptsDynamic[i].X,ptsDynamic[i].Y);
      Canvas.Polyline(ptsDynamic);
    end;
  end;
end;
 
procedure TForm2.RadioGroup1Click(Sender: TObject);
begin
  // меняю режим рисования фигуры
  Invalidate;
end;
 
end.