Копирование в буфер обмена

ClipBoard.Assign(Image1.Picture);

uses
  ShlObj, ClipBrd; 
 
procedure CopyFilesToClipboard(FileList: string); 
var 
  DropFiles: PDropFiles; 
  hGlobal: THandle; 
  iLen: Integer; 
begin 
  iLen := Length(FileList) + 2; 
  FileList := FileList + #0#0; 
  hGlobal := GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT, 
    SizeOf(TDropFiles) + iLen); 
  if (hGlobal = 0) then raise Exception.Create('Could not allocate memory.'); 
  begin 
    DropFiles := GlobalLock(hGlobal); 
    DropFiles^.pFiles := SizeOf(TDropFiles); 
    Move(FileList[1], (PChar(DropFiles) + SizeOf(TDropFiles))^, iLen); 
    GlobalUnlock(hGlobal); 
    Clipboard.SetAsHandle(CF_HDROP, hGlobal); 
  end; 
end; 
 
// Example, Beispiel: 
 
procedure TForm1.Button1Click(Sender: TObject); 
begin 
  CopyFilesToClipboard('C:\1.jpg'#0'C:\2.jpg'); 
end;

uses
  ShlObj, ClipBrd, IOUtils, Types;
 
procedure CopyFilesToClipboard(FileList: string); overload;
begin
  var iLen:= Length(FileList) + 2;
  FileList:= FileList + #0#0;
 
  var hGlobal:= GlobalAlloc(GMEM_SHARE or GMEM_MOVEABLE or GMEM_ZEROINIT,
                            SizeOf(TDropFiles) + sizeof(char) * iLen);
 
  if (hGlobal = 0)
    then raise Exception.Create('Ошибка резервирования памяти.');
 
  var DropFiles:= PDropFiles(GlobalLock(hGlobal));
  DropFiles^.pFiles:= SizeOf(TDropFiles);
  DropFiles^.fWide:= true;
  Move(FileList[1], (PByte(DropFiles) + SizeOf(TDropFiles))^, sizeof(char) * iLen);
  GlobalUnlock(hGlobal);
  Clipboard.SetAsHandle(CF_HDROP, hGlobal);
end;
 
function CopyFilesToClipboard(Files: TStringDynArray): Boolean; overload;
begin
  result:= false;
  try
    if length(Files) = 0
      then raise Exception.Create('Список файлов пуст.');
 
    var filelist:= '';
 
    for var fn in Files do
      begin
        if not FileExists(fn)
          then raise Exception.CreateFmt('Файл "%s" не найден', [fn]);
 
        filelist:= filelist + fn + #0;
      end;
    CopyFilesToClipboard(filelist);
    result:= true;
  except on e: Exception do
    Application.MessageBox(pchar(e.Message), 'Ошибка', MB_OK or MB_ICONSTOP);
  end;
end;