Вывод списка mp3 файлов и их воспроизведение

@FromOutSide · Регистрация: 04.09.2014

Студворк — интернет-сервис помощи студентам

Я искал на форуме, находил что-то похожее, но не нашел то что нужно.
Нужно на delphi 7:
Чтобы выводился список в listbox, всех mp3 файлов в папках и подпапках допустим есть папки:
d:\music\album1\album1.1
d:\music\album1\album1.2
d:\music\album2\album2.1
Ну а вписывать можно или название лишь файла или с полным путем, но при этом стерев два первых символа пути
music1.mp3
\music\album1\album1.2\music1.mp3
\music\album2\album2.1\music1.mp3
Т.е. как бы весь путь, с полным именем
Возможности:Полоса перемотки. И через bitbtnЫ вкл, пауза, след, пред.
Для меня подобные процедуры, непонятны, так что прошу Вас, с комментариями к кодам. Ну или пинайте меня в нужную сторону

@FromOutSide · 19.06.2017, 12:44 **[ТС]**

Добавлено через 16 минут

Сообщение от DenNik

должно читать, пробуй

Перезагрузил оба компа. получилось, ну как получилось, видит лишь путь и файл, но запускать не хочет, ошибка при инициализации.
И как быть с ошибкой другой? Она возникает и с твоим кодом и другим одинаково, время от времени при переключении трэка.
И как, вот как сделать next и prev на картинках/кнопках?

DenNik · 19.06.2017, 13:02

а че ты вообще привязываешься к кнопкам МР? сделай отдельные процедуры

Delphi
1
2
3
4
5
6
procedure buttonclick;
begin
  // изменить Index
  // загрузить новій путь в МР
  // проиграть
end;

@FromOutSide · 19.06.2017, 15:11 **[ТС]**

Я пытался писать отдельные процедуры для кнопок МР. не получилось.
А вот что можно просто сделать процедуру, не пытаясь влиять на некст и прев, вот реально не подумал. извиняюсь.

Позже попробую.

Добавлено через 8 минут

Сообщение от krapotkin

Delphi
1
2
s:='D:\xxxx\yyyy\zzz.mp3';
fname:=extractFileName(s);

ну тут разобрался.

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
Procedure FindFileInFolder(path, ext: string);
Var SR : TSearchRec;
    Res : Integer;
begin
  Res := FindFirst(path+ext, faAnyFile, SR);
  while Res = 0 do
  begin
   form1.ListBox1.Items.Add(path+Sr.Name); //имена и путь
   form1.ListBox2.Items.Add(Sr.Name); //лишь имена
   Res := FindNext(SR);
  end;
  FindClose(SR);
  end;

Сообщение от krapotkin

а если так?

обязательно попробую, я почему то в упор раньше не видел этого сообщения

@Пытливый · 19.06.2017, 19:11

Вы еще громкость там не сделали, вот тут есть код, как это сделать.

@FromOutSide · 22.06.2017, 11:58 **[ТС]**

DenNik,
Я тебе очень благодарен! Но не мог бы ты уделить еще немножко времени?
Не мог ответить раньше, не был за компом.
Но вот что получилось.

DenNik · 22.06.2017, 12:06

Сообщение от FromOutSide

Но вот что получилось.

красиво получилось. а вопрос в чем? )

@FromOutSide · 22.06.2017, 12:07 **[ТС]**

А что хотел еще узнать, объясню на примере.
Допустим, вот есть путь
D:\mus
в нем лежат еще мноооожество папок,
и нужно что бы, в комбобокс, были выведены все пути, с исключением вот этого начала D:\mus
то есть пути будут выглядеть не D:\mus\Album1 а просто \Album1

@FromOutSide · 22.06.2017, 12:11 **[ТС]**

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, ExtCtrls, MPlayer, StdCtrls, jpeg;
 
