Как отладить процедуру, балансирующую двоичное дерево поиска?

@kommunist90 · Регистрация: 17.07.2022

Студворк — интернет-сервис помощи студентам

Решил реализовать красно-чёрное дерево поиска.

К настоящему моменту работает:
- добавление новых узлов в дерево;
- печать дерева:
-- для каждого узла печатается следующая информация: значение, цвет, значение родительского элемента;
-- каждый "этаж" дерева печатается на отдельной строке;
- балансировка дерева (https://www.codesdope.com/cour... sertion/):
-- перекрашивание узлов;
-- левый поворот с перекрашиванием;
-- правый поворот с перекрашиванием;

Написал процедуру для левого поворота:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
procedure LeftRotation(var p: NodePtr);
var
    grandpa, dad, son: NodePtr;
begin
    son := p^.left;
    dad := p^.prev;
    grandpa := p^.prev^.prev;
    grandpa^.left := p;
    p^.prev := grandpa;
    dad^.prev := p;
    dad^.right := son;
    if son <> nil then
        son^.prev := dad;
    p^.left := dad;
end;

столкнулся с проблемой: Runtime error 216.

Прогнал программу через отладчик:

Code
1
2
3
4
5
6
7
8
9
10
11
55      dad^.prev := p;
1: p = 0x7ffff7ff1140
2: p^.value = 65
(gdb) 
56      dad^.right := son;
1: p = 0x7ffff7ff1140
2: p^.value = 65
(gdb) 
57      if son <> nil then
1: p = 0x0
2: p^.value = <error: Cannot access memory at address 0x18>

Установил строку, после выполнения которой в указатель на текущий узел был занесён nil (11-я строка процедуры):

Pascal
1
    dad^.right := son;

Но почему так происходит?
Процедуры, реализующие левый и правый повороты с перекрашиванием, сложнее, они используют туже логику, и работают абсолютно корректно (позволяют отбалансировать дерево при занесении в него элементов уже отсортированных по возрастанию и убыванию):

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
procedure RightRotationAndRecolor(var p: NodePtr);
var
    GreatGrandpa, grandpa, dad, bro: NodePtr;
begin
    dad := p^.prev;
    bro := p^.prev^.right;
    grandpa := p^.prev^.prev;
    GreatGrandpa := p^.prev^.prev^.prev;
    if GreatGrandpa <> nil then begin
        if GrandpaIsRightSon(grandpa) then
            GreatGrandpa^.right := dad
        else
            GreatGrandpa^.left := dad;
    end;
    if bro <> nil then
        bro^.prev := grandpa;
    grandpa^.left := bro;
    dad^.right := grandpa;
    dad^.prev := GreatGrandpa;
    grandpa^.prev := dad;
    dad^.color := black;
    grandpa^.color := red;
end;

Полный текст программы:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
program RBTreeDemo;
 
type
    col = (red, black);
 
    NodePtr = ^Node;
    Node = record
        left, right, prev: NodePtr;
        value: integer;
        color: col;
    end;
 
    NodePosition = ^NodePtr;
 
function TreeHeight(p: NodePtr): word;
var
    CurrHeight: word = 0;
begin
    if p = nil then begin
        TreeHeight := 0;
        exit;
    end;
    if TreeHeight(p^.left) >= TreeHeight(p^.right) then
        CurrHeight := TreeHeight(p^.left)
    else
        CurrHeight := TreeHeight(p^.right);
    TreeHeight := CurrHeight + 1;
end;
 
function CurrentRootIs(p: NodePtr): NodePosition;
begin
    if p^.prev = nil then
        CurrentRootIs := @p
    else
        CurrentRootIs := CurrentRootIs(p^.prev);
end;
 
function GrandpaIsRightSon(p: NodePtr): boolean;
begin
    if p^.value = p^.prev^.right^.value then
        GrandpaIsRightSon := true
    else
        GrandpaIsRightSon := false;
end;
 
procedure LeftRotation(var p: NodePtr);
var
    grandpa, dad, son: NodePtr;
begin
    son := p^.left;
    dad := p^.prev;
    grandpa := p^.prev^.prev;
    grandpa^.left := p;
    p^.prev := grandpa;
    dad^.prev := p;
    dad^.right := son;
    if son <> nil then
        son^.prev := dad;
    p^.left := dad;
end;
 
procedure RightRotationAndRecolor(var p: NodePtr);
var
    GreatGrandpa, grandpa, dad, bro: NodePtr;
begin
    dad := p^.prev;
    bro := p^.prev^.right;
    grandpa := p^.prev^.prev;
    GreatGrandpa := p^.prev^.prev^.prev;
    if GreatGrandpa <> nil then begin
        if GrandpaIsRightSon(grandpa) then
            GreatGrandpa^.right := dad
        else
            GreatGrandpa^.left := dad;
    end;
    if bro <> nil then
        bro^.prev := grandpa;
    grandpa^.left := bro;
    dad^.right := grandpa;
    dad^.prev := GreatGrandpa;
    grandpa^.prev := dad;
    dad^.color := black;
    grandpa^.color := red;
end;
 
procedure LeftRotationAndRecolor(var p: NodePtr);
var
    GreatGrandpa, grandpa, dad, bro: NodePtr;
begin
    dad := p^.prev;
    bro := p^.prev^.left;
    grandpa := p^.prev^.prev;
    GreatGrandpa := p^.prev^.prev^.prev;
    if GreatGrandpa <> nil then begin
        if GrandpaIsRightSon(grandpa) then
            GreatGrandpa^.right := dad
        else
            GreatGrandpa^.left := dad;
    end;
    if bro <> nil then
        bro^.prev := grandpa;
    grandpa^.right := bro;
    dad^.left := grandpa;
    dad^.prev := GreatGrandpa;
    grandpa^.prev := dad;
    dad^.color := black;
    grandpa^.color := red;
end;
 
function DadIsLeftSon(p: NodePtr): boolean;
begin
    if p^.prev^.prev^.left = nil then begin
        DadIsLeftSon := false;
        exit;
    end;
    if p^.prev^.prev^.left^.value = p^.prev^.value then
        DadIsLeftSon := true
    else
        DadIsLeftSon := false;
end;
 
function DadIsRightSon(p: NodePtr): boolean;
begin
    if p^.prev^.prev^.right = nil then begin
        DadIsRightSon := false;
        exit;
    end;
    if p^.prev^.prev^.right^.value = p^.prev^.value then
        DadIsRightSon := true
    else
        DadIsRightSon := false;
end;
 
function ImLeftSon(p: NodePtr): boolean;
begin
    if p^.prev^.left = nil then begin
        ImLeftSon := false;
        exit;
    end;
    if p^.prev^.left^.value = p^.value then
        ImLeftSon := true
    else
        ImLeftSon := false;
end;
 
function ImRightSon(p: NodePtr): boolean;
begin
    if p^.prev^.right = nil then begin
        ImRightSon := false;
        exit;
    end;
    if p^.prev^.right^.value = p^.value then
        ImRightSon := true
    else
        ImRightSon := false;
end;
 
procedure SetGrandpaColorRed(var p: NodePtr);
begin
    if p^.prev^.prev^.prev = nil then
        exit
    else
        p^.prev^.prev^.color := red;
end;
 
procedure SetDadAndUncleColorBlack(var p: NodePtr);
begin
    if (p^.prev^.prev^.left = nil) or (p^.prev^.prev^.right = nil) then
        exit;
    p^.prev^.prev^.left^.color := black;
    p^.prev^.prev^.right^.color := black;
end;
 
procedure recolor(var p: NodePtr);
begin
    SetDadAndUncleColorBlack(p);
    SetGrandpaColorRed(p);
end;
 
function UncleIsBlack(p: NodePtr): boolean;
begin
    if (p^.prev^.prev^.left = nil) or (p^.prev^.prev^.right = nil) then begin
        UncleIsBlack := true;
        exit;
    end;
    if (p^.prev^.prev^.left^.color = black) or
        (p^.prev^.prev^.right^.color = black)
    then begin
        UncleIsBlack := true
    end else
        UncleIsBlack := false;
end;
 
function UncleIsRed(p: NodePtr): boolean;               {technically I check}
begin                                       {if both parent and uncle are red}
    if (p^.prev^.prev^.left = nil) or (p^.prev^.prev^.right = nil) then begin
        UncleIsRed := false;
        exit;
    end;
    if (p^.prev^.prev^.left^.color = red) and
        (p^.prev^.prev^.right^.color = red)
    then begin
        UncleIsRed := true
    end else
        UncleIsRed := false;
end;
 
function DadIsRed(p: NodePtr):boolean;
begin
    if p^.prev^.color = red then
        DadIsRed := true
    else
        DadIsRed := false
end;
 
function DadIsBlack(p: NodePtr):boolean;
begin
    if p^.prev^.color = black then
        DadIsBlack := true
    else
        DadIsBlack := false
end;
 
procedure SelfBalance(var p: NodePtr);
begin
    if (p^.prev = nil) or DadIsBlack(p) or (p^.color = black) then
        exit;
    if DadIsRed(p) then begin
        if UncleIsRed(p) then begin
            recolor(p);
            SelfBalance(p^.prev^.prev);
        end else
        if UncleIsBlack(p) and ImRightSon(p) and DadIsRightSon(p) then begin
            LeftRotationAndRecolor(p);
            SelfBalance(p^.prev);
        end else
        if UncleIsBlack(p) and ImLeftSon(p) and DadIsLeftSon(p) then begin
            RightRotationAndRecolor(p);
            SelfBalance(p^.prev);
        end else
        if UncleIsBlack(p) and ImRightSon(p) and DadIsLeftSon(p) then begin
            LeftRotation(p);
            RightRotationAndRecolor(p^.left);
            SelfBalance(p);
        end;
    end;
end;
 
procedure FindNode(
    n: integer; var p, previous: NodePtr; var position: NodePosition
);
begin
    if (p = nil) or (p^.value = n) then begin
        position := @p;
        exit;
    end;
    previous := p;
    if n < p^.value then
        FindNode(n, p^.left, previous, position)
    else
        FindNode(n, p^.right, previous, position);
end;
 
procedure AddNode(var p: NodePtr; var height: word);
var
    n: integer;
    previous: NodePtr = nil;
    position: NodePosition = nil;
begin
    read(n);
    FindNode(n, p, previous, position);
    if position^ <> nil then
        writeln('The node ', n, ' already exists')
    else begin
        new(position^);
        position^^.value := n;
        position^^.right := nil;
        position^^.left := nil;
        position^^.prev := previous;
        if position^^.prev <> nil then begin
            position^^.color := red;
            SelfBalance(position^);
            position := CurrentRootIs(position^);       {check if root changed}
            p := position^;                             {and set new root}
        end else
            position^^.color := black;
        height := TreeHeight(p);
    end;
end;
 
procedure PrintColor(p: NodePtr);
begin
    if p^.color = black then
        write(',blk(')
    else
        write(',red(');
end;
 
procedure PrintTreeLevel(p: NodePtr; height, CurrentHeight: word);
begin
    if p = nil then
        exit;
    if height = CurrentHeight then begin
        write(p^.value);
        PrintColor(p);
        if p^.prev = nil then
            write(' ) ')
        else
            write(p^.prev^.value, ') ');
    end else begin
        PrintTreeLevel(p^.left, height, CurrentHeight + 1);
        PrintTreeLevel(p^.right, height, CurrentHeight + 1);
    end;
end;
 
procedure PrintTree(root: NodePtr; height: word);
var
    i: word;
begin
    for i := 1 to height do begin
        PrintTreeLevel(root, i, 1);
        writeln;
    end;
end;
 
var
    root: NodePtr = nil;
    height: word = 0;
    c: char;
begin
    while true do begin
        while not SeekEoln do begin
            AddNode(root, height);
        end;
        readln;
        writeln;
        PrintTree(root, height);
        writeln('current tree height is ', height);
        write('Continue input? y/n ');
        readln(c);
        if c <> 'y' then
            halt;
    end;
end.

Я в замешательстве

@bormant · 13.02.2023, 09:05

Если правильно путаю, для вращений должно быть достаточно чего-то такого:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
type
  TNodeData = Integer;
 
  TRBNodeColor = (rbRedNode, rbBlackNode);
  PRBNode = ^TRBNode;
  TRBNode = record
    Data: TNodeData;
    Parent, Left, Right: PRBNode;
    Color: TRBNodeColor;
  end;
 
procedure RotateLeft(var root, x: PRBNode);
var
  y: PRBNode;
begin
  y := x^.Right;
  x^.Right := y^.Left;
  if y^.Left <> nil then
    y^.Left^.Parent := x;
  y^.Parent := x^.Parent;
  if x = root then
    root := y
  else if x = x^.Parent^.Left then
    x^.Parent^.Left := y
  else
    x^.Parent^.Right := y;
  y^.Left := x;
  x^.Parent := y;
end;
 
procedure RotateRight(var root, x: PRBNode);
var
  y: PRBNode;
begin
  y := x^.Left;
  x^.Left := y^.Right;
  if y^.Right <> nil then
    y^.Right^.Parent := x;
  y^.Parent := x^.Parent;
  if x = root then
    root := y
  else if x = x^.Parent^.Right then
    x^.Parent^.Right := y
  else
    x^.Parent^.Left := y;
  y^.Right := x;
  x^.Parent := y;
end;

@kommunist90 · 13.02.2023, 10:39 **[ТС]**

Спасибо!

Но мне всё равно непонятно почему ломается и не хочет работать мой код.
Это свидетельствует, что я чего-то не понимаю про указатели - а это не есть хорошо.

Почему после выполнения

Pascal
1
    dad^.right := son;

в указатель p, в котором содержится адрес нового добавляемого узла (для которого выполнились условия (я - правый красный сын) и (родитель - левый красный сын) и (дядя - чёрный)), заносится нулевой адрес nil?

@bormant · 13.02.2023, 13:38

Сообщение от kommunist90

чего-то не понимаю про указатели - а это не есть хорошо

Не обязательно, может быть элементарная невнимательность.
Берёте свой LeftRotation и сравниваете с моим RotateLeft, выясняя где они работают по-разному. Вот там и будет корень непонимания.

Добавлено через 1 минуту
Правый поворот полностью симметричный, с ним разбираться отдельно нет никакого смысла

@kommunist90 · 23.03.2023, 10:18 **[ТС]**

Я дико извиняюсь, но самостоятельно так и не смог разобраться в данной проблемме.
За прошедший месяц изучал другие темы, но мучает чувство незакрытого гештальта.
Не могли бы вы ткнуть тупого носом в его ошибку?

Новые блоги и статьи Все статьи Все блоги /
Access VikBal 11.12.2025 Помогите пожалуйста !! Как объединить 2 одинаковые БД Access с разными данными.	Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .	Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .
Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .	Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .	Фото: Daniel Greenwood kumehtar 13.11.2025

@kommunist90 0 / 0 / 0 Регистрация: 17.07.2022 Сообщений: 9
	23.03.2023, 10:18 [ТС]
	Я дико извиняюсь, но самостоятельно так и не смог разобраться в данной проблемме. За прошедший месяц изучал другие темы, но мучает чувство незакрытого гештальта. Не могли бы вы ткнуть тупого носом в его ошибку? 0