Как лучше выдернуть значение из строки в котором эти значения делятся (сепаратором ::) или может быть одно

function fGetError(slanguage: string): string;
var
  iPos: integer;
  sText: string;
  blanguage, bclear: boolean;
begin
  bclear := false;
  blanguage := false;
  sText := '';
  iPos := 0;
  for iPos := 1 to Length(sError) do begin
    if bclear = false then begin
      sText := sText + sError[iPos];
    end;
    bclear := false; { если не сбросить, sText будет пустым }
    if sError[iPos] = ':' then begin
      if sText = slanguage + ':' then begin
        blanguage := true;
      end;
      if (iPos + 1 <= Length(sError)) and (sError[iPos + 1] = ':') then begin
        if blanguage = false then begin
          bclear := true;
          sText := '';
        end else begin
          sText := Copy(sText, 1, Length(sText) - 1);
          Break;
        end;
      end;
    end;
  end;
  Result := sText;
end;

uses StrUtils;
...
  s:=ExtractDelimited(msg,n,[#1]);

uses StrUtils;
 
function MsgByNum(const msg: String; n: Integer): String;
const Delim='::';
var b, e: Integer;
begin
  Result:='';
  b:=1;
  while n>1 do begin
    b:=PosEx(Delim,msg,b);
    if b=0 then Exit;
    Inc(b,Length(Delim));
    Dec(n);
  end;
  e:=PosEx(Delim,msg,b);
  if e=0 then e:=Length(msg)+1;
  Result:=Copy(msg,b,e-b);
end;

function MsgByNum(const msg: String; n: Integer): String;
const d=':'; Delim=d+d;
var b, e: Integer;
begin
  Result:='';
  e:=1;
  while n>1 do begin
    while (e<Length(msg)) and ((msg[e]<>d) or (msg[e+1]<>d)) do Inc(e);
    if e>=Length(msg) then Exit;
    Inc(e,Length(Delim));
    Dec(n);
  end;
  b:=e;
  while (e<Length(msg)) and ((msg[e]<>d) or (msg[e+1]<>d)) do Inc(e);
  if e=Length(msg) then Inc(e);
  Result:=Copy(msg,b,e-b);
end;

program project1;
uses SysUtils;
 
var
  s, st : string;
  arr : TStringArray;
 
begin
  readln(s);
  arr := s.Split(['::'], TStringSplitOptions.ExcludeEmpty); // <---
  for st in arr do writeln(st);
  // прекрасно работает с любой кодировкой, если что
end.