Мобильные телефоны

program olimp_task_mob_sol1;
{программа по заданию отсюда https://www.cyberforum.ru/free-pascal/thread2604643.html}
const
  MAX_ACTIVE = 230;
{$DEFINE DEBUG}
type
  TActive = record
    X: integer;     //0..1023 можно поменять на shortInt
    Y: integer;     //0..1023
    Value: integer; //0..230  можно поменять на byte
  end;
 
var
  as_table: array [1..MAX_ACTIVE] of TActive;
  size: integer;  // колличество активных вышек, если s*s < MAX_ACTIVE
 
  procedure update(ax, ay, amount: integer);
  var
    foundZeroVal: boolean = False;
    i, idxZero: integer;
  begin
    for i := 1 to size do
    begin
      if (as_table[i].X = ax) and (as_table[i].Y = ay) then
      begin
        Inc(as_table[i].Value, amount);
        exit;
      end
      else
      if (not foundZeroVal) and (as_table[i].Value = 0) then
      begin
        foundZeroVal := True;
        idxZero := i;
      end;
    end;
    as_table[idxZero].X := ax;
    as_table[idxZero].Y := ay;
    as_table[idxZero].Value := amount;
  end;
 
  function asum(ax1, ay1, ax2, ay2: integer): integer;
  var
    i: integer;
  begin
    Result := 0;
    for i := 1 to size do
      if ((as_table[i].X >= ax1) and (as_table[i].X <= ax2)) and
         ((as_table[i].Y >= ay1) and (as_table[i].Y <= ay2)) then
        Inc(Result, as_table[i].Value);
  end;
var
  cmd, a1, a2, a3, a4: integer;
begin
  {$IFDEF DEBUG}
  Assign(Input, 'input.txt');
  Assign(Output, 'output.txt');
  reset(input);
  Rewrite(output);
  {$ENDIF}
  repeat
    Read(cmd);
    case cmd of
      0:
      begin
        Read(size);
        if size*size > MAX_ACTIVE then
           size:= MAX_ACTIVE
        else
          size *= size;
      end;
 
      1:
      begin
        Read(a1, a2, a3);
 
        update(a1, a2, a3);
      end;
 
      2:
      begin
        Read(a1, a2, a3, a4);
 
        writeln(asum(a1, a2, a3, a4));
      end;
    end;
  until cmd = 3;
  {$IFDEF DEBUG}
  Close(Input);
  Close(Output);
  {$ENDIF}
end.

program olimp_task_mob_sol2;
{программа по заданию отсюда https://www.cyberforum.ru/free-pascal/thread2604643.html}
{$mode objfpc}{$H+}
{$DEFINE DEBUG}
const
  MAX_SIZE = 1024;
var
  table: array[1..MAX_SIZE*MAX_SIZE] of longint; //массив хранения сумм
  size, cmd, a1, a2, a3, a4:longint;
 
//возвращает 2 в стпенеи количества нулей справа в 2-ичном предствалении x
//например  1= 1, 2=2, 3=1, 4=4 и т.д.
function disp (x: longint): longint;
begin
 disp := x and (x xor (x - 1));
end;
 
procedure update (x, y, amount: longint);
var
  idx: longint;
begin
  idx:= x + size * y; //порядковый номер ячейки в одномерном представлении  [0..1024*1024-1]
  inc(idx);           //увеличем на 1, т.к. суммы хранятся для диапазона в след. ячейке
  while idx <= size*size do begin
    inc (table[idx], amount);
    inc (idx, disp(idx));
  end;
end;
 
function asum(ax1, ay1, ax2, ay2: longint): longint;
  function get_sum(ax: longint ): Longint;
  begin
    Result:= 0;
    if ax = -1 then exit(0); //диапазон перед первым элементом
    //сумма для этого элемента записана в следующей ячейке
    inc(ax);
    while ax >= 1 do begin
      inc (Result, table[ax]);
      dec (ax, disp(ax));
    end;
  end;
var
  i, idx1, idx2: longint;
begin
  Result := 0;
 
  //сначала обрабатываем простой случай, если диапазон области непрерывен
  if (ay1 = ay2) or (ax2 - ax1 = pred(size)) then begin
      idx1:= ax1 + size * ay1 -1; //порядкоый номер ячейки перед началом диапазона
      idx2:= ax2 + size * ay2; //порядкоый номер ячейки конца диапазона
      Result:= get_sum(idx2) - get_sum(idx1);
      exit;
  end;
  //если у нас столбец из не полных строк
  for i:= ay1 to ay2 do begin
     idx1:= ax1 + size * i -1; //порядкоый номер ячейки перед началом диапазона
     idx2:= ax2 + size * i; //порядкоый номер ячейки конца диапазона
     Inc(Result, get_sum(idx2) - get_sum(idx1));
  end;
 
end;
 
begin
  {$IFDEF DEBUG}
  Assign(Input, 'input.txt');
  Assign(Output, 'output.txt');
  reset(input);
  Rewrite(output);
  {$ENDIF}
  repeat
    Read(cmd);
    case cmd of
      0:
      begin
        Read(size);
      end;
 
      1:
      begin
        Read(a1, a2, a3);
 
        update(a1, a2, a3);
      end;
 
      2:
      begin
        Read(a1, a2, a3, a4);
 
        writeln(asum(a1, a2, a3, a4));
      end;
    end;
  until cmd = 3;
  {$IFDEF DEBUG}
  Close(Input);
  Close(Output);
  {$ENDIF}
end.