Поля и методы объекта реализуют многострочный текстовый редактор.Требуется дополнить объект методами

Unit Editor;
//--------------------------------------------------------------
// Библиотечный модуль поддержки многострочного редактора
//--------------------------------------------------------------
 
Interface
//--------------------------------------------------------------
// Лицевая часть модуля
//--------------------------------------------------------------
 
Type
        // указатель на тип данных строки в динамической памяти
        PLine =^TLine;
        //------------------------------------------------------
        // тип данных для хранения блока строки
        TLine = record
                  // поле текстовой строки
                  Line: String;
                  // поле числа символов в строке
                  iNum: Byte;
                  // указатель на предыдущий блок строки
                  Prev: PLine;
                  // указатель на следующий блок строки
                  Next: PLine;
                end;
        //------------------------------------------------------
        // тип данных многострочного текстового редактора
        TEditor = object
                    // указатель на первую строку редактирования
                    FirstLine: PLine;
                    // указатель на последнюю строку редактирования
                    LastLine : PLine;
                    // указатель на предыдущую строку редактирования
                    PrevLine : PLine;
                    // указатель на текущую строку редактирования
                    CurrLine : PLine;
                    // переменная для хранения полученного символа
                    Ch       : Char;
                    // переменная для хранения горизонтальной
                    // координаты курсора
                    iCurX    : Byte;
                    // переменная для хранения вертикальной
                    // координаты курсора
                    iCurY    : Byte;
                    // метод инициализации текстового редактора
                    procedure Init;
                    // метод вставки символа в строку, начиная
                    // с заданной позиции курсора
                    procedure InsertSymbToPos;
                    // метод удаления символа в строке, начиная
                    // с заданной позиции курсора
                    procedure DelSymbFromPos;
                    // метод перемещения курсора влево по строке
                    procedure ToLeft;
                    // метод перемещения курсора вправо по строке
                    procedure ToRight;
                    // рабочий метод объекта
                    procedure Run;
        end;
//--------------------------------------------------------------
 
Implementation
//--------------------------------------------------------------
// Внутренняя часть модуля - реализация методов
//--------------------------------------------------------------
Uses
        // подключение консольного модуля
        Crt;
//--------------------------------------------------------------
procedure TEditor.Init;
// метод инициализации текстового редактора
begin
        // очистка консольного окна
        ClrScr;
        // инициализация полей указателей объекта
        FirstLine := nil;
        LastLine  := nil;
        PrevLine  := nil;
        CurrLine  := nil;
        // создание текущей строки редактирования
        // в динамической памяти
        new(CurrLine);
        // инициализация поля содержимого строки
        CurrLine^.Line := '';
        // очистка поля числа символов в строке
        CurrLine^.iNum := 0;
        // поле указателя на предыдущий блок пусто
        CurrLine^.Prev := nil;
        // поле указателя на следующий блок пусто
        CurrLine^.Next := nil;
        // текущая строка становится первой строкой
        FirstLine := CurrLine;
        // текущая строка становится последней строкой
        LastLine  := CurrLine;
        // координаты курсора устанавливаются в начало
        iCurX := 1;
        iCurY := 1;
        // курсор переводится в начальное положение
        GotoXY(iCurX, iCurY);
end; // TEditor.Init
//--------------------------------------------------------------
procedure TEditor.InsertSymbToPos;
// метод вставки символа в строку, начиная с заданной позиции курсора
begin
        // вызов стандартной процедуры вставки символа
        insert(Ch, CurrLine^.Line, iCurX);
        // увеличение числа символов на единицу
        inc(CurrLine^.iNum);
        // смещение позиции курсора вправо на единицу
        inc(iCurX);
        // новая печать строки
        GotoXY(1, iCurY); ClrEol; Write(CurrLine^.Line);
        // смещение курсора в текущее положение
        GotoXY(iCurX, iCurY);
end; // TEditor.InsertSymbToPos
//--------------------------------------------------------------
procedure TEditor.DelSymbFromPos;
// метод удаления символа в строке, начиная с заданной позиции курсора
begin
        // если длина строки больше нуля, то...
        if CurrLine^.iNum > 0
          then
            begin
              // сместить курсор на единицу влево
              dec(iCurX);
              // вызвать стандартную процедуру
              // удаления символа в строке
              delete(CurrLine^.Line, iCurX, 1);
              // уменьшить число символов строки на единицу
              dec(CurrLine^.iNum);
              // новая печать строки
              GotoXY(1, iCurY); ClrEol; Write(CurrLine^.Line);
              // смещение курсора в текущее положение
              GotoXY(iCurX, iCurY);
            end;
end; // TEditor.DelSymbFromPos
//--------------------------------------------------------------
procedure TEditor.ToLeft;
// метод перемещения курсора влево по строке
begin
        // если переменная для хранения положения
        // курсора имеет значение больше единицы, то...
        if iCurX > 1
          then
            begin
              // уменьшить значение переменной на единицу
              dec(iCurX);
              // сдвинуть курсор на один шаг влево
              GotoXY(iCurX, iCurY);
            end;
end; // TLineEdit.ToLeft
//--------------------------------------------------------------
procedure TEditor.ToRight;
// метод перемещения курсора вправо по строке
begin
        // если переменная для хранения положения
        // курсора имеет значение меньшее числа символов
        // в строке плюс единица, то...
        if iCurX < CurrLine^.iNum + 1
          then
            begin
              // увеличить значение переменной на единицу
              inc(iCurX);
              // сдвинуть курсор на один шаг вправо
              GotoXY(iCurX, iCurY);
            end;
end; // TLineEdit.ToRight
//--------------------------------------------------------------
procedure TEditor.Run;
// рабочий метод объекта
const
        // символьные константы клавиш
        Nul = #00;  Ent = #13;
        cLf = #75;  Bck = #08;
        cRg = #77;  Esc = #27;
        cUp = #72;  pUp = #73;
        cDn = #80;  pDn = #81;
begin
        // вызов метода инициализации объекта
        Init;
        // пока условие истинно, выполнить
        while True do
          begin
            // получение символа с клавиатуры
            Ch := ReadKey;
            // выбор варианта действия по первому символу
            case Ch of
              // первый полученный символ - нуль
              Nul: begin
                     // получение символа с клавиатуры
                     Ch := ReadKey;
                     // выбор варианта действия по второму символу
                     case Ch of
                       // полученный символ - стрелка влево
                       cLf: begin
                              // вызов метода перемещения влево
                              ToLeft;
                            end;
                       // полученный символ - стрелка вправо
                       cRg: begin
                              // вызов метода перемещения вправо
                              ToRight;
                            end;
                     end;
                   end;
              // первый символ - алфавитно-цифровая клавиша
         'A'..'Z',
         'a'..'z',
         '0'..'9': begin
                     // вставка символа в указанную курсором позицию
                     InsertSymbToPos;
                   end;
              // первый символ - клавиша стирания BackSpace
              Bck: begin
                     // вызов метода удаления символа
                     DelSymbFromPos;
                   end;
              // первый символ - клавиши Esc
              Esc: begin
                     // выход из редактирования
                     break;
                   end;
            end;
          end;
end; // TEditor.Run
//--------------------------------------------------------------
End.

Program testEditor;
//--------------------------------------------------------------
// Программа тестирования многострочного редактора
//--------------------------------------------------------------
Uses
        // подключение библиотеки редактора
        Editor;
//--------------------------------------------------------------
Var
        // определение объекта-переменной редактора
        edt: TEditor;
Begin
        // вызов рабочего метода редактора
        edt.Run;
End.