type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    MediaPlayer1: TMediaPlayer;
    Timer1: TTimer;
    TrackBar1: TTrackBar;
    ListBox2: TListBox;
    Image1: TImage;
    Image2: TImage;
    Image3: TImage;
    Image4: TImage;
    Image5: TImage;
    procedure PP;
    procedure FormCreate(Sender: TObject);
    Procedure FindFileInFolder(path, ext: string);
    procedure playnext;
    procedure playprev;
    procedure TrackBar1Change(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Image2Click(Sender: TObject);
    procedure Image5Click(Sender: TObject);
    procedure Image3Click(Sender: TObject);
    procedure Image4Click(Sender: TObject);
    procedure ListBox2DblClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
 
var
  Form1: TForm1;
   CurrentIndex: integer = -1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
FindFileInFolder('D:\DLPH7'+'\', '*.mp3');
end;
 
procedure TForm1.TrackBar1Change(Sender: TObject);
begin
If TrackBar1.Position<>mediaplayer1.Position
then begin
mediaplayer1.Position:=TrackBar1.Position;
mediaplayer1.Play;
end;
end;
 
procedure TForm1.Timer1Timer(Sender: TObject);
begin
if MediaPlayer1.FileName<>''
then begin
TrackBar1.Max:=mediaplayer1.Length;
TrackBar1.Position:=mediaplayer1.Position;
end;
end;
 
procedure TForm1.PP;
begin
CurrentIndex:= ListBox2.ItemIndex;
  if CurrentIndex <> -1 then
  begin
    if MediaPlayer1.FileName <> '' then MediaPlayer1.Close;
    MediaPlayer1.FileName:= ListBox1.Items[CurrentIndex];
    MediaPlayer1.Open;
    MediaPlayer1.Play;
  end;
end;
 
procedure TForm1.FindFileInFolder(path, ext: string);
Var SR : TSearchRec;
    Res : Integer;
begin
  Res := FindFirst(path+ext, faAnyFile, SR);
  while Res = 0 do
  begin
   form1.ListBox1.Items.Add(path+Sr.Name);
   form1.ListBox2.Items.Add(Sr.Name);
   Res := FindNext(SR);
  end;
  FindClose(SR);
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
if MediaPlayer1.FileName <> '' then MediaPlayer1.Close;
end;
 
procedure TForm1.playnext;
begin
    if CurrentIndex = -1 then Exit;
    if (CurrentIndex < ListBox2.Count-1)
              then Inc (CurrentIndex)
              else CurrentIndex:= 0;
    ListBox2.ItemIndex:= CurrentIndex;
    PP;
end;
 
procedure TForm1.playprev;
begin
    if CurrentIndex = -1 then Exit;
    if (CurrentIndex > 0)
              then Dec(CurrentIndex)
              else CurrentIndex:= ListBox2.Count-1;
    ListBox2.ItemIndex:= CurrentIndex;
    PP;
end;
 
procedure TForm1.Image2Click(Sender: TObject);
begin
playprev;
end;
 
procedure TForm1.Image5Click(Sender: TObject);
begin
if MediaPlayer1.FileName <> '' then MediaPlayer1.Pause else exit;
end;
 
procedure TForm1.Image3Click(Sender: TObject);
begin
PP;
end;
 
procedure TForm1.Image4Click(Sender: TObject);
begin
playnext;
end;
 
procedure TForm1.ListBox2DblClick(Sender: TObject);
begin
pp;
end;
 
end.

Иногда выдает ошибку при запуске, но это не мешает процессу, и иногда выдает ошибку при переключении. Ну пока эт ладно.

@FromOutSide · 22.06.2017, 12:17 **[ТС]**

Вот, поймал эти ошибки.

@FromOutSide · 22.06.2017, 13:04 **[ТС]**

Или чтобы можно было лазить в папках, как в обычных условиях, но при условии что, предел будет допустим на D:\mus, то есть будет выведено содержимое папки D:\mus, как бы корневая папка.
не знаю понятно нет? а то я умею не уметь объяснять

@Пытливый · 22.06.2017, 13:54

Это мощно.

Delphi
1
'D:\DLPH7'+'\'

Ваша функция FindFileInFolder ищет только в одном каталоге, а как я понял необходимо получить все файлы и в дочерних каталогах, т.е. необходим обход дерева. Я этого не наблюдаю в программе.
А ошибка скорее всего связана с занятостью устройства. Вы видимо одновременно несколько треков в него пытались запихать - вот ему и поплохело.

@FromOutSide · 22.06.2017, 14:03 **[ТС]**

Сообщение от Пытливый

Мощно.

Да тут я хотел вместо 'D:\DLPH7' поставить переменную и плюсовать слэш =)

Сообщение от Пытливый

Я этого не наблюдаю в программе.

Видимо поэтому и интересуюсь...

Сообщение от Пытливый

Вы видимо одновременно несколько треков в него пытались запихать - вот ему и поплохело.

Нет, запускаю лишь по одному, ну разве что благодаря коду запускается две и более. Ну а при запуске что ему дает ошибку? Там же ничего не происходит. Ну кроме

Delphi
1
2
3
4
procedure TForm1.FormCreate(Sender: TObject);
begin
FindFileInFolder('D:\DLPH7'+'\', '*.mp3');
end;

которая в свою очередь запускает

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
procedure TForm1.FindFileInFolder(path, ext: string);
Var SR : TSearchRec;
    Res : Integer;
begin
  Res := FindFirst(path+ext, faAnyFile, SR);
  while Res = 0 do
  begin
   form1.ListBox1.Items.Add(path+Sr.Name);
   form1.ListBox2.Items.Add(Sr.Name);
   Res := FindNext(SR);
  end;
  FindClose(SR);
end;

ноо на медиа плеер это не должно влиять.

Добавлено через 4 минуты
Чтоб было понятнее, в скриншоте 3, ошибка происходит при переключении с трека на трек или просто при его включении, возможно тут и происходит одновременное воспроизведение нескольких треков.
А в скриншоте 4 ошибка при запуске программы, но поскольку их выходит так много, возможно тут виноват timer

Delphi
1
2
3
4
5
6
7
8
procedure TForm1.Timer1Timer(Sender: TObject);
begin
if MediaPlayer1.FileName<>''
then begin
TrackBar1.Max:=mediaplayer1.Length;
TrackBar1.Position:=mediaplayer1.Position;
end;
end;

DenNik · 22.06.2017, 14:21

Сообщение от FromOutSide

Или чтобы можно было лазить в папках, как в обычных условиях, но при условии что, предел будет допустим на D:\mus, то есть будет выведено содержимое папки D:\mus, как бы корневая папка.
не знаю понятно нет?

понятно. возможно в компоненте ShellTreeView можно задать корневой каталог, я не знаю

@FromOutSide · 22.06.2017, 15:25 **[ТС]**

Сообщение от DenNik

возможно в компоненте ShellTreeView можно задать корневой каталог

Что то у меня совсем не густо с такой инфой. наверное этот вариант лучше исключить.
и вариант с выводом списка всех путей в определенной папке, будет попроще.

Сообщение от Пытливый

а как я понял необходимо получить все файлы и в дочерних каталогах

примерно верно, но нужно не список файлов, а лишь списки всех путей.
Позже поищу что либо, если найду, запишу сюда.

@Пытливый · 22.06.2017, 15:36

Давненько это было, писал визуальный компонентик для подобных дел. Вот держите адаптацию невизуальную:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
uses StrUtils;
 
Type
  TFileListOption = (flRecurseScan, flFolderToList, flFileToList, flPathToList, flRelativePath);
  TFileListOptions = set of TFileListOption;
 
var
  Root: String = '';
 
procedure FolderScan(Folder: String; AExt: Array of String; Options: TFileListOptions; List: TStrings);
Var FileInfo: TSearchRec;
begin
 if Root = '' then Root := Folder;
 if Folder = '' then Exit;
 if FindFirst(Folder + '*.*', faAnyFile, FileInfo) = 0
 then begin
      try
       repeat
        if (FileInfo.Name = '.') or (FileInfo.Name = '..') then Continue;
        if (FileInfo.Attr and faDirectory <> 0)
        then begin
             if flFolderToList in Options
             then if flPathToList in Options
                  then if flRelativePath in Options
                       then List.Add(Copy(Folder, Length(Root)) + FileInfo.Name + '\')
                       else List.Add(Folder + FileInfo.Name + '\')
                  else List.Add(FileInfo.Name);
             if flRecurseScan in Options
             then FolderScan(Folder+FileInfo.Name+'\', AExt, Options, List);
             Continue;
             end;
        if IndexStr(ExtractFileExt(FileInfo.Name), AExt) = -1 then Continue;
        if flFileToList in Options
        then if flPathToList in Options
             then if flRelativePath in Options
                  then List.Add(Copy(Folder, Length(Root)) + FileInfo.Name)
                  else List.Add(Folder + FileInfo.Name)
             else List.Add(FileInfo.Name);
       until FindNext(FileInfo) <> 0;
      finally
       FindClose(FileInfo);
      end;
      end;
end;
 
procedure TForm37.Button1Click(Sender: TObject);
begin
 FolderScan('H:\Work\', ['.pas'], [flRecurseScan,flPathToList,flFileToList,flRelativePath], ListBox1.Items);
end;

DenNik · 22.06.2017, 16:10

реализовал
- рекурсивный поиск в подкаталогах
- вывод частичных путей в визуальный список, полных - в список в памяти
смотри, учись

Кликните здесь для просмотра всего текста

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
unit Unit1;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.MPlayer, FileCtrl;
 
type
  TForm1 = class(TForm)
    MediaPlayer1: TMediaPlayer;
    Button1: TButton;
    ListBox1: TListBox;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure ListBox1DblClick(Sender: TObject);
    procedure MediaPlayer1Click(Sender: TObject; Button: TMPBtnType; var DoDefault: Boolean);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormCreate(Sender: TObject);
  end;
 
var
  Form1: TForm1;
  CurrentIndex: integer = -1;
  CurrentRoot: string;
  FullPathesList: TStrings;   // список полных путей к файлам
 
implementation
 
{$R *.dfm}
 
procedure FindInDirectory(APath: string; AItems: TStrings);
var
  Search: TSearchRec;
  Folders: TStrings;
  i: word;
begin
  // ищем сначала файлы
  if FindFirst(APath + '*.mp3',faAnyFile - faDirectory,Search) = 0 then
  repeat
    AItems.Add(APath + Search.Name);
  until FindNext(Search) <> 0;
  FindClose(Search);
  // теперь ищем каталоги
  Folders:= TStringList.Create;
  if FindFirst(APath + '*.*',faDirectory,Search) = 0 then
  repeat
    if (Search.Name <> '.') and (Search.Name <> '..') then
    Folders.Add(IncludeTrailingPathDelimiter(APath + Search.Name));
  until FindNext(Search) <> 0;
  FindClose(Search);
  // в каждом каталоге производим рекурсивный поиск
  if Folders.Count > 0 then
  for i:= 0 to Pred(Folders.Count) do
    FindInDirectory(Folders[i],AItems);    // рекурсивный вход в процедуру поиска
  Folders.Free;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  i: Cardinal;
  temp: string;
begin
  // поиск файлов
  if SelectDirectory('','',CurrentRoot) then
  begin
    CurrentRoot:= IncludeTrailingPathDelimiter(CurrentRoot);
    Label1.Caption:= CurrentRoot;
    // инициируем поиск в выбранном каталоге
    FullPathesList.Clear;
    ListBox1.Clear;
    FindInDirectory(CurrentRoot,FullPathesList);
    // вывод в ListBox путей без стартового каталога
    ListBox1.Items.BeginUpdate;
    if FullPathesList.Count > 0 then
    for i:= 0 to Pred(FullPathesList.Count) do
    begin
      temp:= FullPathesList[i];
      Delete(temp,1,Length(CurrentRoot));
      ListBox1.Items.Add(temp);
    end;
    ListBox1.Items.EndUpdate;
  end;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if MediaPlayer1.Mode = mpPlaying then MediaPlayer1.Close;
  FullPathesList.Free;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  FullPathesList:= TStringList.Create;
end;
 
procedure TForm1.ListBox1DblClick(Sender: TObject);
begin
  // воспроизведение выбранного файла
  CurrentIndex:= ListBox1.ItemIndex;
  if CurrentIndex <> -1 then
  begin
    if MediaPlayer1.FileName <> '' then MediaPlayer1.Close;
    // конкатенация корневого каталога и выбранного имени файла для получения полного пути
    MediaPlayer1.FileName:= CurrentRoot + ListBox1.Items[CurrentIndex];
    MediaPlayer1.Open;
    MediaPlayer1.Play;
  end;
end;
 
 
end.

MediaPlayer скрыт

@Пытливый · 22.06.2017, 16:20

Все в принципе верно, только обычно одним циклом делают заполнение списка файлов и переход в каталог.

DenNik · 22.06.2017, 16:32

Пытливый, мне влом, а ТС для наглядности )

Добавлено через 2 минуты
я просто забыл, как из Search.Attr определить каталoг это или файл

Добавлено через 1 минуту
к тому же при этом придется искать ВСЕ файлы, т.е. ты не сможешь задать фильтр mp3 и при этом найти каталог.

Добавлено через 34 секунды
и это главная причина разделения цикла

@Пытливый · 22.06.2017, 16:49

Посмотрите чуть выше мой пост, там все в одном цикле, но ваш вариант тоже вполне нормален.

DenNik · 22.06.2017, 17:00

Сообщение от Пытливый

Посмотрите чуть выше мой пост, там все в одном цикле.

у тебя расширение не используется при непосредственно поиске. у тебя ищутся ВСЕ файлы, а затем отфильтровываются нужные по расширению. найти 1000 файлов, из них будет 10 нужных. зачем зря тратить ресурсы и писать дополнительный код?

Добавлено через 6 минут
Пы.Сы. наблюдаю некорректное поведение метода MediaPlayer.Stop - срабатывает как Пауза. т.е. файл потом продолжает воспроизводиться с того же места

Новые блоги и статьи Все статьи Все блоги /
Запустил конкурс "тем и промптов для текстовых квестов созданных почти чисто ИИ" Adler 06.10.2026 Всем привет! За последние три-четыре дня я создал более 16 текстовых квестовых игр используя преимущественно по одному запросу к ИИ на игру. Мне так понравилось смотреть все ветки/ сцены во всех. . .	ИИ не может найти нужный язык в списке Supersumestria 05.10.2026 Я ему даю вот такое изображение и прошу найти и подчеркнуть немецкий язык. Возвращает он вот это: https:/ / i. **********/ vqBWLe2. png Нужную строчку в 3й колонке просто выдумал. . Это. . .	Новая последняя моя музыка в SUNO zorxor 05.10.2026 Здравствуйте, дорогие мои друзья! С большой радостью я хотел бы представить вам свою новую последнею музыку, которую сгенерировала мне по моей просьбе нейросеть SUNO. С уважением, zorxor. Это. . .	Nekobox - outbounds[0].transport: unknown transport type: raw damix 01.10.2026 Фикс ошибки Правым кликом по серверу -> отладочная информация -> edit Заменить "net": "raw", на "net": "tcp", Нажать кнопку reload.
Программный домашний кинотеатр russiannick 27.09.2026 Сподобился на программный домашний кинотеатр. В качестве ЯВУ по традиции выбрал js. В помощники взял Яндекс-Алису. Было создано три зала на разные интересы. исторические и ретро сериал Хичкок. . .	Беседа с ИИ о программистах, недопускающих к созданию и правке кода генеративные ИИ и причины этого zorxor 21.09.2026 Раньше я радовался или получал некоторые эмоции, пусть небольшие, но всё же, от самого процесса написания кода, рекомпиляции и запуска, видя постепенное развитие программы и прочее. А теперь лень. . .	Мобильное приложение ColorStep pavlinmavlin 17.09.2026 Реализовал приложение Красный, Зеленый, Синий в Unity3d + c#. Название изменил на ColorStep. Приложение прошло модерацию и теперь доступно для скачивания. Делал его сам, шаг за шагом — и вот,. . .	Запрет дублирования строк в табличной части Maks 13.09.2026 Реализация из решения ниже выполнена на нетиповом справочнике "Нормы ТО" с табличной часть "Виды ТО", разработанного в КА2, со следующими реквизитами: - ВидТО (СправочникСсылка. ВидыТО); - ВидГСМ. . .

@FromOutSide 禁止 13 / 11 / 2 Регистрация: 04.09.2014 Сообщений: 230

	Вывод списка mp3 файлов и их воспроизведение 13.06.2017, 10:30. Показов 7061. Ответов 50 Метки нет (Все метки) Я искал на форуме, находил что-то похожее, но не нашел то что нужно. Нужно на delphi 7: Чтобы выводился список в listbox, всех mp3 файлов в папках и подпапках допустим есть папки: d:\music\album1\album1.1 d:\music\album1\album1.2 d:\music\album2\album2.1 Ну а вписывать можно или название лишь файла или с полным путем, но при этом стерев два первых символа пути music1.mp3 \music\album1\album1.2\music1.mp3 \music\album2\album2.1\music1.mp3 Т.е. как бы весь путь, с полным именем Возможности:Полоса перемотки. И через bitbtnЫ вкл, пауза, след, пред. Для меня подобные процедуры, непонятны, так что прошу Вас, с комментариями к кодам. Ну или пинайте меня в нужную сторону 0

@Пытливый 3765 / 2272 / 706 Регистрация: 29.05.2013 Сообщений: 9,622
	19.06.2017, 19:11
	Вы еще громкость там не сделали, вот тут есть код, как это сделать. 0

@FromOutSide 禁止 13 / 11 / 2 Регистрация: 04.09.2014 Сообщений: 230
	22.06.2017, 11:58 [ТС]
	DenNik, Я тебе очень благодарен! Но не мог бы ты уделить еще немножко времени? Не мог ответить раньше, не был за компом. Но вот что получилось. Миниатюры 0

@FromOutSide 禁止 13 / 11 / 2 Регистрация: 04.09.2014 Сообщений: 230
	22.06.2017, 12:07 [ТС]
	А что хотел еще узнать, объясню на примере. Допустим, вот есть путь D:\mus в нем лежат еще мноооожество папок, и нужно что бы, в комбобокс, были выведены все пути, с исключением вот этого начала D:\mus то есть пути будут выглядеть не D:\mus\Album1 а просто \Album1 Изображения 0

@FromOutSide 禁止 13 / 11 / 2 Регистрация: 04.09.2014 Сообщений: 230
	22.06.2017, 12:17 [ТС]
	Вот, поймал эти ошибки. Миниатюры 0

@FromOutSide 禁止 13 / 11 / 2 Регистрация: 04.09.2014 Сообщений: 230
	22.06.2017, 13:04 [ТС]
	Или чтобы можно было лазить в папках, как в обычных условиях, но при условии что, предел будет допустим на D:\mus, то есть будет выведено содержимое папки D:\mus, как бы корневая папка. не знаю понятно нет? а то я умею не уметь объяснять 0

@Пытливый 3765 / 2272 / 706 Регистрация: 29.05.2013 Сообщений: 9,622
	22.06.2017, 16:20
	Все в принципе верно, только обычно одним циклом делают заполнение списка файлов и переход в каталог. 0

DenNik Житель Земли 3004 / 3026 / 390 Регистрация: 26.07.2011 Сообщений: 11,465 Записей в блоге: 1
	22.06.2017, 16:32
	Пытливый, мне влом, а ТС для наглядности ) Добавлено через 2 минуты я просто забыл, как из Search.Attr определить каталoг это или файл Добавлено через 1 минуту к тому же при этом придется искать ВСЕ файлы, т.е. ты не сможешь задать фильтр mp3 и при этом найти каталог. Добавлено через 34 секунды и это главная причина разделения цикла 0

@Пытливый 3765 / 2272 / 706 Регистрация: 29.05.2013 Сообщений: 9,622
	22.06.2017, 16:49
	Посмотрите чуть выше мой пост, там все в одном цикле, но ваш вариант тоже вполне нормален. 0

Вывод списка mp3 файлов и их воспроизведение

Решение